"{ Package: 'stx:goodies/monticello' }"

MCFileBasedRepository subclass:#MCDirectoryRepository
	instanceVariableNames:'directory'
	classVariableNames:''
	poolDictionaries:''
	category:'Monticello-Repositories'
!


!MCDirectoryRepository class methodsFor:'initialization'!

new
    ^self basicNew initialize
! !

!MCDirectoryRepository class methodsFor:'instance creation'!

description
	^ 'directory'
!

directory: aStringOrFileDirectory

    ^self new directory: aStringOrFileDirectory

    "Created: / 16-09-2010 / 14:51:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 16-09-2010 / 15:59:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

morphicConfigure
	| directory |
	^ (directory := UIManager default chooseDirectory) ifNotNil:
		[
		self new directory: directory]
! !

!MCDirectoryRepository class methodsFor:'as yet unclassified'!

creationTemplate
    "superclass MCRepository class says that I am responsible to implement this method"

    ^'MCDirectoryRepository directory: ''%1'''
        bindWith: (Filename currentDirectory asAbsoluteFilename / 'package-cache') asString

    "Modified: / 16-09-2010 / 14:53:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

fillInTheBlankRequest
    "superclass MCRepository class says that I am responsible to implement this method"

    ^ self shouldImplement
! !

!MCDirectoryRepository methodsFor:'as yet unclassified'!

allFileNames
	^ (directory entries sortBy: [:a :b | a modificationTime >= b modificationTime]) collect: [:ea | ea name]
!

description
	^ directory pathName
!

directory
	^ directory
!

directory: aStringOrDirectory

    directory := aStringOrDirectory isString 
        ifTrue:[FileDirectory directoryNamed: aStringOrDirectory]
        ifFalse:[aStringOrDirectory].

    "Modified: / 16-09-2010 / 15:58:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

initialize
	super initialize.
	directory := FileDirectory default
!

isValid
	^directory exists
!

literalArrayEncoding

    ^Array 
        with: self class name asSymbol
        with: #directory:
        with: directory directoryName

    "
        (MCDirectoryRepository directory: '/tmp')
            literalArrayEncoding decodeAsLiteralArray
    "

    "Created: / 16-09-2010 / 16:01:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

readStreamForFileNamed: aString do: aBlock
	| file val |
	file := FileStream readOnlyFileNamed: (directory fullNameFor: aString).
	val := aBlock value: file.
	file close.
	^ val
!

writeStreamForFileNamed: aString replace: aBoolean do: aBlock
	| file sel |
	sel := aBoolean ifTrue: [#forceNewFileNamed:] ifFalse: [#newFileNamed:].
	file := FileStream perform: sel with: (directory fullNameFor: aString).
	aBlock value: file.
	file close.
! !

!MCDirectoryRepository methodsFor:'comparing'!

hash
	^ directory pathName hash
! !

!MCDirectoryRepository methodsFor:'displaying'!

displayString

    ^directory directoryName

    "Created: / 14-09-2010 / 23:18:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!MCDirectoryRepository class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCDirectoryRepository.st,v 1.3 2011-08-20 12:28:13 cg Exp $'
!

version_CVS
    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCDirectoryRepository.st,v 1.3 2011-08-20 12:28:13 cg Exp $'
!

version_SVN
    ^ '§Id: MCDirectoryRepository.st 17 2010-10-13 12:07:52Z vranyj1 §'
! !