"{ Package: 'stx:goodies/monticello' }"

MCPatchOperation subclass:#MCModification
	instanceVariableNames:'obsoletion modification'
	classVariableNames:''
	poolDictionaries:''
	category:'Monticello-Patching'
!


!MCModification class methodsFor:'as yet unclassified'!

of: base to: target
	^ self new initializeWithBase: base target: target
! !

!MCModification methodsFor:'accessing'!

applyTo: anObject
	anObject modifyDefinition: obsoletion to: modification
!

baseDefinition
	^ obsoletion
!

definition
	^ modification
!

fromSource
	^ obsoletion source
!

modification
	^ modification
!

obsoletion
	^ obsoletion
!

summarySuffix
	^self fromSource = self toSource
		ifTrue: [ ' (source same but rev changed)' ]
		ifFalse: [ ' (changed)' ]
!

targetClass
	^ obsoletion actualClass
!

targetDefinition
	^ modification
!

toSource
	^ modification source
! !

!MCModification methodsFor:'as yet unclassified'!

inverse
	^ MCModification of: modification to: obsoletion
!

isClassPatch
	^obsoletion isClassDefinition
!

printAnnotations: request on: aStream
	aStream nextPutAll: 'old: '.
	obsoletion printAnnotations: request on: aStream.
	aStream cr.
	aStream nextPutAll: 'new: '.
	modification printAnnotations: request on: aStream.
! !

!MCModification methodsFor:'initializing'!

initializeWithBase: base target: target
	obsoletion _ base.
	modification _ target.
! !

!MCModification methodsFor:'testing'!

isModification
	^ true
! !

!MCModification class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCModification.st,v 1.1 2006-11-22 13:12:20 cg Exp $'
! !