"{ Package: 'stx:goodies/petitparser/compiler' }"

PPCDelegateNode subclass:#PPCStarNode
	instanceVariableNames:''
	classVariableNames:''
	poolDictionaries:''
	category:'PetitCompiler-Nodes'
!

!PPCStarNode methodsFor:'accessing'!

acceptsEpsilon
	^ true
!

acceptsEpsilonOpenSet: set
	^ true
!

prefix
	^ #star
!

rewrite: changeStatus
	(child isKindOf: PPCMessagePredicateNode) ifTrue: [ 
		changeStatus change.
		^ PPCStarMessagePredicateNode new
			name: name;
			child: child;
			message: child message;
			yourself
	]. 

	(child isKindOf: PPCAnyNode) ifTrue: [ 
		changeStatus change.
		^ PPCStarAnyNode new
			name: name;
			child: child;
			yourself
	]. 

	(child isKindOf: PPCCharSetPredicateNode) ifTrue: [ 
		changeStatus change.
		^ PPCStarCharSetPredicateNode new
			name: name;
			predicate: child predicate;
			child: child;
			yourself
	] 
! !

!PPCStarNode methodsFor:'analyzing'!

isNullable
	^ true
! !

!PPCStarNode methodsFor:'as yet unclassified'!

compileWith: compiler effect: effect id: id
	compiler startMethod: id.
	compiler addVariable: 'retval'.
	compiler addVariable: 'element'.

	compiler add: 'retval := OrderedCollection new.'.
	compiler add: 'element := '.
	compiler callOnLine: (child compileWith: compiler).
	compiler add: '[ error ] whileFalse: ['.
	compiler indent.
	compiler add: 'retval add: element.'.
	compiler add: 'element := '.
	compiler callOnLine: (child compileWith: compiler).
	compiler dedent.
	compiler add: '].'.
	compiler add: 'self clearError.'.
	compiler add: '^ retval asArray'.
 ^ compiler stopMethod.
! !

!PPCStarNode methodsFor:'first follow next'!

followSets: aFollowDictionary firstSets: aFirstDictionary into: aSet suchThat: aBlock
	| first |
	super followSets: aFollowDictionary firstSets:  aFirstDictionary into: aSet suchThat: aBlock.
	
	first := aFirstDictionary at: self.
	(aFollowDictionary at: child) addAll: (first reject: [:each | each isNullable])
! !