"{ Package: 'jv:libgdbs' }"
"{ NameSpace: Smalltalk }"
GDBDebuggerObject subclass:#GDBThread
instanceVariableNames:'id group status stack'
classVariableNames:''
poolDictionaries:''
category:'GDB-Core'
!
!GDBThread class methodsFor:'instance creation'!
newWithDebugger: debugger id: id group: group
^ self new
setDebugger: debugger;
setId: id;
setGroup: group;
yourself.
"Created: / 07-09-2014 / 21:33:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !
!GDBThread class methodsFor:'accessing - GDB value descriptors'!
description
^ (super description)
define:#id as:Integer;
yourself
"Created: / 06-09-2014 / 02:21:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !
!GDBThread methodsFor:'accessing'!
group
^ group
!
id
^ id
"Created: / 07-09-2014 / 22:41:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
stack
self ensureIsStopped.
stack isNil ifTrue:[
stack := GDBTransientDataHolder debugger: debugger factory:[
| result depth frames |
result := debugger send: (GDBMI_stack_info_depth new arguments: { '--thread' . id . 100 }).
depth := result propertyAt: #depth.
result := debugger send: (GDBMI_stack_list_frames new arguments: { '--thread' . id . 0 . depth - 1 }).
frames := result propertyAt: #stack.
frames do:[:each |
each debugger: debugger.
each propertyAt: #thread put: self
].
frames
].
].
^ stack value
"Created: / 09-09-2014 / 00:02:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified: / 27-02-2015 / 15:10:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
status
^ status
! !
!GDBThread methodsFor:'initialization'!
setGroup: aGDBThreadGroup
self assert: group isNil.
group := aGDBThreadGroup.
"Created: / 07-09-2014 / 21:32:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
setId: tid
self assert: id isNil.
id := tid.
status := GDBThreadStateRunning theOneAndOnlyInstance
"Created: / 07-09-2014 / 21:31:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified: / 27-02-2015 / 09:36:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
setStatus: aGDBThreadState
status := aGDBThreadState.
status isStopped ifFalse:[
stack := nil.
].
"Created: / 07-09-2014 / 23:25:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified: / 09-09-2014 / 00:04:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified (format): / 27-02-2015 / 09:36:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
setTerminated
status := GDBThreadStateTerminated theOneAndOnlyInstance
"Created: / 07-09-2014 / 21:37:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified: / 27-02-2015 / 09:36:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !
!GDBThread methodsFor:'printing & storing'!
printOn:aStream
"append a printed representation if the receiver to the argument, aStream"
aStream nextPutAll:'thread '.
id printOn:aStream.
"/ aStream nextPutAll:'in group '.
"/ group id printOn:aStream.
aStream nextPutAll:' ['.
status printOn:aStream.
aStream nextPutAll:']'.
"Modified: / 22-09-2014 / 00:59:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !
!GDBThread methodsFor:'private'!
ensureIsStopped
self isStopped ifFalse:[
(GDBInvalidObject newException)
parameter:self;
messageText:'Invalid state (thread is running or already dead)';
raise.
].
"Created: / 09-09-2014 / 00:04:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"
"Modified: / 16-09-2014 / 23:51:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !
!GDBThread methodsFor:'testing'!
isDead
^ status isTerminated
"Created: / 22-09-2014 / 00:54:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
isRunning
^ status isRunning
"Created: / 07-09-2014 / 23:23:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
isStopped
^ status isStopped
"Created: / 07-09-2014 / 23:23:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!
isTerminated
^ status isTerminated
"Created: / 07-09-2014 / 23:23:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !