"{ Package: 'stx:goodies/petitparser/compiler' }"

"{ NameSpace: Smalltalk }"

Object subclass:#PPCConfiguration

	instanceVariableNames:'arguments ir history'

	classVariableNames:''

	poolDictionaries:''

	category:'PetitCompiler-Core'

!

!PPCConfiguration class methodsFor:'as yet unclassified'!

default

	^ PPCFirstPrototype new

!

new

	^ self basicNew

		initialize;

		yourself

! !

!PPCConfiguration methodsFor:'accessing'!

arguments: args

	arguments := args

!

input: whatever

	ir := whatever.

	self remember: #input.

!

ir

	^ ir

!

ir: whatever

	ir := whatever

! !

!PPCConfiguration methodsFor:'as yet unclassified'!

compile: whatever

	self input: whatever.

	self invokePhases.

	^ ir

!

compile: whatever arguments: args

	self arguments: args.

	^ self compile: whatever.

!

remember: key

	arguments debug ifTrue: [ 

		history add: key -> (ir copy).

	]

! !

!PPCConfiguration methodsFor:'initialization'!

initialize

	history := OrderedCollection new

! !

!PPCConfiguration methodsFor:'phases'!

check

	ir checkTree 

!

generate

	| compiler rootMethod compiledParser |

	arguments generate ifFalse: [ ^ self ].

	compiler := PPCCompiler on: arguments.

	rootMethod := (PPCCodeGenerator on: compiler)

		arguments: arguments;

		visit: ir.

	compiler compileParser.

	compiler compiledParser startSymbol: rootMethod methodName.

	compiledParser := compiler compiledParser new.

	ir := compiledParser.

!

inline

	arguments inline ifFalse: [ ^ self ].

	ir := PPCInliningVisitor new

		arguments: arguments;

		visit: ir.

	self remember: #inline.

!

merge

	arguments merge ifFalse: [ ^ self ].

	ir :=  PPCMergingVisitor new

		arguments: arguments;

		visit: ir.

	self remember: #merge

!

specialize

	arguments specialize ifFalse: [ ^ self ].

	" 

		Invokes a visitor that creates specialized nodes

		for some patterns of PPCNodes

	"

	ir :=  (PPCOptimizingVisitor new

		arguments: arguments;

		visit: ir).

	self remember: #specialize

!

toPPCIr

	ir := ir asCompilerTree.

	self remember: #ppcNodes

!

tokenize

	arguments tokenize ifFalse: [ ^ self ] .

	ir :=  PPCTokenDetector new

		arguments: arguments;

		visit: ir.

	self remember: #tokenize

! !