"

COPYRIGHT (c) 2023 LabWare

jv:libgdbs - GNU Debugger Interface Library

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

Object subclass:#GDBPortlib

	instanceVariableNames:''

	classVariableNames:'Current'

	poolDictionaries:''

	category:'GDB-Internal-Portlib'

!

!GDBPortlib class methodsFor:'documentation'!

copyright

"

COPYRIGHT (c) 2023 LabWare

jv:libgdbs - GNU Debugger Interface Library

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

! !

!GDBPortlib class methodsFor:'instance creation'!

new

    self shouldNotImplement. "Use #current instead"

! !

!GDBPortlib class methodsFor:'accessing'!

current

    Current isNil ifTrue: [ 

        Current := self basicNew initialize 

    ].

    ^ Current

! !

!GDBPortlib methodsFor:'processes'!

spawn: argv stdin: stdin stdout: stdout stderr: stderr exit: action 

    | pid |

    OperatingSystem isMSWINDOWSlike ifTrue: [

        (OperatingSystem getEnvironment: 'HOME') isNil ifTrue: [

            OperatingSystem setEnvironment: 'HOME' to: Filename homeDirectory pathName

        ].

    ].

    Processor 

        monitor: [

            pid := OperatingSystem 

                    exec: argv first

                    withArguments: argv

                    environment: OperatingSystem getEnvironment

                    fileDescriptors: (Array 

                            with: stdin fileDescriptor

                            with: stdout fileDescriptor

                            with: stderr fileDescriptor)

                    fork: true

                    newPgrp: false

                    inDirectory: Filename currentDirectory

                    showWindow: false.

        ]

        action: action.

    ^ pid

    "Modified: / 24-07-2023 / 22:58:57 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBPortlib methodsFor:'streams'!

newPTY

    "Allocate a PTY and return it as an instance of GDBPTY"

    | triplet name master slave |    

    OperatingSystem isUNIXlike ifTrue:[ 

        "Use a pseudo-tty"

        triplet := OperatingSystem makePTY.

        name := triplet at:3.

        "/ pty at:1 is the master;

        "/ pty at:2 is the slave

        master := NonPositionableExternalStream forReadWriteToFileDescriptor:(triplet at:1).

        master buffered:false.

        slave := NonPositionableExternalStream forReadWriteToFileDescriptor:(triplet at:2).

        slave buffered:false.

        ^ GDBPTY name: name masterReadStream: master masterWriteStream: master slaveReadStream: slave slaveWriteStream: slave.

    ].

    OperatingSystem isMSWINDOWSlike ifTrue:[ 

        ^ self error: 'Windows are not (yet) supported'

    ].

    self error: 'Operating system not supported'

    "Modified: / 02-08-2023 / 13:11:19 / Jan Vrany <jan.vrany@labware.com>"

!

newPipe

    "Create a pipe an return an array with pipe's read end and write end

     (in this order) as smalltalk streams."

    ^ NonPositionableExternalStream makePipe

! !

!GDBPortlib methodsFor:'synchronization'!

newMutex

    ^ RecursionLock new

    "Created: / 18-08-2023 / 14:17:36 / Jan Vrany <jan.vrany@labware.com>"

    "Modified: / 25-08-2023 / 15:58:24 / Jan Vrany <jan.vrany@labware.com>"

!

newSemaphore

    ^ Semaphore new

    "Created: / 18-08-2023 / 14:16:31 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBPortlib methodsFor:'user interface'!

newCLI: aGDBDebugger

    "Open GDB CLI for interactive debugging for given debugger.

     See `GDBDebugger >> #cli`."

    | app |

    (Smalltalk at: #VDBDebuggerApplication) isNil ifTrue: [ 

        PackageNotFoundError ignoreIn: [Smalltalk loadPackage: 'jv:vdb'].

    ].

    (Smalltalk at: #VDBDebuggerApplication) isNil ifTrue: [ 

        self error: 'Failed to load package ''jv:vdb'''

    ].

    app := aGDBDebugger propertyAt: #cli.

    app isNil ifTrue: [

        app := (Smalltalk at: #VDBDebuggerApplication) new.

        app debugger: aGDBDebugger.

        app layout: #layoutSingleSpec.

        app open.

        aGDBDebugger propertyAt: #cli put: app.

    ] ifFalse: [ 

        app window raise.

    ].

    "Created: / 05-08-2023 / 07:38:23 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBPortlib class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !