"{ Package: 'stx:goodies/monticello' }"

Object subclass:#MCReader
	instanceVariableNames:'stream'
	classVariableNames:''
	poolDictionaries:''
	category:'SCM-Monticello-Storing'
!


!MCReader class methodsFor:'instance creation'!

on: aStringOrStream
        ^ self new stream: aStringOrStream readStream

    "Modified: / 25-11-2011 / 16:57:41 / cg"
!

on: aStream name: aFileName
	| class |
	class := self readerClassForFileNamed: aFileName.
	^ class
		ifNil: [self error: 'Unsupported format: ', aFileName]
		ifNotNil: [class on: aStream]
! !

!MCReader class methodsFor:'testing'!

canReadFileNamed: fileName
	^ (fileName endsWith: self extension)
!

concreteSubclasses
	^ self allSubclasses reject: [:c | c isAbstract]
!

isAbstract
	^ (self respondsTo: #extension) not
!

readerClassForFileNamed: fileName
	^ self concreteSubclasses
		detect: [:c | c canReadFileNamed: fileName]
		ifNone: [nil]
! !

!MCReader methodsFor:'accessing'!

stream: aStream
	stream := aStream
! !

!MCReader class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCReader.st,v 1.5 2012-09-11 21:26:02 cg Exp $'
!

version_CVS
    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCReader.st,v 1.5 2012-09-11 21:26:02 cg Exp $'
!

version_SVN
    ^ '§Id: MCReader.st 5 2010-08-29 07:30:29Z vranyj1 §'
! !