"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2022 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:vdb' }"

"{ NameSpace: Smalltalk }"

HierarchicalItem subclass:#VDBAbstractPresenter

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'VDB-Presentation'

!

!VDBAbstractPresenter class methodsFor:'documentation'!

copyright

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2022 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

! !

!VDBAbstractPresenter class methodsFor:'menu specs'!

contextMenu

    "This resource specification was automatically generated

     by the MenuEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the MenuEditor may not be able to read the specification."

    "

     MenuEditor new openOnClass:VDBModelPresenter andSelector:#contextMenu

     (Menu new fromLiteralArrayEncoding:(VDBModelPresenter contextMenu)) startUp

    "

    <resource: #menu>

    ^ 

     #(Menu

        nil nil

        nil

      )

! !

!VDBAbstractPresenter class methodsFor:'queries'!

isAbstract

    "Return if this class is an abstract class.

     True is returned here for myself only; false for subclasses.

     Abstract subclasses must redefine this again."

    ^ self == VDBAbstractPresenter.

! !

!VDBAbstractPresenter methodsFor:'accessing'!

backgroundColor

    | app |

    app := self application.

    app notNil ifTrue:[ 

        ^ app perform: #backgroundColorFor: with: self ifNotUnderstood: [ nil ].

    ].

    ^ nil

    "Created: / 06-06-2017 / 23:38:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

foregroundColor

    | app fg |

    app := self application.

    app notNil ifTrue:[ 

        fg := app perform: #foregroundColorFor: with: self ifNotUnderstood: [ nil ].

        "/ If application does not specify foreground color but does specify

        "/ background color, try to be helpful and choose either white or black

        "/ foreground, whichever is more contrasting on given background.

        "/ This helps especially with dark themes.

        fg isNil ifTrue: [ 

            | bg |

            bg := self backgroundColor.

            bg notNil ifTrue: [ 

                fg := bg contrastingBlackOrWhite.

            ].

        ].

    ].

    ^ fg

    "Created: / 26-06-2018 / 11:46:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 14-10-2021 / 13:49:35 / Jan Vrany <jan.vrany@labware.com>"

!

subject

    "Return an instance of GDB object that this presenter displays."

    ^ self subclassResponsibility

    "Created: / 05-02-2018 / 13:07:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

tooltip

    "Return tooltip (fly-by-help) text as string or `nil`. 

     If `nil` is returned, list views will show generic 

     toolip for the item"

    ^ nil

    "Created: / 29-07-2018 / 21:32:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBAbstractPresenter methodsFor:'change & update'!

updateChildren

    "Update children from model.

     Default implementation here re-creates all children. Subclasses may

     override this to provide custom logic in order to minimize changes to

     the tree (or avoid changes alltogether when nothing has changed).

    "

    children notNil ifTrue: [ 

        self children: self fetchChildren

    ].

    "Created: / 21-09-2014 / 23:43:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-05-2021 / 16:21:14 / Jan Vrany <jan.vrany@labware.com>"

    "Modified (format): / 17-05-2021 / 19:42:15 / Jan Vrany <jan.vrany@labware.com>"

! !

!VDBAbstractPresenter methodsFor:'displaying'!

displayString

    ^ self label

    "Created: / 10-06-2017 / 12:24:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBAbstractPresenter methodsFor:'menu'!

contextMenu

    | menu |

    menu := Menu decodeFromLiteralArray: self class contextMenu.

    menu hasItems ifFalse:[ ^ menu ].

    menu findGuiResourcesIn:self.

    menu itemsDo:[:item| item receiver: self ].

    menu addSeparator.

    self contextMenuExtendersFor: #contextMenu do:[:each |

        self perform: each with: menu

    ]. 

    ^ menu

    "Created: / 16-01-2018 / 22:03:53 / jv"

    "Modified: / 07-02-2018 / 09:52:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

contextMenuExtendersFor: key do: block

    "Evaluates a block for each selector that extends particular menu.

     Extender methods have to be annotated by <menuextension: key> annotation

     and must take one argument (an instance of Menu that the menu extension

     extends."

    | cls |

    cls := self class.

    [ cls notNil ] whileTrue:[

        cls selectorsAndMethodsDo:[ :selector :method |

            method annotationsAt: #menuextension: do: [ :annotation |

                annotation arguments first == key ifTrue:[

                    block value: selector

                ].

            ]

        ].

        cls := cls superclass.

    ].

    "Created: / 07-02-2018 / 09:51:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBAbstractPresenter methodsFor:'menu actions'!

doCopy: aString

    <resource: #uiCallback>

    self application window setClipboardText: aString

    "Created: / 16-01-2018 / 22:36:30 / jv"

!

doDoubleClick

    "Invoked when user double-clicks to list item. "

    self doInspect

    "Created: / 05-02-2018 / 13:03:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-11-2021 / 13:20:33 / Jan Vrany <jan.vrany@labware.com>"

!

doInspect

    self doInspect: self subject

    "Created: / 17-11-2021 / 13:21:13 / Jan Vrany <jan.vrany@labware.com>"

!

doInspect: anObject 

    | app |

    app := self application.

    app notNil ifTrue:[

        app doInspect: anObject

    ] ifFalse: [ 

        anObject inspect.

    ].

    "Created: / 08-07-2019 / 20:17:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-11-2021 / 13:19:13 / Jan Vrany <jan.vrany@labware.com>"

! !

!VDBAbstractPresenter methodsFor:'protocol-displaying'!

displayOn:aGC x:x y:y h:h isHighlightedAsSelected: isHighlightedAsSelected

    isHighlightedAsSelected ifFalse:[ 

        | bg fg |

        fg := self foregroundColor.

        bg := self backgroundColor.

        (fg notNil or:[ bg notNil ]) ifTrue:[

            | fgSaved |

            fgSaved := aGC paint.

            [ 

                bg notNil ifTrue:[ 

                    aGC paint: bg.

                    aGC fillRectangleX: 0"x" y: y width: aGC width height: h.

                    aGC paint: fg ? fgSaved.

                ] ifFalse:[

                    fg notNil ifTrue:[

                        aGC paint: fg.

                    ].

                ].

                super displayOn:aGC x:x y:y h:h isHighlightedAsSelected: isHighlightedAsSelected

            ] ensure:[ 

                aGC paint: fgSaved.

            ].

            ^ self.

        ]

    ].

    super displayOn:aGC x:x y:y h:h isHighlightedAsSelected: isHighlightedAsSelected

    "Created: / 22-05-2021 / 17:05:59 / Jan Vrany <jan.vrany@labware.com>"

! !

!VDBAbstractPresenter methodsFor:'testing'!

isBreakpointPresenter

    ^ false

    "Created: / 11-07-2017 / 11:50:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isFramePresenter

    ^ false

    "Created: / 21-09-2014 / 23:53:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isInstructionPresenter

    ^ false

!

isInstructionsAndSourcePresenter

    ^ false

!

isRegisterPresenter

    ^ false

!

isThreadGroupPresenter

    ^ false

    "Created: / 21-09-2014 / 23:54:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isThreadPresenter

    ^ false

    "Created: / 21-09-2014 / 23:54:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isVariablePresenter

    ^ false

    "Created: / 02-06-2017 / 00:05:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBAbstractPresenter class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !