--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/compiler/PPCSequenceNode.st	Sun Oct 26 01:03:31 2014 +0000
@@ -0,0 +1,99 @@
+"{ Package: 'stx:goodies/petitparser/compiler' }"
+
+PPCListNode subclass:#PPCSequenceNode
+	instanceVariableNames:''
+	classVariableNames:''
+	poolDictionaries:''
+	category:'PetitCompiler-Nodes'
+!
+
+PPCSequenceNode comment:''
+!
+
+!PPCSequenceNode methodsFor:'accessing'!
+
+prefix
+	^ #seq
+! !
+
+!PPCSequenceNode methodsFor:'analysis'!
+
+acceptsEpsilon
+	^ self acceptsEpsilonOpenSet: IdentitySet new.
+!
+
+acceptsEpsilonOpenSet: set
+	set add: self.
+	^ self children allSatisfy: [:e | e acceptsEpsilonOpenSet: set ]
+!
+
+firstSetSuchThat: block into: aCollection openSet: aSet
+	(aSet includes: self) ifTrue: [ ^ aCollection ].
+	aSet add: self.
+	
+	(block value: self) ifTrue: [ aCollection add: self. ^ aCollection ].
+	
+	self children do: [ :child | 
+		child firstSetSuchThat: block into: aCollection openSet: aSet.
+		child acceptsEpsilon ifFalse: [ ^ aCollection ]
+	].
+	^ aCollection
+! !
+
+!PPCSequenceNode methodsFor:'compiling'!
+
+addGuard: compiler id: id
+	|  guard firsts |
+	(compiler guards not or: [(guard := PPCGuard on: self) makesSense not]) ifTrue: [ ^ self].
+
+	firsts := (self firstSetSuchThat: [ :e | (e isKindOf: PPCTrimmingTokenNode) or: [ e isTerminal ] ]).
+
+	
+	(firsts allSatisfy: [ :e | e isKindOf: PPCTrimmingTokenNode ]) ifTrue: [  
+		"If we start with trimming, we should invoke the whitespace parser"
+		firsts anyOne compileWhitespace: compiler.
+		
+		compiler add: 'context atEnd ifTrue: [ ^ self error ].'.
+		guard id: id, '_guard'.
+		guard compileGuard: compiler.
+		compiler addOnLine: 'ifFalse: [ ^ self error ].'
+	].
+
+	(firsts allSatisfy: [ :e | e isTerminal ]) ifTrue: [  
+		compiler add: 'context atEnd ifTrue: [ ^ self error ].'.
+		guard id: id, '_guard'.
+		guard compileGuard: compiler.
+		compiler addOnLine: 'ifFalse: [ ^ self error ].'
+	].
+!
+
+compileWith: compiler effect: effect id: id
+	compiler startMethod: id.
+	compiler addVariable: 'retval'.
+	compiler addVariable: 'element'.
+	compiler addVariable: 'memento'.			
+	compiler add: (compiler smartRemember: self).
+	compiler add: 'retval := Array new: ', children size asString, '.'.
+	self addGuard: compiler id: id.
+
+	(1 to: children size) do: [ :idx  | |child|
+		child := children at: idx.
+		compiler add: 'element := '.
+		compiler callOnLine: (child compileWith: compiler).
+	
+		compiler add: 'error ifTrue: [ ', (compiler smartRestore: self) ,' ^ failure ].'.
+		compiler add: 'retval at: ', idx asString, ' put: element.'.
+	].
+	compiler add: '^ retval'.
+ ^ compiler stopMethod.
+! !
+
+!PPCSequenceNode methodsFor:'optimizing'!
+
+asFast
+	^ PPCTokenSequenceNode new
+		children: children;
+		name: self name;
+		yourself
+! !
+