"
jv:libgdbs - GNU Debugger Interface Library
Copyright (C) 2015-now Jan Vrany
Copyright (C) 2022-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the 'Software'), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
"
"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

Object subclass:#GDBShellCommandParser
	instanceVariableNames:'stream'
	classVariableNames:''
	poolDictionaries:''
	category:'GDB-Internal'
!

!GDBShellCommandParser class methodsFor:'documentation'!

copyright
"
jv:libgdbs - GNU Debugger Interface Library
Copyright (C) 2015-now Jan Vrany
Copyright (C) 2022-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the 'Software'), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
"
! !

!GDBShellCommandParser class methodsFor:'parsing'!

parse: input
     "Parses input (stream or string) as a shell command. Returns
     an array of arguments (main's argv[], actually)"

     ^ self new
        stream: input;
        parse

    "
    GDBShellCommandParser parse: 'gdb'
    GDBShellCommandParser parse: 'ssh jv@debian-sid-rv64 gdb'
    "

    "Created: / 12-12-2018 / 16:43:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!GDBShellCommandParser methodsFor:'accessing'!

stream
    ^ stream
!

stream:aStringOrStream
    stream := aStringOrStream readStream.

    "Modified: / 12-12-2018 / 16:39:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!GDBShellCommandParser methodsFor:'parsing'!

parse
    "Parses input stream as a shell command. Returns
     an array of arguments (main's argv[], actually)"

    OperatingSystem isMSWINDOWSlike ifTrue:[ 
        ^ self parseAsForCmd
    ] ifFalse:[
        ^ self parseAsForSh
    ]

    "Created: / 12-12-2018 / 16:40:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 12-07-2023 / 12:10:16 / Jan Vrany <jan.vrany@labware.com>"
! !

!GDBShellCommandParser methodsFor:'parsing - private'!

parseAsForCmd
    ^ Array streamContents:[ :argv | 
        stream skipSeparators.
        [ stream atEnd ] whileFalse:[
            argv nextPut: self parseTokenAsForCmd.
            stream skipSeparators.   
        ].
    ].

    "Created: / 12-12-2018 / 16:41:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

parseAsForSh
    ^ Array streamContents:[ :argv | 
        stream skipSeparators.
        [ stream atEnd ] whileFalse:[
            argv nextPut: self parseTokenAsForSh.
            stream skipSeparators.   
        ].
    ].

    "Created: / 12-12-2018 / 16:40:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

parseTokenAsForCmd
    | buffer char done1 done2 |

    buffer := (String new: 10) writeStream.
    done1 := false.
    char := stream next.
    [ done1 ] whileFalse:[
        char == $" ifTrue:[ 
            done2 := false.
            [ done2 ] whileFalse:[
                stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                char := stream next.
                char == $" ifTrue:[
                    done2 := true.
                ] ifFalse:[ 
                    buffer nextPut: char      
                ].
            ]
        ] ifFalse:[ 
            char == $^ ifTrue:[ 
                stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                char := stream next.                    
                char == Character space ifTrue:[ 
                    buffer nextPut: $^ 
                ].
            ].
            buffer nextPut: char.   
        ].
        char := stream atEnd ifTrue:[ nil ] ifFalse:[ stream next ].  
        done1 := char isNil or:[ char isSeparator ].
    ].
    ^ buffer contents

    "Created: / 12-12-2018 / 16:41:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

parseTokenAsForSh
    | buffer char done1 done2 |

    buffer := (String new: 10) writeStream.
    done1 := false.
    char := stream next.
    [ done1 ] whileFalse:[
        char == $" ifTrue:[ 
            done2 := false.
            [ done2 ] whileFalse:[
                stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                char := stream next.
                char == $\ ifTrue:[ 
                    stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                    char := stream next.
                    char == $" ifTrue:[ 
                        buffer nextPut: $"  
                    ] ifFalse:[ 
                        buffer nextPut: $\; nextPut: char  
                    ].
                ] ifFalse:[ char == $" ifTrue:[
                    done2 := true.
                ] ifFalse:[ 
                    buffer nextPut: char      
                ]].
            ]
        ] ifFalse:[ char == $' ifTrue:[ 
            done2 := false.
            [ done2 ] whileFalse:[
                stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                char := stream next.
                char == $' ifTrue:[
                    done2 := true.
                ] ifFalse:[ 
                    buffer nextPut: char      
                ].                       
            ]
        ] ifFalse:[ 
            char == $\ ifTrue:[ 
                stream atEnd ifTrue:[ self error:'Unterminated string token'. ^ nil ].
                char := stream next.                    
            ].
            buffer nextPut: char.   
        ]].
        char := stream atEnd ifTrue:[ nil ] ifFalse:[ stream next ].  
        done1 := char isNil or:[ char isSeparator ].
    ].
    ^ buffer contents

    "Created: / 12-12-2018 / 16:41:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!GDBShellCommandParser class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'
! !