UIPainterView.st
author ca
Thu, 17 Jul 1997 12:05:00 +0200
changeset 218 5c88856b360f
parent 212 1836a16763cc
child 219 7b38043ae232
permissions -rw-r--r--
access MenuEditor from any specification; common changes

"
 COPYRIGHT (c) 1995 by Claus Gittinger / eXept Software AG
              All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

UIObjectView subclass:#UIPainterView
	instanceVariableNames:'listHolder superclassName className methodName categoryName'
	classVariableNames:'HandCursor'
	poolDictionaries:''
	category:'Interface-UIPainter'
!

MultiSelectionInList subclass:#ListHolder
	instanceVariableNames:'painter propertyList masterElement disabledChanged'
	classVariableNames:''
	poolDictionaries:''
	privateIn:UIPainterView
!

Object subclass:#ViewProperty
	instanceVariableNames:'view spec identifier'
	classVariableNames:'Identifier'
	poolDictionaries:''
	privateIn:UIPainterView
!

!UIPainterView class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1995 by Claus Gittinger / eXept Software AG
              All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    buildIn view used by the UIPainter; from this view, the layout of the
    new application derives from.

    [see also:]
        UIBuilder
        UIObjectView

    [author:]
        Claus Gittinger
        Claus Atzkern
"
! !

!UIPainterView class methodsFor:'defaults'!

defaultMenuMessage   
    "This message is the default yo be sent to the menuHolder to get a menu
    "
    ^ #showMiddleButtonMenu


! !

!UIPainterView class methodsFor:'menu specs'!

menu

  ^ #(#Menu #(
        #(#MenuItem
                #'label:' 'copy'
                #'value:' #copySelection
                #'shortcutKeyCharacter:' #Copy
         )
        #(#MenuItem
                #'label:' 'cut'
                #'value:' #deleteSelection
                #'shortcutKeyCharacter:' #Cut
         )
        #(#MenuItem
                #'label:'   'paste'
                #'nameKey:' #paste
                #'value:'   #paste
                #'submenu:'
                        #(#Menu #(
                                #(#MenuItem
                                        #'label:' 'paste'
                                        #'value:' #pasteBuffer
                                        #'shortcutKeyCharacter:' #Paste
                                        #'activeHelpKey:' #pasteBuffer
                                 )
                                #(#MenuItem
                                        #'label:' 'keep layout'
                                        #'value:' #pasteWithLayout
                                        #'activeHelpKey:' #pasteWithLayout
                                 )
                                )
                                nil 
                                nil
                         )
          )
         #(#MenuItem
                #'label:'   'undo'
                #'nameKey:' #undo
                #'value:'   #undoLast)
         #(#MenuItem
                #'label:' 'arrange'
                #'value:' #arrange
                #'submenu:'
                        #(#Menu #(
                                #(#MenuItem
                                        #'label:' 'to front'
                                        #'value:' #raiseSelection
                                 )
                                #(#MenuItem
                                        #'label:' 'to back'
                                        #'value:' #lowerSelection
                                 )
                                )
                                nil
                                nil
                          )
          )
         #(#MenuItem
                #'label:' 'dimension'
                #'value:' #dimension
                #'submenu:'
                        #(#Menu #(
                                #(#MenuItem
                                        #'label:' 'default extent'
                                        #'value:' #setToDefaultExtent
                                        #'activeHelpKey:' #setToDefaultExtent
                                 )
                                #(#MenuItem
                                        #'label:' 'default width'
                                        #'value:' #setToDefaultWidth
                                        #'activeHelpKey:' #setToDefaultWidth
                                 )
                                #(#MenuItem
                                        #'label:' 'default height'
                                        #'value:' #setToDefaultHeight
                                        #'activeHelpKey:' #setToDefaultHeight
                                 )
                                #(#MenuItem
                                        #'label:' 'copy extent'
                                        #'value:' #copyExtent
                                        #'activeHelpKey:' #copyExtent
                                 )
                                #(#MenuItem
                                        #'label:' 'paste extent'
                                        #'value:' #pasteExtent
                                        #'activeHelpKey:' #pasteExtent
                                 )
                                #(#MenuItem
                                        #'label:' 'paste width'
                                        #'value:' #pasteWidth
                                        #'activeHelpKey:' #pasteWidth
                                 )
                                #(#MenuItem
                                        #'label:' 'paste height'
                                        #'value:' #pasteHeight
                                        #'activeHelpKey:' #pasteHeight
                                 )
                                #(#MenuItem
                                        #'label:' 'copy  layout'
                                        #'value:' #copyLayout
                                        #'activeHelpKey:' #copyLayout
                                 )
                                #(#MenuItem
                                        #'label:' 'paste layout'
                                        #'value:' #pasteLayout
                                        #'activeHelpKey:' #pasteLayout
                                 )
                                )
                                #(3 1 3) 
                                nil
                        )
         )
        #(#MenuItem
                #'label:' 'align'
                #'value:' #align
                #'submenu:'
                        #(#Menu #(
                                #(#MenuItem
                                        #'value:' #alignSelectionLeft
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignL 'align left' )
                                        #'activeHelpKey:' #alignSelectionLeft
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionRight
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignR 'align right' )
                                        #'activeHelpKey:' #alignSelectionRight
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionLeftAndRight
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignLR 'align left & right' )
                                        #'activeHelpKey:' #alignSelectionLeftAndRight
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionTop
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignT 'align top' )
                                        #'activeHelpKey:' #alignSelectionTop
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionBottom
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignB 'align bottom' )
                                        #'activeHelpKey:' #alignSelectionBottom
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionTopAndBottom
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignTB 'align top & bottom' )
                                        #'activeHelpKey:' #alignSelectionTopAndBottom
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionCenterHor
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignCenterH 'align centered horizontal' )
                                        #'activeHelpKey:' #alignSelectionCenterHor
                                 )
                                #(#MenuItem
                                        #'value:' #alignSelectionCenterVer
                                        #'labelImage:' #( ResourceRetriever UIPainter iconAlignCenterV 'align centered vertical' )
                                        #'activeHelpKey:' #alignSelectionCenterVer
                                 )
                                #(#MenuItem
                                        #'label:' 'spread horizontal'
                                        #'value:' #spreadSelectionHor
                                        #'activeHelpKey:' #spreadSelectionHor
                                 )
                                #(#MenuItem
                                        #'label:' 'spread vertical'
                                        #'value:' #spreadSelectionVer
                                        #'activeHelpKey:' #spreadSelectionVer
                                 )
                                #(#MenuItem
                                        #'label:' 'center horizontal in frame'
                                        #'value:' #centerSelectionHor
                                        #'activeHelpKey:' #centerSelectionHor
                                 )
                                #(#MenuItem
                                        #'label:' 'center vertical in frame'
                                        #'value:' #centerSelectionVer
                                        #'activeHelpKey:' #centerSelectionVer
                                 )
                                )
                               #(8 2)
                               nil
                        )
         )
        )
        #(4) 
        nil
    )
! !

!UIPainterView methodsFor:'accessing'!

application
    ^ nil

    "Modified: 6.9.1995 / 00:46:44 / claus"
!

applicationName
    ^ self className
!

applicationName:aName
    self className:aName
!

className
    ^ className
!

className:aName
    className := aName
!

className:aClassName superclassName:aSuperclassName selector:aSelector
    className      := aClassName.
    superclassName := aSuperclassName.
    methodName     := aSelector.

!

listHolder
    ^ listHolder
!

methodName
    ^ methodName
!

methodName:aName
    methodName := aName
!

selectNames:aStringOrCollection
    |prop coll s|

    (aStringOrCollection isNil or:[aStringOrCollection isEmpty]) ifTrue:[
        ^ self select:nil
    ].

    (s := aStringOrCollection) isString ifFalse:[
        s size == 1 ifTrue:[
            s := s first
        ] ifFalse:[
            coll := OrderedCollection new.

            s do:[:aName|
                (prop := self propertyOfName:aName) notNil ifTrue:[
                    coll add:(prop view)
                ]
            ].
            coll size == 1 ifTrue:[ ^ self select:(coll at:1) ].
            coll size == 0 ifTrue:[ ^ self select:nil ].

          ^ self select:coll.
        ]
    ].

    prop := self propertyOfName:s.
    prop isNil ifTrue:[^ self select:nil]
              ifFalse:[^ self select:(prop view)]

! !

!UIPainterView methodsFor:'change & update'!

changed:aParameter
    aParameter == #layout ifTrue:[
        listHolder removeDependent:self.
        listHolder changed:aParameter.
        listHolder addDependent:self.
    ] ifFalse:[
        super changed:aParameter
    ]
!

selectionChanged
    "selection has changed
    "
    |newSel|

    self selectionDo:[:aView||p|
        (p := self propertyOfView:aView) notNil ifTrue:[
            newSel isNil ifTrue:[
                newSel := OrderedCollection new
            ].
            newSel add:(listHolder indexOfName:(p name))
        ]
    ].
    listHolder removeDependent:self.
    listHolder selectionIndex:newSel.
    listHolder addDependent:self.
!

update:what with:aParm from:aSender
    |loIdx newSel|

    (what == #selectionIndex and:[aSender == listHolder]) ifFalse:[
        ^ self
    ].
    loIdx := listHolder selectionIndex.

    loIdx size ~~ 0 ifTrue:[
        newSel := loIdx collect:[:i|(listHolder propertyAt:i) view]
    ].
    self updateSelectionFrom:newSel.
!

updateSelectionFrom:aSel
    "update selection from a new selection
    "
    |csel|

    selectionHiddenLevel == 0 ifTrue:[
        aSel isCollection ifTrue:[
            self selectionDo:[:el|
                (aSel includes:el) ifFalse:[self showUnselected:el]
            ]
        ] ifFalse:[
            self selectionDo:[:el|
                aSel == el ifFalse:[self showUnselected:el]
            ]
        ]
    ].
    self setSelection:aSel withRedraw:false.
    self showSelection
! !

!UIPainterView methodsFor:'copy & cut & paste'!

copySelection
    "copy the selection into the cut&paste-buffer
    "
    |specs coll|

    coll := self minSetOfSuperViews:(self selection).

    coll notNil ifTrue:[
        self select:nil.
        specs := coll collect:[:aView| self fullSpecFor:aView ].
        self setSelection:specs
    ].


!

deleteSelection
    "delete the selection; copy the selection into the cut&paste-buffer
     and open a transaction
    "
    |specs coll|

    coll := self minSetOfSuperViews:(self selection).

    coll notNil ifTrue:[
        listHolder disableNotificationsWhileEvaluating:[
            self select:nil.
            specs := coll collect:[:aView| self fullSpecFor:aView ].

            self withinTransaction:#cut objects:coll do:[
                coll reverseDo:[:aView|
                    self createUndoRemove:aView.
                    self remove:aView
                ]
            ].
            self setSelection:specs.
        ]
    ]
!

pasteBuffer
    "add the objects in the paste-buffer to the object view
    "
    self pasteSpecifications:(self getSelection) keepLayout:false

!

pasteSpecifications:aSpecificationOrList keepLayout:keepLayout
    "add the specs to the object view
    "
    |paste frame pasteOrigin pasteOffset builder newSel|

    (self canPaste:aSpecificationOrList) ifFalse:[
        ^ self
    ].
    listHolder disableNotificationsWhileEvaluating:[
        aSpecificationOrList isCollection ifTrue:[
            paste := aSpecificationOrList
        ] ifFalse:[
            paste := Array with:aSpecificationOrList
        ].
        frame := self singleSelection.

        (self canPasteInto:frame) ifFalse:[
            frame := self
        ].
        self setSelection:nil withRedraw:true.

        newSel  := OrderedCollection new.
        builder := UIBuilder new.
        className notNil ifTrue:[
            builder applicationClass:(Smalltalk classNamed:className).
        ].

        keepLayout ifFalse:[
            pasteOffset := 0@0.
            pasteOrigin := self sensor mousePoint.
            pasteOrigin := device translatePoint:pasteOrigin from:device rootView id to:frame id.
        ].

        listHolder disableNotificationsWhileEvaluating:[
            paste do:[:aSpec|
                |view|

                view := self addSpec:aSpec builder:builder in:frame.

                keepLayout ifFalse:[
                    (frame bounds containsPoint:pasteOrigin) ifFalse:[
                        self moveObject:view to:pasteOffset.
                    ] ifTrue:[
                        self moveObject:view to:pasteOrigin + pasteOffset.
                    ].
                    pasteOffset := pasteOffset + 4
                ].
                view realize.
                newSel add:view.
            ].
        ].

        self withinTransaction:#paste objects:newSel do:[
            undoHistory addUndoSelector:#undoCreate:
                               withArgs:(newSel collect:[:v|(self propertyOfView:v) identifier])
        ].

        newSel size == 1 ifTrue:[
            newSel := newSel at:1
        ].
        self realizeAllSubViews.
        inputView raise.
        self select:newSel.
        self elementChangedSize:frame.
    ]

    "Modified: 4.7.1997 / 23:49:14 / cg"
!

pasteWithLayout
    "add the objects in the paste-buffer to the object view; don't change the
     layout
    "
    self pasteSpecifications:(self getSelection) keepLayout:true

! !

!UIPainterView methodsFor:'drag & drop'!

canDrop:anObjectOrCollection
    |spec|

    self enabled ifTrue:[
        anObjectOrCollection size == 1 ifTrue:[
            spec := (anObjectOrCollection at:1) theObject.
            ^ (spec isKindOf:UISpecification)
        ]
    ].
    ^ false

    "Modified: 8.4.1997 / 01:01:50 / cg"
!

drop:anObjectOrCollection at:aPoint
    |spec|

    spec := (anObjectOrCollection at:1) theObject.
    self pasteSpecifications:spec keepLayout:false.


! !

!UIPainterView methodsFor:'generating output'!

generateActionMethodFor:aspect spec:protoSpec inClass:targetClass
    |args showIt|

    (aspect asSymbol numArgs) == 1 ifFalse:[
        args := '\'.
        showIt := ' ...''.\'.
    ] ifTrue:[
        args := 'anArgument\'.
        showIt := ''' , anArgument printString , '' ...''.\'.
    ].

    ^ ('!!' , targetClass name , ' methodsFor:''actions''!!\\' ,
      aspect , args ,
      '    "automatically generated by UIPainter ..."\' ,
      '\' ,
      '    "action to be added ..."\' ,
      '    Transcript showCR:self class name , '': action for ' , aspect , showIt ,
      '!! !!\\') withCRs
!

generateAspectMethodFor:aspect spec:protoSpec inClass:targetClass
    |modelClass|

    modelClass := protoSpec defaultModelClassFor:aspect.

    ^ ('!!' , targetClass name , ' methodsFor:''aspects''!!\\' ,
      aspect , '\' ,
      '    "automatically generated by UIPainter ..."\' ,
      '\' ,
      '    |holder|\' ,
      '\' ,
      '    (holder := builder bindingAt:#' , aspect , ') isNil ifTrue:[\' ,
      '        builder aspectAt:#' , aspect , ' put:(holder := ' , ' ' , modelClass name , ' new' , ').\' ,
      '    ].\' ,
      '    ^ holder\' ,
      '!! !!\\') withCRs
!

generateAspectMethods
    |cls code skip|

    code := ''.

    className isNil ifTrue:[
        self warn:'set the class first'.
        ^ code
    ].
    cls := Smalltalk classNamed:className.

    listHolder propertiesDo:[:aProp |
        |modelSelector menuSelector protoSpec thisCode|

        protoSpec := aProp spec.

        (modelSelector := aProp model) notNil ifTrue:[
            (cls implements:modelSelector asSymbol) ifFalse:[
                skip := false.
                (cls isSubclassOf:SimpleDialog) ifTrue:[
                    skip := SimpleDialog implements:modelSelector asSymbol
                ].
                skip ifFalse:[
                    "/ kludge ..
                    (protoSpec isMemberOf:ActionButtonSpec) ifTrue:[
                        thisCode := (self generateActionMethodFor:modelSelector spec:protoSpec inClass:cls).
                    ] ifFalse:[
                        thisCode := (self generateAspectMethodFor:modelSelector spec:protoSpec inClass:cls).
                    ].
                    code := code , thisCode
                ].
            ].
        ].

        (menuSelector := aProp menu) notNil ifTrue:[
            (cls implements:menuSelector asSymbol) ifFalse:[
                thisCode := (self generateAspectMethodFor:menuSelector spec:protoSpec inClass:cls).
                code := code , thisCode
            ]
        ].

        aProp spec aspectSelectors do:[:aSel|
            (cls implements:aSel asSymbol) ifFalse:[
                thisCode := (self generateAspectMethodFor:aSel spec:protoSpec inClass:cls).
                code := code , thisCode
            ]
        ].
        aProp spec actionSelectors do:[:aSel|
            (cls implements:aSel asSymbol) ifFalse:[
                thisCode := (self generateActionMethodFor:aSel spec:protoSpec inClass:cls).
                code := code , thisCode
            ]
        ].
        aProp spec valueSelectors do:[:aSel|
            (cls implements:aSel asSymbol) ifFalse:[
                thisCode := (self generateValueMethodFor:aSel spec:protoSpec inClass:cls).
                code := code , thisCode
            ]
        ].

    ].
    ^ code
!

generateValueMethodFor:aspect spec:protoSpec inClass:targetClass
    ^ ('!!' , targetClass name , ' methodsFor:''values''!!\\' ,
      aspect , '\' ,
      '    "automatically generated by UIPainter ..."\' ,
      '\' ,
      '    "value to be added below ..."\' ,
      '    Transcript showCR:self class name , '': no value yet for ' , aspect , ' ...''.\' ,
      '\' ,
      '^ nil.' ,
      '!! !!\\') withCRs




!

generateWindowSpecMethodSource
    |t s spec specArray str code category cls mthd|

    specArray := OrderedCollection new.

    self subViews do:[:aView|
        aView ~~ inputView ifTrue:[
            specArray add:(self fullSpecFor:aView)
        ]
    ].
    spec := FullSpec new.
    spec fromBuilder:self components:(SpecCollection new collection:specArray).
    specArray := spec literalArrayEncoding.

    str := WriteStream on:String new.
    UISpecification prettyPrintSpecArray:specArray on:str indent:5.

    "/ if that method already exists, do not overwrite the category

    category := 'interface specs'.
    (cls := Smalltalk classNamed:className) notNil ifTrue:[
        (mthd := cls class compiledMethodAt:methodName asSymbol) notNil ifTrue:[
            category := mthd category.
        ]
    ].

    code := Character excla asString 
            , className , ' class methodsFor:' , category storeString
            , Character excla asString , '\\'

            , methodName , '\'
            , '    "this window spec was automatically generated by the ST/X UIPainter"\\'
            , '    "do not manually edit this - the painter/builder may not be able to\'
            , '     handle the specification if its corrupted."\\'
            , '    "\'
            , '     UIPainter new openOnClass:' , className , ' andSelector:#' , methodName , '\'
            , '     ' , className , ' new openInterface:#' , methodName , '\'
            , '    "\'.

    methodName = 'windowSpec' ifTrue:[
        code := code , '    "' , className , ' open"\'
    ].
    code := code 
            , '\'
            , '    <resource: #canvas>\\'
            , '    ^\' 
            , '     ', str contents
            , '\'
            , Character excla asString
            , ' '
            , Character excla asString
            , '\\'.

    ^ code withCRs

    "Modified: 5.9.1995 / 21:01:35 / claus"
    "Modified: 24.6.1997 / 19:12:44 / cg"
! !

!UIPainterView methodsFor:'initialization'!

destroy
    "remove dependencies
    "
    listHolder notNil ifTrue:[
        listHolder removeDependent:self.
    ].
    super destroy.
!

initialize
    "setup attributes
    "
    super initialize.

    superclassName := 'ApplicationModel'.
    className      := 'NewApplication'.
    methodName     := 'windowSpec'.
    categoryName   := 'Applications'.
    listHolder     := ListHolder for:self.
    HandCursor     := Cursor leftHand.

!

setupFromSpec:specOrSpecArray
    |spec builder|

    listHolder disableNotificationsWhileEvaluating:[
        self removeAll.
        spec    := UISpecification from:specOrSpecArray.
        builder := UIBuilder new.
        spec window setupView:self topView for:builder.
        self addSpec:(spec component) builder:builder in:self.
        self realizeAllSubViews.
        inputView raise.
    ]
! !

!UIPainterView methodsFor:'menus'!

showMiddleButtonMenu
    "show the middle button menu; this returns nil
    "
    |menu canPaste|

    self enabled ifFalse:[
        ^ nil
    ].
    menu := MenuPanel fromSpec:(self class menu) receiver:self.

    canPaste := self canPaste:(self getSelection).

    self hasSelection ifTrue:[
        canPaste := (canPaste and:[self canPasteInto:(self selection)])
    ] ifFalse:[
        menu disableAll
    ].
    menu enabledAt:#paste put:canPaste.
    menu enabledAt:#undo  put:(undoHistory isEmpty not).
    menu startUp.
  ^ nil



! !

!UIPainterView methodsFor:'removing components'!

remove:anObject
    "remove anObject from the contents do redraw
    "
    anObject notNil ifTrue:[
        listHolder remove:anObject
    ]
!

removeAll
    "remove all objects and properties
    "
    listHolder disableNotificationsWhileEvaluating:[
        self select:nil.
        listHolder removeAll.
        self removeUndoHistory.
    ]
! !

!UIPainterView methodsFor:'searching'!

findContainerViewAt:aPoint
    "find container view responds to aPoint.
    "
    |view|

    (view := self findObjectAt:aPoint) isNil ifTrue:[
        ^ self
    ].

    [(view specClass supportsSubComponents or:[(view := view superView) == self])
    ] whileFalse:[
        [(self propertyOfView:view) isNil] whileTrue:[
            (view := view superView) == self ifTrue:[^ self]
        ].
    ].
    ^ view
!

findObjectAt:aPoint
    "find the origin/corner of the currentWidget
    "
    |view|

    view := super findObjectAt:aPoint.

    view notNil ifTrue:[
        "can be a view within a view not visible
        "
        [ (self propertyOfView:view) isNil ] whileTrue:[
            (view := view superView) == self ifTrue:[^ nil]
        ]
    ].
    ^ view
!

findViewWithId:aViewId
    "finds view assigned to identifier and returns the view or nil
    "
    |prop|

    prop := self propertyOfIdentifier:aViewId.

    prop notNil ifTrue:[^ prop view]
               ifFalse:[^ nil]
!

propertyOfIdentifier:anId
    "returns property assigned to unique identifier
    "
    anId notNil ifTrue:[
        ^ listHolder detectProperty:[:p| p identifier == anId ]
    ].
    ^ nil
!

propertyOfName:aString
    "returns property assigned to name
    "
    |name|

    aString isNil ifFalse:[
        name := aString string withoutSeparators.

        name = 'self' ifFalse:[
            ^ listHolder detectProperty:[:p| p name = name ].
        ]
    ].
    ^ nil
!

propertyOfView:aView
    "returns property assigned to view
    "
    (aView isNil or:[aView == self]) ifFalse:[
        ^ listHolder detectProperty:[:p| p view == aView ]
    ].
    ^ nil
!

uniqueNameFor:aSpecOrString
    "generate and return an unique name for a class
    "
    |next name size|

    aSpecOrString isString ifFalse:[name := aSpecOrString className asString]
                            ifTrue:[name := aSpecOrString].

    (name endsWith:'Spec') ifTrue:[
        name := name copyFrom:1 to:(name size - 4).
    ] ifFalse:[
        name := name copy
    ].
    name at:1 put:(name at:1) asLowercase.
    size  := name size + 1.
    next  := 0.

    listHolder propertiesDo:[:p|
        |n|
        n := p name.

        (n size >= size and:[n startsWith:name]) ifTrue:[
            next := next max:(p extractNumberStartingAt:size)
        ]
    ].
    next := next + 1.
    name := name, next printString.
  ^ name



!

uniqueNameOf:aView
    |prop|

    (prop := self propertyOfView:aView) notNil ifTrue:[
        prop name isNil ifTrue:[
            prop name:(self uniqueNameFor:(prop spec)).
        ].
        ^ prop name
    ].
    ^ 'self'

! !

!UIPainterView methodsFor:'specification'!

addSpec:aSpecification builder:aBuilder in:aFrame
    "build view and subviews from aSpecification into a frame. The top view
     is returned. The contained components of a spec are set to nil
    "

    className notNil ifTrue:[
        aBuilder applicationClass:(Smalltalk classNamed:className).
    ].

    aBuilder componentCreationHook:[:aView :aSpec :aBdr||sv p s n|
        p := ViewProperty new.
        s := aSpec copy.
        p spec:s.
        p view:aView.

        s class supportsSubComponents ifTrue:[
            s component:nil
        ].

        n := s name.

        (n isNil or:[(self propertyOfName:n) notNil]) ifTrue:[
            s name:(self uniqueNameFor:s)
        ].
        listHolder add:p
    ].

    ^ aSpecification buildViewWithLayoutFor:aBuilder in:aFrame.

    "Modified: 4.7.1997 / 23:48:55 / cg"
!

fullSpecFor:anObject
    "generate a full spec for an object
    "
    |mySpec subSpecs|

    mySpec := self specFor:anObject.

    (mySpec notNil and:[mySpec class supportsSubComponents]) ifTrue:[
        (anObject subViews notNil) ifTrue:[
            anObject subViews do:[:aSubView||spec|
                spec := self fullSpecFor:aSubView.
                spec notNil ifTrue:[
                    subSpecs isNil ifTrue:[
                        subSpecs := OrderedCollection new
                    ].
                    subSpecs add:spec.
                ].
            ].
            subSpecs notNil ifTrue:[
                mySpec component:(SpecCollection new collection:subSpecs)
            ]
        ]
    ].
    ^ mySpec






!

specFor:anObject
    "returns spec assigned to an object
    "
    |prop spec|

    (prop := self propertyOfView:anObject) notNil ifTrue:[
        spec := prop spec copy.
        spec layoutFromView:anObject
    ].
    ^ spec



!

specForSelection
    "returns spec assigned to current single selection or nil
    "
    ^ self specFor:(self singleSelection)


!

updateFromSpec:aSpec
    "update current selected view from specification
    "
    |props name builder v|

    self singleSelection notNil ifTrue:[
        self withSelectionHiddenDo:[
            self transaction:#specification selectionDo:[:aView|
                builder := UIBuilder new.
                className notNil ifTrue:[
                    builder applicationClass:(Smalltalk classNamed:className).
                ].
                props   := self propertyOfView:aView.
                name    := (aSpec name) withoutSeparators.

                name = props name ifFalse:[
                    (self propertyOfName:name) notNil ifTrue:[
                        name := props name
                    ]
                ].
                aSpec name:name.
                self createUndoSpecModify:props.

                aSpec needsRebuildForAttributes ifTrue:[
                    v := aSpec buildViewWithLayoutFor:builder in:aView superView.
                    v realize.    
                    aView destroy.
                    device sync. device flush.
                    aView becomeSameAs:v.
                    inputView raise.
                ] ifFalse:[
                    aSpec setAttributesIn:aView with:builder.
                    self elementChangedSize:aView.
                ].
                props spec:(aSpec copy).
                listHolder propertyChanged:props.
            ]
        ]
    ]

    "Modified: 4.7.1997 / 23:49:44 / cg"
! !

!UIPainterView methodsFor:'transaction'!

transaction:aType objects:something do:aOneArgBlock
    "opens a transaction and evaluates a block within the transaction; the
     argument to the block is a view from derived from something
    "
    self withinTransaction:aType objects:something do:[
        self forEach:something do:aOneArgBlock
    ]
!

withinTransaction:aType objects:objects do:aNoneArgBlock
    "evaluate a block with no arguments within a transaction
    "
    |text size prop|

    objects isNil ifTrue:[ ^ self ].

    size := objects size.

    objects isCollection ifTrue:[
        size == 0 ifTrue:[ ^ self ].
        size == 1 ifTrue:[ prop := self propertyOfView:(objects first) ]
    ] ifFalse:[
        prop := self propertyOfView:objects
    ].

    prop notNil ifTrue:[
        text := prop name
    ] ifFalse:[
        text := size printString, ' elements'
    ].

    undoHistory withinTransaction:aType text:text do:[
        aNoneArgBlock value
    ]
! !

!UIPainterView methodsFor:'undo actions'!

createUndoLayout:aView
    "create undo action before changing a views layout
    "
    |lyt args prop|

    undoHistory isTransactionOpen ifTrue:[
        prop := self propertyOfView:aView.

        prop notNil ifTrue:[
            args := Array new:3.
            args at:1 put:(prop identifier).

            (lyt := aView geometryLayout) notNil ifTrue:[
                args at:2 put:#geometryLayout:
            ] ifFalse:[
                lyt := aView extent.
                args at:2 put:#extent:
            ].
            args at:3 put:(lyt copy).
            undoHistory addUndoSelector:#undoLayout: withArgs:args.
        ]
    ]
!

createUndoRemove:aView
    "create undo method before deleting views
    "
    |frame prop pId spec|

    (prop := self propertyOfView:aView) notNil ifTrue:[
        spec  := self fullSpecFor:aView.
        frame := aView superView.

        (self canPasteInto:frame) ifTrue:[
            (frame := self propertyOfView:frame) notNil ifTrue:[
                pId := frame identifier
            ]
        ].
        undoHistory addUndoSelector:#undoRemove:
                           withArgs:(Array with:spec with:(prop identifier) with:pId)
    ]
!

createUndoSpecModify:aProp
    "undo method when changing the specification for an object
    "
    aProp notNil ifTrue:[
        undoHistory addUndoSelector:#undoSpecModify:
                           withArgs:(Array with:(aProp spec) with:(aProp identifier))
    ]
!

undoCreate:something
    "undo method for creating or pasting an object
    "
    self forEach:something do:[:anId|self remove:(self findViewWithId:anId)].
!

undoLayout:args
    "undo method to set the old layout; see 'createUndoLayout:'
    "
    |view|

    (view := self findViewWithId:(args at:1)) notNil ifTrue:[
        view perform:(args at:2) with:(args at:3).
        self changed:#layout.
    ]
!

undoRemove:args
    "undo method when removing an object; see 'createUndoRemove:'
    "
    |frame prop view|

    (args at:3) notNil ifTrue:[
        frame := self findViewWithId:(args at:3).
    ].
    frame isNil ifTrue:[
        frame := self
    ].
    view := self addSpec:(args at:1) builder:(UIBuilder new) in:frame.
    view realize.
    inputView raise.

    prop := self propertyOfView:view.
    prop identifier:(args at:2).

!

undoSpecModify:args
    "undo method when changing a spec; see 'createUndoSpecModify:'
    "
    |builder view spec v props|

    props := self propertyOfIdentifier:(args at:2).

    props notNil ifTrue:[
        view    := props view.
        spec    := args at:1.
        builder := UIBuilder new.
        className notNil ifTrue:[
            builder applicationClass:(Smalltalk classNamed:className).
        ].
        props spec:spec.

        spec needsRebuildForAttributes ifTrue:[
            v := spec buildViewWithLayoutFor:builder in:view superView.
            v realize.    
            view destroy.
            view become:v
        ] ifFalse:[
            spec setAttributesIn:view with:builder.
            self elementChangedSize:view.
        ].
        listHolder propertyChanged:props.
    ]

    "Modified: 4.7.1997 / 23:49:39 / cg"
! !

!UIPainterView methodsFor:'user actions - arrange'!

lowerSelection
    "lower all objects in the selection
    "
    self hasSelection ifTrue:[
        self selectionDo:[:aView|
            aView lower.
            aView superView changeSequenceOrderFor:aView to:1.
        ].
        listHolder recompute.
    ]


!

raiseSelection
    "raise all objects in the selection
    "
    self hasSelection ifTrue:[
        self selectionDo:[:aView||sv|
            aView raise.
            sv := aView superView.
            sv changeSequenceOrderFor:aView to:(sv subViews size)
        ].
        inputView raise.
        listHolder recompute.
    ].


! !

!UIPainterView::ListHolder class methodsFor:'instance creation'!

for:aPainter
    ^ self new for:aPainter
! !

!UIPainterView::ListHolder methodsFor:'accessing'!

painter
    "returns painter
    "
    ^ painter
!

propertyAt:anIndex
    "returns property at an index
    "
    ^ propertyList at:anIndex
! !

!UIPainterView::ListHolder methodsFor:'adding & removing'!

add:aProperty
    "add property and update list
    "
    |idx list name last|

    list := self list.
    idx  := self findParentProperty:aProperty.
    name := aProperty name.

    idx == 0 ifTrue:[
        last := list size
    ] ifFalse:[
        last := self lastInGroupStartingAt:idx.
        name := (String new:(4+((list at:idx) leftIndent))), name.
    ].
    propertyList add:aProperty afterIndex:last.
    list         add:name      afterIndex:last.
    self changed:#size


!

remove:aView
    "remove all view relevant resources
    "
    |start|

    aView notNil ifTrue:[
        start := self findProperty:[:p| p view == aView ].

        start ~~ 0 ifTrue:[
            self basicRemove:start.
            self changed:#size.
        ]
    ]
!

removeAll
    masterElement := nil.
    self selection:#().

    [propertyList notEmpty] whileTrue:[
        self basicRemove:1
    ].
    self changed:#size.

! !

!UIPainterView::ListHolder methodsFor:'change & update'!

changed:aParameter
    "notify all dependents that the receiver has changed somehow.
     Each dependent gets a '#update:'-message with aParameter
     as argument. In case of disabled no notifications are raised
    "
    disabledChanged ifFalse:[
        super changed:aParameter
    ]
!

disableNotificationsWhileEvaluating:aBlock
    "perform block without notification; after evaluation of block,
     a #size changed notification is raised
    "
    |oldState|

    oldState := disabledChanged.
    disabledChanged := true.
    aBlock value.
    disabledChanged := oldState.
    self changed:#size.
!

propertyChanged:aProperty
    "property list changed; update list names
    "
    |list idx oldName newName wspName view indent mid|

    view := aProperty view.
    idx  := self findProperty:[:p| p view == view ].

    idx == 0 ifTrue:[
        ^ self error
    ].

    list    := self list.
    oldName := list at:idx.
    wspName := oldName string withoutSeparators.
    newName := aProperty name.

    wspName = newName ifFalse:[
        mid := self masterElement.
        list at:idx put:((String new:(oldName leftIndent)), newName).

        idx == mid ifTrue:[
            masterElement := nil.
            self masterElement:idx
        ].
    ].
    self changed:#property

! !

!UIPainterView::ListHolder methodsFor:'enumerating'!

propertiesDo:aBlock
    "evaluate a block for each property
    "
    propertyList do:aBlock
! !

!UIPainterView::ListHolder methodsFor:'initialization'!

for:aPainter
    "initialize for a painter
    "
    painter := aPainter.
    disabledChanged := false.
    self list:(OrderedCollection new).
    propertyList := OrderedCollection new.
    self selection:#().
    self addDependent:painter.

! !

!UIPainterView::ListHolder methodsFor:'private'!

basicRemove:start
    "remove all resources assigned to a group starting at start;
     no notifications are raised
    "
    |end view superView|

    end  := self lastInGroupStartingAt:start.
    view := (propertyList at:start) view.

    view notNil ifTrue:[
        superView := view superView.
        view destroy.
        superView sizeChanged:nil.
    ].

    propertyList removeFromIndex:start toIndex:end.
    self list    removeFromIndex:start toIndex:end.
!

masterElement
    "returns index of master
    "
    ^ self indexOfName:masterElement.
!

masterElement:newIndex
    "change master of selection
    "
    |name list oldIdx|

    (oldIdx := self masterElement) ~~ newIndex ifTrue:[
        list := self list.
        
        oldIdx ~~ 0 ifTrue:[
            list at:oldIdx put:masterElement
        ].
        newIndex ~~ 0 ifTrue:[
            masterElement := list at:newIndex.
            name := Text string:masterElement.
            name emphasizeFrom:(1+(name leftIndent)) with:#(#bold #underline).
            list at:newIndex put:name.
        ] ifFalse:[
            masterElement := nil
        ].
        self changed:#list.
    ]
! !

!UIPainterView::ListHolder methodsFor:'recomputing'!

recompute
    |list prop size osel|

    osel := self selection copy.
    size := self list size.
    list := OrderedCollection new:size.
    prop := OrderedCollection new:size.

    painter allSubViewsDo:[:v|
        size := self indexOfView:v.

        size ~~ 0 ifTrue:[
            list add:(self list at:size).
            prop add:(propertyList at:size)
        ]
    ].
    propertyList := prop.
    self list:list.
    self selection:osel.
! !

!UIPainterView::ListHolder methodsFor:'searching'!

detectProperty:aBlock
    "find the property, for which evaluation of the argument, aBlock
     returns true; return the property or nil if none detected
    "
    |idx|

    idx := self findProperty:aBlock.
    idx ~~ 0 ifTrue:[ ^ propertyList at:idx ].
  ^ nil
!

findParentProperty:aChildProp
    "returns index of parent or 0
    "
    |view index|

    view := aChildProp view.

    view notNil ifTrue:[
        [ (view := view superView) notNil ] whileTrue:[
            index := self findProperty:[:aProp| aProp view == view ].
            index ~~ 0 ifTrue:[
                ^ index
            ]
        ]
    ].
    ^ 0


!

findProperty:aBlock
    "find the first property, for which evaluation of the argument, aBlock
     returns true; return its index or 0 if none detected
    "
    ^ propertyList findFirst:aBlock
!

indexOfName:aString
    "returns index assigned to a string or 0
    "
    |name list size|

    aString notNil ifTrue:[
        name := aString string withoutSeparators.
        size := name size.
        list := self list.

        list keysAndValuesDo:[:anIndex :aName|
            |el|

            el := aName string.
            (el endsWith:name) ifTrue:[
                (el size - el leftIndent) == name size ifTrue:[
                    ^ anIndex
                ]
            ]
        ]
    ].
    ^ 0

!

indexOfView:aView
    "returns index assigned to a view or 0
    "
    aView notNil ifTrue:[
        ^ propertyList findFirst:[:p| p view == aView ]
    ].
    ^ 0

!

lastInGroupStartingAt:start
    "returns last index of a group
    "
    |end list idt|

    list := self list.

    start < list size ifTrue:[
        idt := (list at:start) leftIndent.
        end := list findFirst:[:el|(el leftIndent) <= idt] startingAt:(start+1).
        end ~~ 0 ifTrue:[
            ^ end - 1
        ]
    ].
    ^ list size
! !

!UIPainterView::ListHolder methodsFor:'selection'!

selectGroup
    "select all elements assigned to master
    "
    |start end sel size|

    painter enabled ifTrue:[
        (start := self masterElement) ~~ 0 ifTrue:[
            end  := self lastInGroupStartingAt:start.
            size := end - start + 1.
            sel  := Array new:size.

            1 to:size do:[:i|
                sel at:i put:start.
                start := start + 1
            ].
            self selectionIndex:sel.
        ] ifFalse:[
            (self selectionIndex) size == 0 ifFalse:[
                self selectionIndex:#()
            ].
        ]
    ]
!

selectedProperty
    "returns current selected instance; in case of multiple selection
     or no selection nil is returned
    "
    |selection|
    selection := self selectionIndex.

    selection size == 1 ifTrue:[
        propertyList size ~~ 0 ifTrue:[
            ^ propertyList at:(selection first)
        ]
    ].
    ^ nil
!

selectionIndex:aList
    |masterIndex aSel|

    painter enabled ifTrue:[aSel := aList]
                   ifFalse:[aSel := nil].

    aSel size ~~ 0 ifTrue:[masterIndex := aSel at:1]
                  ifFalse:[masterIndex := 0].

    self masterElement:masterIndex.
    super selectionIndex:aSel
! !

!UIPainterView::ViewProperty class methodsFor:'instance creation'!

new
    Identifier notNil ifTrue:[Identifier := Identifier + 1]
                     ifFalse:[Identifier := 1].

  ^ self basicNew initialize
! !

!UIPainterView::ViewProperty methodsFor:'accessing'!

identifier
    "return the unique identifier assigned to property
    "
    ^ identifier
!

identifier:anIdentifier
    "set the unique identifier assigned to property; called after an restore of
     a deleted instance
    "
    identifier := anIdentifier
!

spec
    "return the value of the instance variable 'spec' (automatically generated)"

    ^ spec!

spec:something
    "set the value of the instance variable 'spec' (automatically generated)"

    spec := something.!

view
    "return the value of the instance variable 'view' (automatically generated)"

    ^ view!

view:something
    "set the value of the instance variable 'view' (automatically generated)"

    view := something.! !

!UIPainterView::ViewProperty methodsFor:'initialization'!

initialize
    super initialize.
    identifier := Identifier
! !

!UIPainterView::ViewProperty methodsFor:'misc'!

extractNumberStartingAt:anIndex
    "return the number from the name starting at anIndex or 0.
    "
    |val|

    val := 0.

    self name from:anIndex do:[:c|
        c isDigit ifTrue:[val := val * 10 + c digitValue]
                 ifFalse:[^ 0]
    ].
    ^ val
        
! !

!UIPainterView::ViewProperty methodsFor:'spec messages'!

doesNotUnderstand:aMessage
    spec notNil ifTrue:[
        (spec respondsTo:(aMessage selector)) ifTrue:[^ aMessage sendTo:spec]
    ].
    ^ nil
!

layout
    spec layout
!

layout:aLayout
    spec layout:aLayout
!

name
    ^ spec name
!

name:aName
    spec name:aName
! !

!UIPainterView class methodsFor:'documentation'!

version
    ^ '$Header$'
! !