ObjectView subclass:#UIObjectView

	instanceVariableNames:'saveSelection inputView enableChannel undoHistory copiedExtent

		copiedLayout actionData createClass clipChildren

		selectionHiddenLevel setOfSuperViewsSizeChanged'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-UIPainter'

!

Object subclass:#UndoHistory

	instanceVariableNames:'history transaction enabled'

	classVariableNames:''

	poolDictionaries:''

	privateIn:UIObjectView

!

Object subclass:#Transaction

	instanceVariableNames:'type text actions'

	classVariableNames:''

	poolDictionaries:''

	privateIn:UIObjectView::UndoHistory

!

!UIObjectView class methodsFor:'conversion'!

asLayoutFrameFromView:aView

    "convert layout from aView to a frameLayout. On success the frameLayout is

     returned otherwise nil

    "

    |lF lO rF rO tF tO bF bO type layout newLyt|

    type   := self layoutType:aView.

    layout := aView geometryLayout.

    layout isNil ifTrue:[

        type == #Extent ifTrue:[

            layout := aView bounds asLayout

        ]

    ].

    (type isNil or:[layout isNil]) ifTrue:[

        ^ nil

    ].

    type == #LayoutFrame ifTrue:[

        ^ layout copy

    ].

    layout isLayout ifFalse:[

        type == #Rectangle ifTrue:[

            lO := layout left.

            tO := layout top.

            rO := layout right.

            bO := layout bottom.

        ] ifFalse:[

            lO := layout x.

            tO := layout y.

            rO := lO + aView extent x.

            bO := tO + aView extent y.

        ].

        ^ LayoutFrame leftFraction:0 offset:lO  rightFraction:0 offset:rO

                       topFraction:0 offset:tO bottomFraction:0 offset:bO

    ].

    lF := layout leftFraction.

    lO := layout leftOffset.

    tF := layout topFraction.

    tO := layout topOffset.

    bF := tF.

    bO := tO + aView extent y.

    rF := lF.

    rO := lO + aView extent x.

    newLyt := LayoutFrame leftFraction:lF offset:lO  rightFraction:rF offset:rO

                           topFraction:tF offset:tO bottomFraction:bF offset:bO.

    (    (type == #AlignmentOrigin)

     and:[layout leftAlignmentFraction ~~ 0

      or:[layout topAlignmentFraction  ~~ 0]]

    ) ifTrue:[

        |svRc prBd dlta|

        svRc := aView superView viewRectangle.

        prBd := aView preferredBounds.

        dlta := (  ((layout rectangleRelativeTo:svRc preferred:prBd) corner)

                 - ((newLyt rectangleRelativeTo:svRc preferred:prBd) corner)

                ) rounded.

        newLyt leftOffset:(lO + dlta x).

        newLyt rightOffset:(rO + dlta x).

        newLyt topOffset:(tO + dlta y).

        newLyt bottomOffset:(bO + dlta y).

    ].

  ^ newLyt.

    "Modified: 28.3.1997 / 19:52:48 / cg"

! !

!UIObjectView class methodsFor:'defaults'!

defaultGrid

    ^ 4 @ 4

!

gridShown

    ^ false

!

handleSize

    "size of blob drawn for handles"

    ^ 4

!

hitDelta

    ^ 4

! !

!UIObjectView class methodsFor:'queries'!

layoutType:aView

    "returns layout type of aView or nil

    "

    |layout spec superView|

    aView notNil ifTrue:[

        layout := aView geometryLayout.

        layout notNil ifTrue:[

            layout isLayout ifTrue:[

                layout isLayoutFrame        ifTrue:[ ^ #LayoutFrame ].

                layout isAlignmentOrigin    ifTrue:[ ^ #AlignmentOrigin ].

                layout isLayoutOrigin       ifTrue:[ ^ #LayoutOrigin ].

            ] ifFalse:[

                layout isRectangle          ifTrue:[ ^ #Rectangle ].

                layout isPoint              ifTrue:[ ^ #Point ].

            ]

        ] ifFalse:[

            (superView := aView superView) notNil ifTrue:[

                spec := superView specClass.

                spec canResizeSubComponents ifTrue:[

                    ^ #Extent

                ]

            ]

        ]

    ].

    ^ nil

    "Modified: 28.2.1997 / 13:02:16 / cg"

! !

!UIObjectView methodsFor:'accessing'!

enableChannel

    "returns the channel which keeps false if running test otherwise true

    "

  ^ enableChannel

!

gridAlign

    "returns state of aligning to grid

    "

    ^ aligning

!

gridAlign:aBool

    "change state of aligning to grid

    "

    aBool ifTrue:[self alignOn]

         ifFalse:[self alignOff]

!

gridParameters

    "used by defineGrid, and in a separate method for

     easier redefinition in subclasses. 

     Returns the grid parameters in an array of 7 elements,

     which control the appearance of the grid-pattern.

     the elements are:

        bigStepH        number of pixels horizontally between 2 major steps

        bigStepV        number of pixels vertically between 2 major steps

        littleStepH     number of pixels horizontally between 2 minor steps

        littleStepV     number of pixels vertically between 2 minor steps

        gridAlignH      number of pixels for horizontal grid align (pointer snap)

        gridAlignV      number of pixels for vertical grid align (pointer snap)

        docBounds       true, if document boundary should be shown

     if littleStepH/V are nil, only bigSteps are drawn.

    "

    ^ #(10 10 nil nil 10 10 false)

!

gridShown:aBool

    "change visibility of grid

    "

    aBool ifTrue:[self showGrid]

         ifFalse:[self hideGrid]

!

hideGrid

    "hide grid

    "

    gridShown ifTrue:[

        self withSelectionHiddenDo:[super hideGrid]

    ]

!

showGrid

    "show grid

    "

    self withSelectionHiddenDo:[super showGrid]

! !

!UIObjectView methodsFor:'accessing behavior'!

enabled

    ^ enableChannel value

!

enabled:aState

    "set the modification / test mode

    "

    (aState == enableChannel value) ifFalse:[

        aState ifFalse:[

            saveSelection := selection copy

        ].

        enableChannel value:aState.

        aState ifFalse:[

            self unselect.

            inputView unrealize

        ] ifTrue:[

            inputView raise.

            inputView realize.

            self select:saveSelection.

        ]

    ]

!

testMode

    "returns true if running test

    "

    ^ enableChannel value not

!

testMode:aBoolean

    "change test mode

    "

    self enabled:(aBoolean not)

! !

!UIObjectView methodsFor:'blocked'!

addObject:anObject

    "add the argument, anObject to the contents - with redraw

    "

    self halt

!

addObjectWithoutRedraw:anObject

    "add the argument, anObject to the contents - with redraw

    "

    self halt

! !

!UIObjectView methodsFor:'event handling'!

elementChangedSize:aView

    "some element has changed its size; collect them during selectionHiddenLevel 

     is on

    "

    selectionHiddenLevel ~~ 0 ifTrue:[

        setOfSuperViewsSizeChanged add:aView superView

    ] ifFalse:[

        aView superView sizeChanged:nil

    ]

!

exposeX:x y:y width:w height:h

    "handle an expose event from device; redraw selection

    "

    super exposeX:x y:y width:w height:h.

"/    selectionHiddenLevel == 0 ifTrue:[

        self selectionDo:[:v | self showSelected:v]

"/    ]

!

keyPress:key x:x y:y

    "any key pressed

    "

    <resource: #keyboard ( #Delete #BackSpace #Cut #Copy #Paste ) >

    (key == #Cut or:[key == #Delete or:[key == #BackSpace]]) ifTrue: [

        ^ self deleteSelection

    ].

    key == #Copy  ifTrue:[ ^ self copySelection].

    key == #Paste ifTrue:[ ^ self pasteBuffer].

    super keyPress:key x:x y:y

!

processEvent:anEvent

    "catch expose events for components, and redraw its handles after

     the redraw when this happens

    "

    |view|

    selection notNil ifTrue:[

        anEvent type == #damage ifTrue:[

            view := anEvent view.

            (selection == view

            or:[selection isCollection

                and:[selection includes:view]]) ifTrue:[

                    self showSelected:view

            ]

        ]

    ].

    ^ false.

!

sizeChanged:how

    "size of a view(s) changed

    "

    self withSelectionHiddenDo:[

        super sizeChanged:how

    ]

! !

!UIObjectView methodsFor:'initialization'!

initialize

    "setup attributes

    "

    super initialize.

    "funny: since I do not want the created widgets to get pointer

     events, I put an InputView on top of them, which catches those events

     and passes them back to me - have to take care, that this inputView

     is always on top

    "

    inputView := InputView origin:0.0@0.0 extent:1.0@1.0 in:self.

    setOfSuperViewsSizeChanged := IdentitySet new.

    inputView eventReceiver:self.

    inputView enableButtonEvents.

    inputView enableButtonMotionEvents.

    self setDefaultActions.

    undoHistory          := UndoHistory new.

    enableChannel        := true asValue.

    clipChildren         := true.

    selectionHiddenLevel := 0.

    (self class gridShown) ifTrue:[

        super showGrid

    ].

!

realize

    super realize.

    self windowGroup postEventHook:self

! !

!UIObjectView methodsFor:'misc'!

cursor:aCursor

    "set cursor

    "

    inputView realized ifTrue:[

        inputView cursor:aCursor

    ].

    super cursor:aCursor

!

invertOutlineOf:anObject

    "invert outline of an object

    "

    |wasClipped delta|

    (wasClipped := clipChildren) ifTrue:[

        self clippedByChildren:(clipChildren := false).

    ].

    delta := (anObject originRelativeTo:self) - anObject origin.

    self xoring:[

        self displayRectangle:((anObject origin + delta) extent:anObject extent).

    ].

    wasClipped ifTrue:[

        self clippedByChildren:(clipChildren := true).

    ].

    "Modified: 5.9.1995 / 12:25:25 / claus"

!

minSetOfSuperViews:setOfViews

    setOfViews isCollection ifFalse:[

        setOfViews notNil ifTrue:[^ Array with:setOfViews]

                         ifFalse:[^ nil]

    ].

  ^ setOfViews select:[:aView|

        (setOfViews detect:[:v|aView isComponentOf:v] ifNone:nil) isNil

    ]

!

setDefaultActions

    "set default actions

    "

    pressAction      := [:pressPoint | self startSelectOrMove:pressPoint].

    shiftPressAction := [:pressPoint | self startSelectMoreOrMove:pressPoint].

    motionAction     := [:movePoint  | nil].

    releaseAction    := [nil].

    keyPressAction   := nil.

    self cursor:Cursor normal.

! !

!UIObjectView methodsFor:'object creation'!

actionCreate:anObject frame:aFrame delta:aDelta

    "create and initialize action data

    "

    |extent x y selectors values|

"minimum extent

"

    (anObject specClass supportsSubComponents) ifTrue:[

        extent := 25@25

    ] ifFalse:[

        extent := self extent.

        x := extent x // 3.

        y := extent y // 3.

        extent := anObject preferredExtent.

        (extent x > x) ifTrue:[extent x:x].

        (extent y > y) ifTrue:[extent y:y].

    ].

"setup structure

"

    selectors := #( object frame delta vertical horizontal minExtent ).

    values    := Array new:(selectors size).

    values at:1 put:anObject.

    values at:2 put:aFrame.

    values at:3 put:aDelta.

    values at:4 put:(self isVerticalResizable:anObject).

    values at:5 put:(self isHorizontalResizable:anObject).

    values at:6 put:extent.

    actionData := Structure newWith:selectors values:values.

"can change cursor dependent on vertical/horizontal resizing