"

 COPYRIGHT (c) 1995 by Claus Gittinger / eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool2' }"

UIObjectView subclass:#UIPainterView

	instanceVariableNames:'treeView listHolder superclassName className methodName

		categoryName handleColorBlack handleColorWhite handleMasterColor

		sketchPainter listOfAspectsHolder'

	classVariableNames:'HandCursor RedefineAspectMethods AspectsAsInstances

		GenerateCommentedCode'

	poolDictionaries:''

	category:'Interface-UIPainter'

!

Object subclass:#ViewProperty

	instanceVariableNames:'view spec identifier'

	classVariableNames:'Identifier'

	poolDictionaries:''

	privateIn:UIPainterView

!

!UIPainterView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger / eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    buildIn view used by the UIPainter; from this view, the layout of the

    new application derives from.

    [see also:]

	UIBuilder

	UIObjectView

    [author:]

	Claus Gittinger

	Claus Atzkern

"

! !

!UIPainterView class methodsFor:'initialization'!

initialize

    AspectsAsInstances := true. "/ false.

    RedefineAspectMethods := false.

    "Created: / 22.9.1999 / 12:32:31 / stefan"

! !

!UIPainterView class methodsFor:'code generation mode'!

generateAspectsAsInstanceVariables

    "if on, aspects are held as instance variables;

     if off (the default), they are kept in the bindings dictionary."

    ^ AspectsAsInstances

    "Created: / 29.7.1998 / 11:21:38 / cg"

    "Modified: / 29.7.1998 / 11:22:01 / cg"

!

generateAspectsAsInstanceVariables:aBoolean

    "if on, aspects are held as instance variables;

     if off (the default), they are kept in the bindings dictionary."

    AspectsAsInstances := aBoolean

    "Created: / 29.7.1998 / 11:21:26 / cg"

    "Modified: / 29.7.1998 / 11:22:11 / cg"

!

generateCommentedCode

    "comments in generated aspect methods; yes or no."

    ^ GenerateCommentedCode ? true

    "Modified: / 12-01-2008 / 10:21:06 / cg"

!

generateCommentedCode:aBoolean

    "comments in generated aspect methods; yes or no."

    GenerateCommentedCode := aBoolean

!

redefineAspectMethods

    "redefine methods yes or no. 

     If a method is defined in super class should the message be reinstalled ?"

    ^ RedefineAspectMethods

    "Modified: / 22.9.1999 / 12:33:03 / stefan"

!

redefineAspectMethods:aBoolean

    "redefine methods yes or no.

     If a method is defined in super class should the message be reinstalled ?"

    RedefineAspectMethods := aBoolean

! !

!UIPainterView class methodsFor:'defaults'!

defaultMenuMessage

    "This message is the default yo be sent to the menuHolder to get a menu

    "

    ^ #showMiddleButtonMenu

! !

!UIPainterView methodsFor:'accessing'!

application

    ^ nil

    "Modified: 6.9.1995 / 00:46:44 / claus"

!

applicationName

    ^ self className

!

applicationName:aName

    self className:aName

!

class:aClass superclassName:aSuperclassName selector:aSelector

    self assert:(aClass isBehavior).

    className      := aClass name.

    superclassName := aSuperclassName.

    methodName     := aSelector.

!

className

    ^ className

!

className:aName

    self assert:(aName isString).

    className := aName

!

className:aClassName superclassName:aSuperclassName selector:aSelector

    self assert:(aClassName isString).

    className      := aClassName.

    superclassName := aSuperclassName.

    methodName     := aSelector.

!

listOfAspectsHolder:something

    listOfAspectsHolder := something.

!

methodName

    ^ methodName

!

methodName:aName

    methodName := aName

!

selectNames:aStringOrCollection

    |prop coll s n newSel|

    (aStringOrCollection size == 0) ifTrue:[

	newSel := nil.

    ] ifFalse:[

	(s := aStringOrCollection) isString ifFalse:[

	    s size == 1 ifTrue:[

		s := s first

	    ] ifFalse:[

		coll := OrderedCollection new.

		s do:[:aName|

		    (prop := self propertyOfName:aName) notNil ifTrue:[

			coll add:(prop view)

		    ]

		].

		(n := coll size) == 1 ifTrue:[

		    newSel := coll at:1

		] ifFalse:[

		    n == 0 ifTrue:[

			newSel := nil

		    ] ifFalse:[

			newSel := coll

		    ]

		].

		^ self select:newSel.

	    ]

	].

	prop := self propertyOfName:s.

	prop isNil ifTrue:[

	    newSel := nil

	] ifFalse:[

	    newSel := prop view

	].

    ].

    ^ self select:newSel

! !

!UIPainterView methodsFor:'change & update'!

layoutChanged

    treeView notNil ifTrue:[

	treeView layoutChanged

    ]

! !

!UIPainterView methodsFor:'copy & cut & paste'!

changeSelectionAfterPasteOf:sel

    sel notNil ifTrue:[

        self select:sel.

    ].

!

commonContainerOf:someComponents

    |container|

    container := someComponents first container.

    [container notNil

     and:[ (someComponents conform:[:eachComponent | eachComponent isComponentOf:container]) not]]

	whileTrue:[

	container := container container.

    ].

    ^ container

!

copySelection

    "copy the selection into the cut & paste-buffer"

    |specs coll|

    coll := self minClosedViewSetFor:(self selection).

    coll notNil ifTrue:[

"/        self select:nil.

        specs := coll collect:[:eachView | self fullSpecWithAbsolutePositionFor:eachView].

        self setClipboardObject:specs.

"/        treeView selection: sel

    ].

!

deleteSelection

    "delete the selection buffered"

    self deleteSelectionBuffered: true

!

deleteSelectionBuffered:buffered

    "cut the selection. If buffered is true, place it into the cut&paste-buffer"

    |specs viewsToRemove newSelection firstView|

    treeView askForSelectionChangeAllowed ifFalse:[^ self].

    viewsToRemove := self minClosedViewSetFor:(self selection).

    viewsToRemove isEmptyOrNil ifTrue:[ ^ self].

    buffered ifTrue:[

        specs := viewsToRemove collect:[:aView| self fullSpecWithAbsolutePositionFor:aView ].

        self setClipboardObject:specs

    ].

    firstView    := viewsToRemove first.

    newSelection := self findContainerOfView:firstView.

    newSelection isNil ifTrue:[

        newSelection := self.

    ] ifFalse:[

        viewsToRemove size == 1 ifTrue:[

            |subviews index|

            subviews := newSelection subViews.

            subviews size > 1 ifTrue:[

                index := subviews findFirst:[:eachView| eachView isSameOrComponentOf:firstView ].

                index > 0 ifTrue:[

                    newSelection := subviews

                            at:(index + 1)

                            ifAbsent:[subviews at:index -1].

                ].

            ].

        ].

    ].

    self withSelectionHiddenDo:[

        self select:newSelection.

        treeView canvasEventsDisabledDo:[

            self withinTransaction:#cut objects:viewsToRemove do:[

                viewsToRemove reverseDo:[:aView|

                    self createUndoRemove:aView.

                    self remove:aView.

                ]

            ].

        ].

        self windowGroup processRealExposeEvents.

    ].

!

deleteTotalSelection

    "delete the selection"

    self deleteSelectionBuffered: false

!

getSelectedViewsAndSpecs

    "return an array filed with selected views and corresponding specs.

     Nil if there is none."

    |specs coll sel|

    sel := treeView selection.

    coll := self minClosedViewSetFor:(self selection).

    coll isNil ifTrue:[^ nil].

    specs := coll collect:[:aView| self fullSpecFor:aView ].

    ^ Array with: coll with: specs

!

pasteBuffer

    "add the objects in the paste-buffer to the object view; 

     don't change the layout if more than a single item has been selected"

    |sel clipboard|

    self enabled ifFalse:[

        Dialog warn:'Operation currently disabled (In geometry test mode)'.

        ^ self

    ]. 

    clipboard := self getClipboardObject.

    sel := self pasteSpecifications:clipboard keepLayout:true "(clipboard size > 1)".

    self changeSelectionAfterPasteOf:sel.

!

pasteKeepingPosition

    "add the objects in the paste-buffer to the object view;

     translate the layout as appropriate, to position the component

     at the same absolute position (relative to topView) as before"

    |sel|

    sel := self

        pasteSpecifications:(self getClipboardObject)

        keepLayout:true

        keepPosition:true

        at:nil.

    self changeSelectionAfterPasteOf:sel.

!

pasteSpecifications:aSpecificationOrList into:aContainerOrNil beforeIndex:anIndexOrNil keepLayout:keepLayout keepPosition:keepPosition at:aPointOrNilOrKeep

    "add the specs to the object view; returns list of pasted widgets"

    |specsToPaste pasteOffset builder newSel 

     bounds containerToPasteInto pastePoint beforeIndex|

    treeView askForSelectionChangeAllowed ifFalse:[^ nil].

    containerToPasteInto := aContainerOrNil.

    (aPointOrNilOrKeep == #keep

    or:[ self window sensor shiftDown

    or:[ self window sensor ctrlDown ]]) ifTrue:[

        "/ paste into the selection

        containerToPasteInto isNil ifTrue:[

            containerToPasteInto := self singleSelection.

        ].

    ] ifFalse:[

        "/ ignore the selection and paste where we drop!!

        pastePoint := aPointOrNilOrKeep.

        pastePoint isNil ifTrue:[

            pastePoint := device 

                                translatePoint:(self sensor mousePoint)

                                fromView:nil

                                toView:self.

        ].

        containerToPasteInto isNil ifTrue:[

            containerToPasteInto := self findObjectAt:pastePoint.

        ].

    ].

    containerToPasteInto isNil ifTrue:[

        self selection size > 0 ifTrue:[

            containerToPasteInto := self commonContainerOf:self selection

        ] ifFalse:[

            containerToPasteInto := self

        ].

"/        self selection:containerToPasteInto.

    ].

    "/ search up parent list for something we can paste into

    [containerToPasteInto notNil and:[(self canPasteInto:containerToPasteInto) not]] whileTrue:[

        containerToPasteInto == self ifTrue:[

            containerToPasteInto := nil

        ] ifFalse:[

            containerToPasteInto := containerToPasteInto container.

        ].

    ].

    containerToPasteInto isNil ifTrue:[

        containerToPasteInto := self

    ].

    (self canPaste:aSpecificationOrList into:containerToPasteInto)

    ifFalse:[

        self enabled ifTrue:[

            Dialog warn:'Cannot paste into selected component (not a container ?)'.

        ] ifFalse:[

            Dialog warn:'Operation currently disabled (In Geometry test mode)'.

        ]. 

        ^ nil

    ].

    aSpecificationOrList isCollection ifTrue:[

        specsToPaste := aSpecificationOrList

    ] ifFalse:[

        specsToPaste := Array with:aSpecificationOrList

    ].

"/    self setClipboardObject:nil.

    newSel  := OrderedCollection new.

    builder := UIBuilder new isEditing:true.

    className notNil ifTrue:[

        builder applicationClass:(self resolveName:className)

    ].

    bounds := Rectangle origin:0@0 extent:(containerToPasteInto bounds extent).

    pasteOffset := 0.

    (anIndexOrNil notNil and:[anIndexOrNil > 0]) ifTrue:[

        beforeIndex := anIndexOrNil.

    ].

    specsToPaste do:[:eachSpec|

        |view newOrigin uiPainterAttributes thisAbsOrigin|

        uiPainterAttributes := eachSpec otherAttributeAt:#uiPainterAttributes.

        eachSpec otherAttributeAt:#uiPainterAttributes put:nil.

        view := self addSpec:eachSpec builder:builder in:containerToPasteInto beforeIndex:beforeIndex.

        beforeIndex notNil ifTrue:[

            beforeIndex := beforeIndex + 1

        ].

        (keepPosition and:[ uiPainterAttributes notNil ]) ifTrue:[

            aPointOrNilOrKeep == #keep ifTrue:[

                newOrigin := uiPainterAttributes at:#origin.

            ] ifFalse:[

                thisAbsOrigin := uiPainterAttributes at:#absOrigin.

                newOrigin := device 

                                    translatePoint:thisAbsOrigin

                                    fromView:self

                                    toView:containerToPasteInto.

            ].

        ] ifFalse:[