"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool2' }"

ApplicationModel subclass:#DirectoryView

	instanceVariableNames:'directory selectedFileFilter readTask monitoring

		monitoringTimeBlock fileDoubleClickAction fileSelectAction

		fileFilterSelectAction fileAttributes'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Dialogs'

!

Object subclass:#FileRow

	instanceVariableNames:'fileName size modified iconKey imageFromFile group owner

		permissions baseName'

	classVariableNames:'MaxImageFileSize'

	poolDictionaries:''

	privateIn:DirectoryView

!

!DirectoryView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    documentation to be added.

    [author:]

        Thomas Zwick

"

! !

!DirectoryView class methodsFor:'instance creation'!

openOnDirectory: aDirectoryString

    "open a DirectoryView for a aDirectoryString"

    ^ (self new directory: aDirectoryString) open

    "

     self openOnDirectory: '/etc'

    "

    "Modified: / 28.1.1998 / 15:44:53 / stefan"

! !

!DirectoryView class methodsFor:'interface specs'!

windowSpec

    "This resource specification was automatically generated

     by the UIPainter of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIPainter may not be able to read the specification."

    "

     UIPainter new openOnClass:DirectoryView andSelector:#windowSpec

     DirectoryView new openInterface:#windowSpec

     DirectoryView open

    "

    <resource: #canvas>

    ^ 

     #(#FullSpec

        #name: #windowSpec

        #window: 

       #(#WindowSpec

          #label: 'Directory View'

          #name: 'Directory View'

          #min: #(#Point 10 10)

          #max: #(#Point 1152 900)

          #bounds: #(#Rectangle 13 23 413 323)

        )

        #component: 

       #(#SpecCollection

          #collection: #(

           #(#DataSetSpec

              #name: 'filesDataSetView'

              #layout: #(#LayoutFrame 0 0.0 24 0.0 -2 1.0 0 1.0)

              #model: #selectionOfFile

              #menu: #fileListMenu

              #hasHorizontalScrollBar: true

              #hasVerticalScrollBar: true

              #miniScrollerHorizontal: true

              #dataList: #listOfFiles

              #useIndex: false

              #has3Dsepartors: false

              #doubleClickSelector: #fileDoubleClicked

              #columnHolder: #fileAttributeColumns

              #valueChangeSelector: #fileSelected

              #verticalSpacing: 1

            )

           #(#ComboBoxSpec

              #name: 'formatComboBox'

              #layout: #(#LayoutFrame 63 0.0 0 0 0 1.0 22 0)

              #model: #selectionOfFileFilter

              #immediateAccept: false

              #acceptOnTab: false

              #acceptOnPointerLeave: false

              #comboList: #listOfFileFilters

            )

           #(#LabelSpec

              #label: 'Filter: '

              #name: 'filterLabel'

              #layout: #(#LayoutFrame 0 0 0 0 62 0 22 0)

              #adjust: #right

            )

           )

        )

      )

    "Modified: / 11.2.2000 / 00:11:43 / cg"

! !

!DirectoryView class methodsFor:'list specs'!

tableColumnsForFileAttributes

    "This resource specification was automatically generated

     by the DataSetBuilder of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the DataSetBuilder may not be able to read the specification."

    "

     DataSetBuilder new openOnClass:DirectoryView andSelector:#tableColumnsForFileAttributes

    "

    <resource: #tableColumns>

    ^ #(

        #(#DataSetColumnSpec

           #label: ''

           #width: 30

           #height: 22

           #printSelector: #iconOn:

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'File name'

           #labelAlignment: #left

           #minWidth: 150

           #model: #baseName

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'Size'

           #labelAlignment: #left

           #width: 70

           #model: #size

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'Modified'

           #labelAlignment: #left

           #model: #modified

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'Permissions'

           #labelAlignment: #left

           #width: 85

           #model: #permissions

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'Owner'

           #labelAlignment: #left

           #width: 50

           #model: #owner

           #canSelect: false

       )

        #(#DataSetColumnSpec

           #label: 'Group'

           #labelAlignment: #left

           #width: 50

           #model: #group

           #canSelect: false

       )

     )

! !

!DirectoryView class methodsFor:'menu specs'!

fileListMenu

    "This resource specification was automatically generated

     by the MenuEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the MenuEditor may not be able to read the specification."

    "

     MenuEditor new openOnClass:DirectoryView andSelector:#fileListMenu

     (Menu new fromLiteralArrayEncoding:(DirectoryView fileListMenu)) startUp

    "

    <resource: #menu>

    ^ 

     #(#Menu

        #(

         #(#MenuItem

            #label: 'Update'

            #translateLabel: true

            #value: #updateFileList

          )

         )

        nil

        nil

      )

    "Created: / 11.2.2000 / 00:11:39 / cg"

! !

!DirectoryView methodsFor:'accessing'!

directory: aDirectory

    directory := aDirectory asFilename asAbsoluteFilename name

!

fileAttributes: anArray

    fileAttributes := anArray

!

fileDoubleClickAction: anActionBlock

    fileDoubleClickAction := anActionBlock

!

fileFilterSelectAction: anActionBlock

    fileFilterSelectAction := anActionBlock

!

fileSelectAction: anActionBlock

    fileSelectAction := anActionBlock

!

listOfFileFilters: aCollection

    self listOfFileFilters contents: aCollection.

    self selectionOfFileFilter value: (self listOfFileFilters at: 1 ifAbsent: [nil]).

!

monitoring: aBoolean

    aBoolean

    ifTrue:

    [

        monitoringTimeBlock := [self readDirectory].

        self readDirectory.

    ]

    ifFalse:

    [

        monitoring ifTrue:

        [

            Processor removeTimedBlock:monitoringTimeBlock.

            monitoringTimeBlock := nil

        ]

    ].

    monitoring := aBoolean.

! !

!DirectoryView methodsFor:'aspects'!

fileAttributeColumns

    |holder|

    (holder := builder bindingAt:#fileAttributeColumns) isNil ifTrue:[

        |fileAttributeColumns|

        builder aspectAt:#fileAttributeColumns put:(holder := List new).

        fileAttributeColumns := self class tableColumnsForFileAttributes collect: [:i| i decodeAsLiteralArray].

        holder add: fileAttributeColumns first.

        fileAttributeColumns do:

        [:col|

            (fileAttributes includes: col label) ifTrue: [holder add: col]

        ].

        holder do: [:col| col label: ' ', col label]

    ].

    ^ holder

!

listOfFileFilters

    |holder|          

    (holder := builder bindingAt:#listOfFileFilters) isNil ifTrue:[

        builder aspectAt:#listOfFileFilters put:(holder :=  List with: '*').

    ].

    ^ holder

!

listOfFiles

    |holder|

    (holder := builder bindingAt:#listOfFiles) isNil ifTrue:[

        builder aspectAt:#listOfFiles put:(holder :=  List new).

    ].

    ^ holder

!

selectionOfFile

    |holder|

    (holder := builder bindingAt:#selectionOfFile) isNil ifTrue:[

        builder aspectAt:#selectionOfFile put:(holder :=  ValueHolder new).

    ].

    ^ holder

!

selectionOfFileFilter

    |holder|

    (holder := builder bindingAt:#selectionOfFileFilter) isNil ifTrue:[

        builder aspectAt:#selectionOfFileFilter put:

        (holder := AspectAdaptor new subject:self; forAspect:#selectedFileFilter).

        selectedFileFilter := '*'.

    ].

    ^ holder

! !

!DirectoryView methodsFor:'callbacks'!

fileDoubleClicked

    (fileDoubleClickAction notNil and: [self selectionOfFile value notNil]) 

    ifTrue: 

    [

        fileDoubleClickAction numArgs = 0

        ifTrue:

        [

            fileDoubleClickAction value

        ].

        fileDoubleClickAction numArgs = 1

        ifTrue:

        [                

            fileDoubleClickAction value: (directory asFilename construct: self selectionOfFile value baseName) name

        ]

    ]

!

fileSelected

    (fileSelectAction notNil and: [self selectionOfFile value notNil]) 

    ifTrue: 

    [

        fileSelectAction numArgs = 0

        ifTrue:

        [

            fileSelectAction value

        ].

        fileSelectAction numArgs = 1

        ifTrue:

        [

            fileSelectAction value: (directory asFilename construct: self selectionOfFile value baseName) name

        ]

    ]

! !

!DirectoryView methodsFor:'initialization'!

initialize

    super initialize.

    self createBuilder.

    directory :=  directory ? '.' asFilename asAbsoluteFilename directoryName.

    monitoring := false.

    fileAttributes := #('File name' 'Size' 'Modified').

    self selectionOfFileFilter value: (self listOfFileFilters at: 1 ifAbsent: [nil]).

    "Modified: / 20.6.1998 / 14:46:10 / cg"

! !

!DirectoryView methodsFor:'menu actions'!

updateFileList

    DirectoryContents flushCache.

    self readDirectory

    "Created: / 11.2.2000 / 00:12:46 / cg"

    "Modified: / 11.2.2000 / 00:14:32 / cg"

! !

!DirectoryView methodsFor:'private'!

readDirectory

    |allFiles foundFiles filterList dir|    

    allFiles := Set new.

    foundFiles := Set new.

    "/ filterList := self listOfFileFilters value.

    filterList := self selectedFileFilter asCollectionOfSubstringsSeparatedBy:$;.

    filterList := filterList collect:[:pattern | pattern withoutSeparators].

    self withCursor:Cursor read do:[ 

        (dir := DirectoryContents directoryNamed: directory) notNil ifTrue:[

"/            dir filesAndBasenamesDo:[:file :name|      

"/                filterList do:[:filter|

"/                    ((filter match:name) and:[(foundFiles includes: name) not])

"/                    ifTrue:[

"/                        foundFiles add: name

"/                    ].

"/                ].

"/            ].

            dir filesAndBasenamesDo:[:file :name|      

                allFiles add: name

            ].

            Filename isCaseSensitive ifFalse:[

                filterList do:[:filter|

                    |lcFilter|

                    lcFilter := filter asLowercase.

                    foundFiles

                        addAll:(allFiles 

                                    select:[:name | lcFilter match:name asLowercase]

                                ).

                ]

            ] ifTrue:[

                filterList do:[:filter|

                    foundFiles

                        addAll:(allFiles 

                                    select:[:name | filter match:name]

                                ).

                ]

            ].

            foundFiles := foundFiles asOrderedCollection sort.

            dir := directory asFilename.

            self listOfFiles contents: (foundFiles collect:[:name| FileRow new fileName:(dir construct:name)])

        ]

    ]

    "Modified: / 23.9.1998 / 17:00:42 / cg"

!

readMonitoringDirectory

    |readBlock|

    readTask notNil ifTrue: [readTask terminate].

    readBlock :=

    [

        |dir currentFilenames oldListOfFiles|

        dir := directory asFilename.

        currentFilenames := OrderedCollection new.

        (dir isReadable and:[dir isExecutable]) ifTrue:

        [

            self listOfFileFilters value do:

            [:filter|

                (dir filesMatchingWithoutDotDirs: filter) do:

                [:aFileName|

                    |file|

                    (file := dir construct: aFileName) isDirectory

                    ifFalse:

                    [

                        currentFilenames add: file

                    ]

                ].

            ].

        ].

        oldListOfFiles := self listOfFiles copy.

        (currentFilenames asSortedCollection: [:f1 :f2| f1 baseName < f2 baseName]) asSet do: 

        [:fileName| 

            (oldListOfFiles detect: [:fileRow| fileRow fileName = fileName] ifNone: nil) isNil

            ifTrue:                                                                             

            [

                |nearestFileRow r|

                nearestFileRow := self listOfFiles indexOf: (self listOfFiles detect: [:fileRow| fileRow baseName > fileName baseName] ifNone: nil).

                nearestFileRow = 0

                ifTrue: [self listOfFiles add: (r := FileRow new fileName: fileName asFilename)]

                ifFalse: [self listOfFiles add: (r := FileRow new fileName: fileName asFilename) beforeIndex: nearestFileRow].

                monitoring ifTrue: [self selectionOfFile value: r].