"

 COPYRIGHT (c) 1997-1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool2' }"

"{ NameSpace: Smalltalk }"

ResourceSpecEditor subclass:#ImageEditor

	instanceVariableNames:'imageEditView colorMapMode editMode mouseKeyColorMode

		selectedColorIndex postOpenAction imageSeqNr drawingColormap

		lastShiftUsedWrap lastGrabbedScreenArea

		allowedToChangeImageDimensionAndDepth savedImage savedFile'

	classVariableNames:'DefaultRelativeSizes LastColormapMode LastDirectory

		LastSizeString LastURL MaskClipboard'

	poolDictionaries:''

	category:'Interface-UIPainter'

!

!ImageEditor class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997-1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Image Editor allows you to create, design, modify or just inspect images.

    It is also used subclasses as a tool to post-process captured screen images and

    bitmaps in expecco.

    [start with:]

        ImageEditor open

        ImageEditor openOnClass:Icon andSelector:#startIcon

    [see also:]

        ImageEditView Image

    [author:]

        Thomas Zwick, eXept Software AG

        Claus Gittinger, eXept Software AG

"

! !

!ImageEditor class methodsFor:'instance creation'!

openLoadingImageWith:aBlock modal:modalBoolean

    "opens an Image Editor on anImage.

     returns the editor (to access its attributes)"

    |editor|

    editor := self new.

    editor allButOpen.

    aBlock value:editor.

    modalBoolean ifTrue:[

        editor openWindowModal.

    ] ifFalse:[

        editor openWindow.

    ].

    ^ editor

!

openModalOnClass: aClass andSelector: aSelector

    "opens a modal Image Editor on aClass and aSelector.

     Returns the real name of the edited resource method (in case, user changed it)."

    |imageEditor imageEditView className resourceClass resourceSelector| 

    imageEditor := self new.

    aClass isClass  ifTrue: [className := aClass name].

    aClass isString ifTrue: [className := aClass].      

    aClass isNil    ifTrue: [className := ''].      

    imageEditor postOpenAction: [

            imageEditView := imageEditor imageEditView. 

            imageEditor loadFromOrPrepareForClass: aClass andSelector: aSelector

        ].

    imageEditor openModal.

    resourceClass := imageEditView resourceClass.

    resourceSelector := imageEditView resourceSelector.

    (resourceClass isNil or:[resourceSelector isNil]) ifTrue:[^ nil].

    ^ Array with:resourceClass with:resourceSelector

    "

     self openModalOnClass: self andSelector: #leftMouseKeyIcon

    "

!

openModalOnFile:aFileName

    "opens an Image Editor on aFileName"

    self 

        openLoadingImageWith:[:editor | 

            editor loadFromFile:aFileName.

        ] 

        modal:true.

    "

     self openModalOnFile: '../../goodies/bitmaps/gifImages/back.gif'

    "

    "Modified (format): / 18-02-2017 / 00:17:52 / cg"

!

openModalOnImage:anImage

    "opens a modal Image Editor on an image.

     Returns the modified image or nil if unsaved/unchanged"

    |imageEditor imageEditView newImage| 

    imageEditor := self new.

    imageEditor allowedToChangeImageDimensionAndDepth:false.

    imageEditor postOpenAction: [

            imageEditView := imageEditor imageEditView. 

            imageEditor loadFromImage: anImage

        ].

    imageEditor openModal.

    newImage := imageEditor savedImage.

    ^ newImage

!

openOnClass:aClass andSelector:aSelector

    "opens an Image Editor on aClass and aSelector"

    self 

        openLoadingImageWith:[:editor | 

            editor loadFromClass:aClass theNonMetaclass andSelector:aSelector

        ] 

        modal:false.

    "

     self openOnClass:self andSelector:#leftMouseKeyIcon

     self openOnClass:self andSelector:nil

    "

    "Modified: / 16.3.1999 / 21:33:49 / cg"

!

openOnFile:aFileName

    "opens an Image Editor on aFileName"

    self    

        openLoadingImageWith:[:editor | editor loadFromFile:aFileName ] 

        modal:false.

    "

     self openOnFile: '../../goodies/bitmaps/gifImages/back.gif'

    "

    "Modified: / 16.3.1999 / 21:33:25 / cg"

!

openOnImage:anImage

    "opens an Image Editor on anImage"

    self 

        openLoadingImageWith:[:editor | editor loadFromImage: anImage ] 

        modal:false

    "

     self openOnImage: Icon startIcon

    "

    "Modified: / 11.3.1999 / 16:18:33 / cg"

! !

!ImageEditor class methodsFor:'accessing'!

listOfColorMaps

    "returns the list of default color maps for a new image"

    |colorMap|

    (colorMap := OrderedCollection new)

        add: Color black;

        add: Color white;

        add: Color red;

        add: Color green;

        add: Color blue;

        add: Color cyan;

        add: Color yellow;

        add: Color magenta;

        add: (Color redByte: 127 greenByte:   0 blueByte:   0);

        add: (Color redByte:   0 greenByte: 127 blueByte:   0);

        add: (Color redByte:   0 greenByte:   0 blueByte: 127);

        add: (Color redByte:   0 greenByte: 127 blueByte: 127);

        add: (Color redByte: 127 greenByte: 127 blueByte:   0);

        add: (Color redByte: 127 greenByte:   0 blueByte: 127);

        add: (Color redByte: 127 greenByte: 127 blueByte: 127);

        add: (Color redByte: 170 greenByte: 170 blueByte: 170).

    0 to: 5 do: [:r|                                                    

        0 to: 5 do: [:g|

            0 to: 5 do: [:b|

                colorMap add: (Color redByte: (r*255//5) ceiling greenByte: (g*255//5) ceiling blueByte: (b*255//5) ceiling)

            ]

        ]

    ].

    1 to: 25 do: [:g|                             

        colorMap add: (Color redByte: (g*255//26) ceiling greenByte: (g*255//26) ceiling blueByte: (g*255//26) ceiling)

    ].

    ^ Dictionary new

        at: #depth32 put:(FixedPalette redShift:16 redMask:16rFF greenShift:8 greenMask:16rFF blueShift:0 blueMask:16rFF);

        at: #depth24 put:(FixedPalette redShift:16 redMask:16rFF greenShift:8 greenMask:16rFF blueShift:0 blueMask:16rFF);

        at: #masked24 put:(FixedPalette redShift:16 redMask:16rFF greenShift:8 greenMask:16rFF blueShift:0 blueMask:16rFF);

        at: #depth16 put:(FixedPalette redShift:11 redMask:16r1F greenShift:5 greenMask:16r3F blueShift:0 blueMask:16r1F);

        at: #masked16 put:(FixedPalette redShift:11 redMask:16r1F greenShift:5 greenMask:16r3F blueShift:0 blueMask:16r1F);

        at: #depth8  put: colorMap;

        at: #masked8 put: colorMap;

        at: #depth4  put: (colorMap copyFrom: 1 to: 16);

        at: #masked4 put: (colorMap copyFrom: 1 to: 16);

        at: #depth2  put: (colorMap copyFrom: 1 to: 4);

        at: #masked2 put: (colorMap copyFrom: 1 to: 4);

        at: #depth1  put: (colorMap copyFrom: 1 to: 2);

        at: #masked1 put: (colorMap copyFrom: 1 to: 2);

        yourself

!

listOfDefaultSizes

    "returns the list of default sizes for a new image"

    ^ #('8x8' '16x16' '22x22' '32x32' '48x48' '64x64')

    "Modified: / 31.7.1998 / 01:57:34 / cg"

!

namesOfColorMaps

    ^ Dictionary new

        at: #depth32 put: '32-plane (rgba)';

        at: #depth24 put: '24-plane';

        at: #masked24 put: '24-plane + mask';

        at: #depth16 put: '16-plane';

        at: #masked16 put: '16-plane + mask';

        at: #depth8  put: ' 8-plane';

        at: #masked8 put: ' 8-plane + mask';

        at: #depth4  put: ' 4-plane';

        at: #masked4 put: ' 4-plane + mask';

        at: #depth2  put: ' 2-plane';

        at: #masked2 put: ' 2-plane + mask';

        at: #depth1  put: ' 1-plane';

        at: #masked1 put: ' 1-plane + mask' ;

        yourself

! !

!ImageEditor class methodsFor:'help specs'!

flyByHelpSpec

    <resource: #programHelp>

    ^super flyByHelpSpec addPairsFrom:(self helpPairs)

    "Modified: / 16-02-2017 / 12:30:55 / cg"

!

helpPairs

    "This resource specification was automatically generated

     by the UIHelpTool of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIHelpTool may not be able to read the specification."

    "

     UIHelpTool openOnClass:ImageEditor

    "

    <resource: #help>

    ^ #(

#colorMap

'ColorMap functions'

#colorMap1

'Convert to depth-1 image'

#colorMap1M

'Convert to depth-1 image plus mask'

#colorMap2

'Convert to depth-2 image'

#colorMap24

'Convert to depth-24 image (rgb)'

#colorMap2M

'Convert to depth-2 image plus mask'

#colorMap32

'Convert to depth-32 image (rgba)'

#colorMap4

'Convert to depth-4 image'

#colorMap4M

'Convert to depth-4 image plus mask'

#colorMap8

'Convert to depth-8 image'

#colorMap8M

'Convert to depth-8 image plus mask'

#colorMapTable

'Shows a list of used colors of the image'

#compressColormap

'Remove unneeded entries from the colorMap'

#cropAll

#cropBottom

#cropLeft

#cropManual

'Specify border(s) to remove.'

#cropRight

#cropTop

#drawModeBox

'Rectangle Drawing Mode'

#drawModeCircle

'Circle Drawing Mode'

#drawModeCopy

'Area Copy Mode'

#drawModeFill

'Flood Fill Mode'

#drawModeFilledBox

'Filled Rectangle Drawing Mode'

#drawModeFilledCircle

'Filled Circle Drawing Mode'

#drawModeMaskOutsideCircle

'Mask everything outside a Circle'

#drawModeMaskOutsideRectangle

'Mask everything outside a Rectangle'

#drawModePaste

'Paste Mode'

#drawModePasteUnder

'Paste-Under Mode'

#drawModePasteWithMask

'Paste-with-Mask Mode'

#drawModePoint

'Point Drawing Mode'

#drawModeSpecial

'Special operations (select rectangle, then choose operation)'

#drawModeSpray

'Spray Drawing Mode'

#edit3DProjection

'Generate a 3D projection'

#editFlipHorizontal

'Flip the image horizontally'

#editFlipVertical

'Flip the image vertically'

#editMagnifyImage

'Magnify the image'

#editNegate

'Invert the images colors'

#editResize

'Resize the image (preserving the old image)'

#editRotate

'Rotate the image'

#fileEditMask

'Load Mask from a File'

#fileGrabImageFromScreen

'Pick an image from the screen (specify area)'

#fileGrabImageFromWindow

'Pick an image from a window on the screen (click on window)'

#fileLoadFromClass

'Select and load an image from a resource method'

#fileLoadFromFile

'Select and load an image from a file'

#fileLoadFromURL

'Load an image from the net, given its URL'

#fileNewImage

'Create a new image'

#fileNewImageFromClipboard

'Create a new image and initialize it from the clipboard'

#fileNewMaskFromClipboard

'Paste the image in the clipboard as a mask. Must be a depth-1 image'

#filePrint

#filePrint

#fileSave

'Save the image'

#fileSaveAs

'Save the image to a file'

#fileSaveButtonImageAs

'Save an image of a button with the image to a file (for html use)'

#fileSaveMaskAs

'Save the mask of the image to a file'

#fileSaveMethod

'Save the image as resource method in the current class and selector'

#fileSaveMethodAs

'Save the image as resource method in a class'

#floodFillMaxError