"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2022-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

Object subclass:#GDBProcess

	instanceVariableNames:'connection debuggerInput debuggerOutput'

	classVariableNames:'GDBCommand'

	poolDictionaries:''

	category:'GDB-Internal'

!

!GDBProcess class methodsFor:'documentation'!

copyright

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2022-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

!

documentation

"

    GDBProcess is represents a running GDB and provides access

    to MI and CLI channels (see #debuggerIput / #debuggerOutput).

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

        GDBStXUnixProcess

        GDBStXWindowsProcess

"

! !

!GDBProcess class methodsFor:'instance creation'!

new

    self == GDBProcess ifTrue:[

        ^ GDBLocalProcess newWithCommand: nil  

    ] ifFalse:[

        ^ super new.

    ].

    "

     GDBProcess new release."

    "Modified (comment): / 11-01-2018 / 23:02:11 / jv"

    "Modified: / 12-12-2018 / 22:22:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBProcess class methodsFor:'accessing'!

gdbCommand

    GDBCommand notNil ifTrue: [ 

        ^ GDBCommand

    ] ifFalse: [

        ^ self gdbCommandDefault

    ].

    "

    GDBProcess gdbCommand

    GDBProcess gdbCommand: nil.

    GDBProcess gdbCommand: '/home/jv/Projects/gdb/users_jv_vdb/gdb/gdb'

    "

    "Created: / 13-12-2018 / 11:29:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-06-2019 / 14:21:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-07-2023 / 17:52:38 / Jan Vrany <jan.vrany@labware.com>"

!

gdbCommand: aString

    GDBCommand := aString

    "Created: / 13-12-2018 / 11:29:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-07-2023 / 17:51:33 / Jan Vrany <jan.vrany@labware.com>"

!

gdbCommandDefault

    "Return default path to `gdb` command or nil if no

     suitable `gdb` executable is found"

    | exe |

    "/ On Windows, look for MSYS2 installation and

    "/ try to pick GDB matching current arch (i686

    "/ or x86_64) since on Windows, there's no GDB

    "/ supporting both targets :-(

    OperatingSystem isMSWINDOWSlike ifTrue:[ 

        ExternalAddress pointerSize == 8 ifTrue:[

            exe := 'C:\msys64\mingw64\bin\gdb-multiarch.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

            exe := 'C:\msys64\usr\bin\gdb-multiarch.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

            exe := 'C:\msys64\mingw64\bin\gdb.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

            exe := 'C:\msys64\usr\bin\gdb.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

        ] ifFalse:[

            exe := 'C:\msys64\mingw32\bin\gdb-multiarch.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

            exe := 'C:\msys64\mingw32\bin\gdb.exe'.

            exe asFilename exists ifTrue:[ ^ exe ].

        ]

    ].

    "/ Search for `gdb` along the PATH...

    exe := OperatingSystem pathOfCommand: 'gdb-multiarch'.

    exe notNil ifTrue:[ ^ exe ].   

    exe := OperatingSystem pathOfCommand: 'gdb'.

    exe notNil ifTrue:[ ^ exe ].   

    "/ Nothing found :-(

    ^ nil

    "

    GDBProcess  gdbCommand

    UserPreferences current gdbCommand: nil.

    UserPreferences current gdbCommand: '/home/jv/Projects/gdb/users_jv_vdb/gdb/gdb'.

    "

    "Created: / 17-06-2019 / 14:20:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 16-05-2023 / 17:28:56 / Jan Vrany <jan.vrany@labware.com>"

!

gdbCommandParseAndValidate:command 

    "Given a `command`, checks whether it is a valid gdb command.

     Returns absolute path to gdb binary and global arguments (if any)

     or raise an GDBError if `command` is not valid hg command."

    | tokens  executable  executableAsFilename  arguments  version |

    command isEmptyOrNil ifTrue:[

        GDBError 

            raiseErrorString:('''gdb'' executable not configured and not found in standard places!!').

        ^ nil

    ].

    command asFilename exists ifTrue:[

        executable := command.

        arguments := #().

    ] ifFalse:[

        tokens := GDBShellCommandParser parse:command.

        executable := tokens first.

        arguments := tokens copyFrom:2.

    ].

    executableAsFilename := executable asFilename.

    executableAsFilename isAbsolute ifFalse:[

        executableAsFilename := executableAsFilename asAbsoluteFilename.

        executableAsFilename exists ifTrue:[

            executable := executableAsFilename pathName.

        ] ifFalse:[

            "/ Also try to find specified command along PATH, maybe somebody

            "/ just typed 'gdb' in...

            executable := (OperatingSystem pathOfCommand:executable).

            executable isNil ifTrue:[

                GDBError 

                    raiseErrorString:('''gdb'' executable (%1) not found!!' bindWith:command).

                ^ nil

            ] ifFalse:[

                executableAsFilename := executable asFilename.

            ].

        ]

    ].

    executableAsFilename exists ifFalse:[

        GDBError 

            raiseErrorString:('Specified ''gdb'' executable (%1) does not exists!!' 

                    bindWith:executable).

        ^ nil

    ].

    executableAsFilename isDirectory ifTrue:[

        GDBError 

            raiseErrorString:('Specified ''gdb'' executable (%1) is actually a directory!!' 

                    bindWith:executable).

        ^ nil

    ].

    executableAsFilename isExecutable ifFalse:[

        GDBError 

            raiseErrorString:('Specified ''gdb'' executable (%1) is cannot be executed!!' 

                    bindWith:executable).

        ^ nil

    ].

     "

     [

     version := self gdbVersionOf: executable arguments: arguments.

     ] on: Error do:[:ex |

     HGInvalidExecutableError newException

     parameter: ex;

     messageText: 'Failed to check version: ', ex description;

     raise.

     ^ nil

     ].

     (self gdbVersionIsSupported: version) ifFalse:[

     HGInvalidVersionError newException

     parameter: version;

     messageText: ('Unsuported Mercurial version (%1)' bindWith: ((version collect:[:e|e printString]) asStringWith:$.));

     raise.

     ^ nil

     ].

    "

    ^ (Array with:executable) , arguments

    "

     GDBProcess  gdbCommand

     GDBProcess gdbCommandParseAndValidate: 'gdb'

     GDBProcess gdbCommandParseAndValidate: 'gdb -q'

"

    "Created: / 18-06-2019 / 10:26:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 20-06-2019 / 11:06:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBProcess class methodsFor:'queries'!

isAbstract

    "Return if this class is an abstract class.

     True is returned here for myself only; false for subclasses.

     Abstract subclasses must redefine again."

    ^ self == GDBProcess.

! !

!GDBProcess methodsFor:'accessing'!

connection:aGDBConnection

    connection := aGDBConnection.

!

consoleInput

    "Return a write stream on debugger's CLI channel. CLI commands

     should be written here. If this process does not have a CLI

     channel opened, `nil` is returned. In this case, CLI must be

     emulated - if required. See `-interpreter-exec` MI command.

     CLI channel is generally available only on Smalltalk/X and only

     on UNIX platform where this stream points to TTY."

    ^ nil

    "Created: / 02-06-2017 / 23:35:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 15-12-2017 / 23:58:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 17-10-2018 / 22:20:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

consoleOutput

    "Return a read stream on debugger's CLI channel. CLI output

     should be read from. If this process does not have a CLI

     channel opened, `nil` is returned. In this case, CLI must be

     emulated - if required.

     CLI channel is generally available only on Smalltalk/X and only

     on UNIX platform where this stream points to TTY."

    ^ nil

    "Created: / 02-06-2017 / 23:35:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 15-12-2017 / 23:58:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 17-10-2018 / 22:21:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

debuggerInput

    "Return a write stream on debugger's MI channel. (MI) commands

     should be written there."

    ^ debuggerInput

    "Modified: / 15-12-2017 / 23:58:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 17-10-2018 / 22:14:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

debuggerOutput

    "Return read stream on debuugger's MI channel. Command responses

     and events should be read from here"

    ^ debuggerOutput

    "Modified: / 15-12-2017 / 23:58:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 17-10-2018 / 22:15:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

id

    "Return a string identification of this GDBProcess. 

     Used for debugging purposes only."

    ^ self subclassResponsibility

    "Created: / 19-10-2018 / 10:08:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nativeTargetFeatures    

    "Return default native target features. This is used when

     used GDB does not support =target-connected and =target-disconnected

     events."

    "/ Be conservative and  report no features at all...

    ^ #()

    "Created: / 09-04-2018 / 15:40:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 17-10-2018 / 22:12:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBProcess methodsFor:'queries'!

canUsePTY

    "Return true if PTYs can be used with this process, false otherwise"

    ^ false

    "Created: / 16-01-2019 / 23:02:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBProcess class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !