"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

Object subclass:#GDBArchitecture

	instanceVariableNames:''

	classVariableNames:'Architectures'

	poolDictionaries:''

	category:'GDB'

!

!GDBArchitecture class methodsFor:'documentation'!

copyright

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

!

documentation

"

    Sub-instances of GDBArchitecture models a target 

    architecture such as x86_64, PowerPC or RISC-V and

    provides architecture-specific services.

    In GDB, each frame has associated architecture (and

    may differ from architecture of other frames!!)

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!GDBArchitecture class methodsFor:'initialization'!

initialize

    "Invoked at system start or when the class is dynamically loaded."

    "/ please change as required (and remove this comment)

    Architectures := Dictionary new

                        at: 'i386'        put: (GDBArch_x86 new setMode: 32; yourself);

                        at: 'i386:x86-64' put: (GDBArch_x86 new setMode: 64; yourself);

                        at: 'riscv:rv64'  put: (GDBArch_RV64 new);

                        at: 'powerpc:common64' put: (GDBArch_PPC64 new);

                        yourself.

    "Created: / 22-05-2020 / 13:21:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-11-2022 / 17:11:05 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBArchitecture class methodsFor:'instance creation'!

named: aString

    Architectures isEmptyOrNil ifTrue:[self initialize].

    ^ Architectures 

        at: aString 

        ifAbsentPut:[GDBArch_unknown new setName: aString ].

    "

    GDBArchitecture named: 'i386:x86-64'

    GDBArchitecture named: 'riscv:rv64'

    GDBArchitecture named: 'mips'

    "

    "Created: / 16-08-2018 / 08:57:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 22-05-2020 / 13:22:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

unknown

    ^ GDBArchitecture named: 'unknown'

    "Created: / 10-06-2019 / 12:37:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 10-06-2019 / 14:38:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBArchitecture methodsFor:'accessing'!

name

    ^ self subclassResponsibility

    "Created: / 16-08-2018 / 07:35:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

registerNameOfProgramCounter

    "Returns the name of program counter register. For example,

     on i386 it is 'eip', on x86_64 it is 'rip'."

    ^ 'pc' "This should be a good guess"

    "Created: / 09-12-2022 / 12:47:44 / Jan Vrany <jan.vrany@labware.com>"

!

registerNamesToDisplay

    "Returns a list of register names to display in register view (VDBRegisterListApplication)

     or `nil` if all available registers are to be displayed.

     This is used on platforms for limit the number of registers, usually

     because either (i) it is too long and has a lots of 'uninterested' registers

     or (ii) some registers are not supported by gdbserver / QEMU or whatever

     and this is used to avoid errors while still displaying 'interesting' registers.

     Essentially a hack.

    "

    ^ nil "/ By default, show all registers

    "Created: / 22-05-2020 / 13:17:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

registerNumbersToDisplayUsing: registerMap

    "Returns a list of register numbers to display or empty list

     to display all registers.

     See #registerNamesToDisplay.

    "

    | inverseMap |

    self registerNamesToDisplay isNil ifTrue:[ ^ #() ].

    inverseMap := Dictionary new.

    registerMap keysAndValuesDo:[:regno :reg | inverseMap at: reg name put: regno ].

    ^ self registerNamesToDisplay collect:[:regname |  inverseMap at: regname ]

    "Created: / 22-05-2020 / 13:42:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-11-2022 / 17:00:24 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBArchitecture methodsFor:'printing & storing'!

printOn:aStream

    super printOn:aStream.

    aStream 

        nextPut: $(;

        nextPutAll: self name;

        nextPut: $).

    "Modified: / 16-08-2018 / 09:01:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBArchitecture methodsFor:'queries'!

sizeofPointer

    self subclassResponsibility

    "Created: / 16-08-2018 / 09:35:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBArchitecture methodsFor:'utilities'!

disassemble1: bytes pc: pc

    "

    Disassemble one instruction from given bytes (as ByteArray)

    and return the instruction dissection. Returned object must

    conform to GDBInstructionDissection protocol.

    @see GDBInstructionDissection

    "

    ^ GDBInstructionDissection null

    "Created: / 16-08-2018 / 10:56:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBArchitecture class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !

GDBArchitecture initialize!