"{ Package: 'jv:dragonfly/c1' }"

"{ NameSpace: DragonFly }"

TestCase subclass:#C1CompilerTests

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:'DragonFly::C1LLVMMTypes LLVMIntPredicate VMData VMOffsets'

	category:'DragonFly-C1-Tests'

!

!C1CompilerTests methodsFor:'tests - building blocks'!

test_isSmallIntegerObject

    | compiler module function asm jit test |

    compiler := C1Compiler new.

    module := LLVMModule newWithName: testSelector.

    function := module addFunctionNamed: 'test'

                                   type: (LLVMType function: { TyOBJ } returning: LLVMType int1).

    asm := function builder.

    compiler 

        instVarNamed: #module put: module;

        instVarNamed: #function put: function;

        instVarNamed: #asm put: asm.

    asm ret: (compiler isSmallIntegerObject: (function parameterAt: 1)).

    jit := LLVMExecutionEngine newForModule: module.  

    test := jit externalOfFunction: function. 

    self assert: (test callWith: 1) == 1.

    self assert: (test callWith: self) == 0.

    "Created: / 12-02-2016 / 12:17:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_loadClassOf

    | method compiler asm obj |

    method := Method new.

    method numberOfArgs: 2.

    method numberOfVars: 0.

    method stackSize: 0.

    compiler := C1Compiler new.

    compiler method: method.

    compiler prepare.

    asm := compiler instVarNamed: #asm.

    obj := (compiler instVarNamed: #function) parameterAt: OBJFUNCArgIndexArg1.

    asm ret: (compiler loadClassOf: obj).

    compiler finish.

    self assert: method code notNil.

    self assert: (method valueWithReceiver:nil arguments: { 1.0  . 2 }) == Double.

    self assert: (method valueWithReceiver:nil arguments: { self . 2 }) == self class.

    self assert: (method valueWithReceiver:nil arguments: { 1 . 2 }) == SmallInteger

    "Created: / 12-02-2016 / 12:27:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-04-2016 / 09:57:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_loadClassSmallInteger

    | method compiler asm |

    method := Method new.

    method numberOfArgs: 2.

    method numberOfVars: 0.

    method stackSize: 0.

    compiler := C1Compiler new.

    compiler method: method.

    compiler prepare.

    asm := compiler instVarNamed: #asm.

    asm ret: (compiler loadClassSmallInteger).

    compiler finish.

    self assert: method code notNil.

    self assert: (method valueWithReceiver:nil arguments: #(1 2)) == SmallInteger

    "Created: / 12-02-2016 / 12:26:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-04-2016 / 09:23:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 21-04-2016 / 14:02:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!C1CompilerTests methodsFor:'tests - codegen'!

test_codegen

    | method compiler asm |

    method := Method new.

    method numberOfArgs: 2.

    method numberOfVars: 0.

    method stackSize: 0.

    compiler := C1Compiler new.

    compiler method: method.

    compiler prepare.

    asm := compiler instVarNamed: #asm.

    asm ret: (asm int: (LLVMConstant uintptr: 0) toPtr: TyOBJ).  

    compiler finish.

    self assert: method code notNil.

    self assert: (method valueWithReceiver:nil arguments: #(1 2)) == nil

    "Created: / 21-04-2016 / 13:48:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!C1CompilerTests class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !