"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

GDBDebuggerObject subclass:#GDBBreakpoint

	instanceVariableNames:'number type disp enabled addr func file fullname line times

		condition script locations'

	classVariableNames:''

	poolDictionaries:''

	category:'GDB'

!

!GDBBreakpoint class methodsFor:'documentation'!

copyright

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

! !

!GDBBreakpoint class methodsFor:'accessing - GDB value descriptors'!

description

    ^ (super description)

        define:#number as:String;

        define:#type as:String;

        define:#disp as:String;

        define:#enabled as:Boolean;

        define:#addr as:Integer;

        define:#func as:String;

        define:#file as:String;

        define:#fullname as:String;

        define:#line as:Integer;

        define:#times as:Integer;

        define:#locations as:Array of: self;

        yourself

    "Created: / 06-09-2014 / 01:56:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 25-04-2019 / 14:27:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'accessing'!

addr

    ^ addr

!

condition

    ^ condition

!

condition:aString

    self assert: debugger notNil.

    condition ~= aString ifTrue:[ 

        debugger send: (GDBMI_break_condition arguments: (Array with: number with: aString)) andWait: true.    

    ].

    "Modified: / 17-11-2017 / 20:25:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-05-2021 / 16:38:06 / Jan Vrany <jan.vrany@labware.com>"

!

disp

    ^ disp

!

enabled

    ^ enabled

!

enabled: aBoolean

    self assert: debugger notNil.

    enabled ~~ aBoolean ifTrue:[

        aBoolean ifTrue:[

            debugger send: (GDBMI_break_enable arguments: (Array with: number)) andWait: true.

        ] ifFalse:[ 

            debugger send: (GDBMI_break_disable arguments: (Array with: number)) andWait: true.

        ].

    ].

    "Created: / 07-07-2017 / 12:33:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-11-2017 / 20:24:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-05-2021 / 16:16:35 / Jan Vrany <jan.vrany@labware.com>"

!

file

    ^ file

!

fullname

    ^ fullname

!

func

    ^ func

!

line

    ^ line

!

locations

    locations isNil ifTrue:[ ^ Array with: self ].

    ^ locations

    "Modified: / 18-05-2018 / 12:23:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

locations:aCollection

    self assert:  aCollection isCollection.

    self assert: (aCollection allSatisfy:[:e|e isKindOf: GDBBreakpoint]).

    self assert: (aCollection allSatisfy:[:e|e number beginsWith: number , '.']).

    locations := aCollection.

    locations do:[:e|e setDebugger: debugger].

    "Modified: / 18-05-2018 / 15:01:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 12-07-2023 / 15:32:55 / Jan Vrany <jan.vrany@labware.com>"

!

number

    ^ number

!

script

    ^ script

!

script:aString

    self assert: debugger notNil.

    script ~= aString ifTrue:[ 

        debugger send: (GDBMI_break_commands arguments: (Array with: number) , aString asStringCollection) andWait: true.    

    ].

    "Created: / 11-07-2017 / 14:32:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-11-2017 / 20:24:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-05-2021 / 16:38:18 / Jan Vrany <jan.vrany@labware.com>"

!

times

    ^ times

!

type

    ^ type

! !

!GDBBreakpoint methodsFor:'accessing-properties'!

propertyAt: name

    name = 'at' ifTrue:[ 

        ^ nil

    ].

    ^super propertyAt: name

    "Created: / 05-06-2017 / 23:22:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-06-2017 / 09:18:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propertyAt: name put: value

    name = 'at' ifTrue:[ 

        ^ self.

    ].

    ^ super propertyAt: name put: value

    "Created: / 05-06-2017 / 23:22:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-06-2017 / 09:19:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'displaying'!

displayOn: aStream

    aStream nextPutAll:(self enabled ifTrue:[ 'e ' ] ifFalse:[ 'd ' ]).

    (self type = 'watchpoint' or:[ self type = 'hw watchpoint' ]) ifTrue:[ 

        | location |

        aStream nextPutAll: 'W '.

        self number printOn:aStream.

        aStream nextPutAll:', '.

        aStream nextPutAll:'at '.

        location := self propertyAt: 'what'.

        aStream nextPutAll: location ? '??'.

    ] ifFalse: [

        | fn |

        aStream nextPutAll: 'B '.

        aStream nextPutAll: self number.

        aStream nextPutAll:', '.

        fn := self func.

        fn isNil and:[  

            fn := self propertyAt:'original-location'

        ].

        fn notNil ifTrue:[ 

            aStream nextPutAll:'in '.

            aStream nextPutAll: fn.

            "I (JV) prefer to have () after plain C function names. GDB seems to

             to add them for C functions but does no add them for C++ functions / methods

             (well, perhaps it's the compiler who does that, does not matter).

             So, if there's no $(, assume it's a C++ function and add () at the end.

             We'll see how this works..."

            (fn includes: $() ifFalse:[

                aStream nextPutAll:'()'. 

            ].

            aStream nextPutAll:', '

    ].

    self hasMultipleLocations ifTrue:[ 

        self locations size printOn: aStream.

        aStream nextPutAll: ' locations'.

    ] ifFalse:[

        self file notNil ifTrue:[

            self file printOn:aStream.

            aStream nextPut:$:.

            self line printOn:aStream.

        ] ifFalse:[ 

            | address |

            address := self addr.

            address isNil ifTrue:[ 

                    aStream nextPutAll:'at ??'.

            ] ifFalse:[address isInteger ifTrue:[

                    aStream nextPutAll:'at 0x'.

                    address printOn: aStream paddedWith: $0 to: 16 base: 16.

            ] ifFalse:[ 

                    address printOn: aStream

            ]].

        ].      

    ].

    ].

    "Created: / 29-08-2023 / 11:58:44 / Jan Vrany <jan.vrany@labware.com>"

    "Modified (format): / 30-08-2023 / 11:46:31 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBBreakpoint methodsFor:'initialization & release'!

setDebugger: aGDBDebugger

    super setDebugger: aGDBDebugger.

    locations notEmptyOrNil ifTrue:[ 

        locations do:[:e | e setDebugger: debugger ]

    ].

    "Created: / 18-05-2018 / 15:00:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'inspecting'!

inspector2TabCondition

    <inspector2Tab>

    | editor |

    editor := (HVScrollableView for:EditTextView).

    editor model: ((AspectAdaptor forAspect: #condition) subject: self).

    ^ Tools::Inspector2Tab new

            priority: 41;

            label:'Condition';  

            view: editor

            yourself.

    "Created: / 11-07-2017 / 14:36:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

inspector2TabScript

    <inspector2Tab>

    | editor |

    editor := (HVScrollableView for:EditTextView).

    editor model: ((AspectAdaptor forAspect: #script) subject: self).

    ^ Tools::Inspector2Tab new

            priority: 40;

            label:'Script';  

            view: editor

            yourself.

    "Created: / 11-07-2017 / 14:41:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'printing & storing'!

printOn:aStream

    "append a printed representation of the receiver to the argument, aStream"

    super printOn:aStream.

    aStream nextPut:$(.

    number printOn:aStream.

    aStream nextPutAll:', '.

    aStream nextPutAll:(enabled ifTrue:[ 'enabled, ' ] ifFalse:[ 'disabled, ' ]).

    func notNil ifTrue:[ 

        aStream nextPutAll:'in '.

        func printOn:aStream.   

        aStream nextPutAll:'(), '. 

    ].

    file notNil ifTrue:[

        file printOn:aStream.

        aStream nextPut:$:.

        line printOn:aStream.

    ] ifFalse:[ 

        aStream nextPutAll:'at '.

        addr printOn: aStream.

    ].

    "Modified: / 10-07-2017 / 12:55:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'private'!

_cond: aString

    condition := aString

    "Created: / 11-07-2017 / 14:11:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

_enabled: aBoolean

    enabled := aBoolean

    "Created: / 07-07-2017 / 12:46:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

_script: anArray

    script := anArray asStringWith: Character cr.

    "Created: / 11-07-2017 / 14:11:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

updateFromIgnoredInstvarNames

    ^ super updateFromIgnoredInstvarNames , #(locations)

    "Created: / 25-02-2019 / 16:25:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint methodsFor:'testing'!

hasMultipleLocations

    "Return `true` if the breakpoint has multiple locations,

     `false` otherwise."

    ^ locations notNil

    "Created: / 26-03-2019 / 10:42:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isEnabled

    ^ enabled

    "Created: / 07-07-2017 / 12:31:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isValid

    ^ debugger isConnected

    "Created: / 04-02-2018 / 21:29:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBBreakpoint class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !