"{ Package: 'stx:goodies/regression' }"

"{ NameSpace: RegressionTests }"

TestCase subclass:#SmallDictionaryTest
	instanceVariableNames:'dictionaryClass'
	classVariableNames:''
	poolDictionaries:''
	category:'tests-Regression-Collections'
!


!SmallDictionaryTest class methodsFor:'queries'!

coveredClassNames
    ^ #( SmallDictionary )
! !

!SmallDictionaryTest methodsFor:'initialize / release'!

setUp
    dictionaryClass := SmallDictionary.

    "Created: / 14-09-2018 / 16:38:30 / Stefan Vogel"
! !

!SmallDictionaryTest methodsFor:'testing'!

test01_AddAll
        "(self run: #testAddAll)"

        | dict1 dict2 |

        dict1 := dictionaryClass new.
        self assert:(dict1 isEmpty).
        self assert:(dict1 size == 0).

        dict1 at: #a put:1 ; at: #b put: 2.
        dict2 := dictionaryClass new.
        dict2 at: #a put: 3 ; at: #c put: 4.
        dict1 addAll: dict2.
        self assert: (dict1 at: #a) = 3.
        self assert: (dict1 at: #b) = 2.
        self assert: (dict1 at: #c) = 4.

    "Modified: / 14-09-2018 / 16:38:54 / Stefan Vogel"
!

test02_AssociationsSelect

        "(self selector: #testAssociationsSelect) run"

        | answer d|

        d := dictionaryClass new.
        d at: (Array with: #hello with: #world) put: #fooBar.
        d at: Smalltalk put: #'Smalltalk is the key'.
        d at: #Smalltalk put: Smalltalk.

        answer := d associationsSelect:
                [:assoc | (assoc key == #Smalltalk) and: [assoc value == Smalltalk]].
        self should: [answer isKindOf: dictionaryClass].
        self should: [answer size == 1].
        self should: [(answer at: #Smalltalk) == Smalltalk].

        answer := d associationsSelect:
                [:assoc | (assoc key == #NoSuchKey) and: [assoc value == #NoSuchValue]].
        self should: [answer isKindOf: dictionaryClass].
        self should: [answer size == 0]

    "Modified: / 14-09-2018 / 16:39:05 / Stefan Vogel"
!

test03_Comma
        "(self run: #testComma)"

        | dict1 dict2 dict3 |
        dict1 := dictionaryClass new.
        dict1 at: #a put:1 ; at: #b put: 2.
        dict2 := dictionaryClass new.
        dict2 at: #a put: 3 ; at: #c put: 4.
        dict3 := dict1, dict2.
        self assert: (dict3 at: #a) = 3.
        self assert: (dict3 at: #b) = 2.
        self assert: (dict3 at: #c) = 4.

    "Modified: / 14-09-2018 / 16:39:14 / Stefan Vogel"
!

test04_IncludesAssociation
        "self debug: #testIncludesAssociation"

        | d |
        d := dictionaryClass new
                at: #five put: 5;
                at: #givemefive put: 5;
                at: #six put: 6;
                yourself.

        self assert: (d includesAssociation: (d associationAt: #five)).
        self assert: (d associationAt: #five) key == #five.
        self assert: (d associationAt: #five) value == 5.
        self assert: (d includesAssociation: (#five -> 5)).
        self assert: (d includesAssociation: (#five -> 6)) not.

    "Modified: / 06-12-2016 / 14:19:15 / cg"
    "Modified: / 14-09-2018 / 16:39:21 / Stefan Vogel"
!

test05_RemoveAllDeclareAll
    "self debug: #testRemoveAllDeclareAll"

    "/ verifies that we can restore a dictionaries original contents
    "/ by making a copy of it, then redeclaring from the copy.
    "/ (needed by the refactorybrowser)
    
    | d copyOfIt |
    
    d := dictionaryClass new
            at: #five put: (5@5);
            at: #givemefive put: (55@55);
            at: #six put: (6@6);
            yourself.

    copyOfIt := d copy.
    d keysAndValuesDo:[:k :v |
        self assert: (copyOfIt at:k) == v.
    ].

    "/ add something
    d at:#seven put:(7@7).

    "/ removeall - redeclare
    d removeAll; declareAllFrom:copyOfIt.

    self assert: (d size = copyOfIt size).
    self assert: (d keys = copyOfIt keys).
    d keysAndValuesDo:[:k :v |
        self assert: (copyOfIt at:k) == v.
    ].

    "Created: / 06-02-2017 / 12:26:22 / cg"
    "Modified: / 14-09-2018 / 16:39:28 / Stefan Vogel"
!

test06_AddRemove
    "self debug: #testRemoveAllDeclareAll"

    "/ verifies that we can restore a dictionaries original contents
    "/ by making a copy of it, then redeclaring from the copy.
    "/ (needed by the refactorybrowser)
    
    | d a |
    
    d := dictionaryClass new.
    d at:'a' put:1.
    self assert:(d includesKey:'a').
    self assert:d size == 1.
    self assert:(d instVarNamed:'tally') == 1.

    d at:'b' put:2.
    self assert:(d includesKey:'a').
    self assert:(d includesKey:'b').
    self assert:d size == 2.
    self assert:(d instVarNamed:'tally') == 2.

    d at:'c' put:3.
    self assert:(d includesKey:'a').
    self assert:(d includesKey:'b').
    self assert:(d includesKey:'c').
    self assert:(d at:'a') == 1.
    self assert:(d at:'b') == 2.
    self assert:(d at:'c') == 3.
    self assert:d size == 3.
    self assert:(d instVarNamed:'tally') == 3.
    self assert:(d order = #('a' 'b' 'c')).

    d removeKey:'b'.
    self assert:(d includesKey:'a').
    self assert:(d includesKey:'b') not.
    self assert:(d includesKey:'c').
    self assert:(d at:'a') == 1.
    self assert:(d at:'b' ifAbsent:nil) isNil.
    self assert:(d at:'c') == 3.
    self assert:d size == 2.
    self assert:(d instVarNamed:'tally') == 2.
    a := (d instVarNamed:'keysAndValues').
    self assert:(a = #('a' 1 'c' 3 nil nil nil nil)).
    self assert:(d order = #('a' 'c')).
!

test07_AddAssoc
    | d |
    
    d := dictionaryClass new.
    d add:('a' -> 1).
    d add:('b' -> 2).
    d add:('c' -> 3).

    d at:'c' put:3.
    self assert:(d includesKey:'a').
    self assert:(d includesKey:'b').
    self assert:(d includesKey:'c').
    self assert:(d at:'a') == 1.
    self assert:(d at:'b') == 2.
    self assert:(d at:'c') == 3.
    self assert:d size == 3.

    self assert:(d order = #('a' 'b' 'c')).

!

test08_Do
    | d coll |
    
    d := dictionaryClass new.
    d add:('a' -> 1).
    d add:('b' -> 2).
    d add:('c' -> 3).

    coll := OrderedCollection new.
    d do:[:each |
        coll add:each
    ].
    self assert:(coll sameContentsAs:#(1 2 3)).

    d removeKey:'a'.
    coll := OrderedCollection new.
    d do:[:each |
        coll add:each
    ].
    self assert:(coll sameContentsAs:#(2 3)).
!

test08_KeysAndValuesDo
    | d coll |
    
    d := dictionaryClass new.
    d add:('a' -> 1).
    d add:('b' -> 2).
    d add:('c' -> 3).

    coll := OrderedCollection new.
    d keysAndValuesDo:[:eachKey :eachValue |
        coll add:eachKey.
        coll add:eachValue.
    ].
    self assert:(coll sameContentsAs:#('a' 1 'b' 2 'c' 3)).

    d removeKey:'a'.
    coll := OrderedCollection new.
    d keysAndValuesDo:[:eachKey :eachValue |
        coll add:eachKey.
        coll add:eachValue.
    ].
    self assert:(coll sameContentsAs:#('b' 2 'c' 3)).
!

test08_KeysDo
    | d coll |
    
    d := dictionaryClass new.
    d add:('a' -> 1).
    d add:('b' -> 2).
    d add:('c' -> 3).

    coll := OrderedCollection new.
    d keysDo:[:eachKey |
        coll add:eachKey.
    ].
    self assert:(coll sameContentsAs:#('a'  'b'  'c' )).

    d removeKey:'a'.
    coll := OrderedCollection new.
    d keysDo:[:eachKey |
        coll add:eachKey.
    ].
    self assert:(coll sameContentsAs:#('b'  'c' )).
! !

!SmallDictionaryTest class methodsFor:'documentation'!

version_CVS
    ^ '$Header$'
! !