Updated to PetitCompiler-JanKurs.118, PetitCompiler-Tests-JanKurs.46, PetitCompiler-Extras-Tests-JanKurs.11, and PetitCompiler-Benchmarks-JanKurs.11
Name: PetitCompiler-JanKurs.118
Author: JanKurs
Time: 13-05-2015, 03:59:01.292 PM
UUID: 4a8ccd94-3131-4cc7-9098-528f8e5ea0b5
Name: PetitCompiler-Tests-JanKurs.46
Author: JanKurs
Time: 04-05-2015, 04:25:06.162 PM
UUID: 9f4cf8b7-876e-4a13-9579-b833f016db66
Name: PetitCompiler-Extras-Tests-JanKurs.11
Author: JanKurs
Time: 13-05-2015, 04:27:27.940 PM
UUID: e9f30c31-fbd0-4e96-ad2a-868f88d20ea8
Name: PetitCompiler-Benchmarks-JanKurs.11
Author: JanKurs
Time: 13-05-2015, 02:21:49.932 PM
UUID: 6a23fd1e-a86f-46db-8221-cc41b778d32c
"{ Package: 'stx:goodies/petitparser/tests' }"
"{ NameSpace: Smalltalk }"
TestCase subclass:#PPAbstractParserTest
instanceVariableNames:''
classVariableNames:''
poolDictionaries:''
category:'PetitTests-Core'
!
!PPAbstractParserTest class methodsFor:'accessing'!
packageNamesUnderTest
^ #('PetitParser' 'PetitTests')
! !
!PPAbstractParserTest class methodsFor:'testing'!
isAbstract
^ self name = #PPAbstractParserTest
! !
!PPAbstractParserTest methodsFor:'context'!
context
^ PPContext new
! !
!PPAbstractParserTest methodsFor:'utilities'!
assert: aParser fail: aCollection
^ self assert: aParser fail: aCollection end: 0
!
assert: aParser fail: aCollection end: anInteger
| stream result context |
self
assert: aParser isPetitParser
description: 'Parser invalid'.
stream := aCollection asPetitStream.
context := self context.
result := aParser parse: stream withContext: context.
self
assert: result isPetitFailure
description: 'Parser did not fail'.
self
assert: context position = anInteger
description: 'Parser failed at wrong position'.
^ result
!
assert: string1 includesSubstring: string2
"Support portability by using ANSI search method"
self assert: (string1 notEmpty and: [string2 notEmpty and: [0 < (string1 indexOfSubCollection: string2 startingAt: 1)]])
!
assert: aParser parse: aCollection
^ self assert: aParser parse: aCollection to: nil end: aCollection size
!
assert: aParser parse: aCollection end: anInteger
^ self assert: aParser parse: aCollection to: nil end: anInteger
!
assert: aParser parse: aCollection to: anObject
^ self assert: aParser parse: aCollection to: anObject end: aCollection size
!
assert: aParser parse: aCollection to: aTargetObject end: anInteger
| stream result context |
self assert: aParser isPetitParser description: 'Parser invalid'.
stream := aCollection asPetitStream.
context := self context.
result := aParser parse: stream withContext: context.
aTargetObject isNil
ifTrue: [ self deny: result isPetitFailure ]
ifFalse: [ self assert: result equals: aTargetObject ].
self assert: context position = anInteger description: 'Parser accepted at wrong position'.
^ result
!
assert: aParser parse: aCollection toToken: aStartInteger stop: aStopInteger
^ self assert: aParser parse: aCollection toToken: aStartInteger stop: aStopInteger end: aCollection size
!
assert: aParser parse: aParserObject toToken: aStartInteger stop: aStopInteger end: anEndInteger
| token |
token := self
assert: aParser
parse: aParserObject
to: nil
end: anEndInteger.
self assert: (token isKindOf: PPToken).
self assert: token start equals: aStartInteger.
self assert: token stop equals: aStopInteger.
^ token
! !
!PPAbstractParserTest class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/goodies/petitparser/tests/PPAbstractParserTest.st,v 1.2 2014-03-04 20:31:52 cg Exp $'
!
version_CVS
^ '$Header: /cvs/stx/stx/goodies/petitparser/tests/PPAbstractParserTest.st,v 1.2 2014-03-04 20:31:52 cg Exp $'
!
version_HG
^ '$Changeset: <not expanded> $'
! !