"{ Package: 'stx:goodies/regression' }"

"{ NameSpace: RegressionTests }"

TestCase subclass:#DictionaryTest
	instanceVariableNames:''
	classVariableNames:''
	poolDictionaries:''
	category:'tests-Regression-Collections'
!


!DictionaryTest methodsFor:'testing'!

testAddAll
	"(self run: #testAddAll)"

	| dict1 dict2 |
	dict1 := Dictionary new.
	dict1 at: #a put:1 ; at: #b put: 2.
	dict2 := Dictionary new.
	dict2 at: #a put: 3 ; at: #c put: 4.
	dict1 addAll: dict2.
	self assert: (dict1 at: #a) = 3.
	self assert: (dict1 at: #b) = 2.
	self assert: (dict1 at: #c) = 4.
!

testAssociationsSelect

	"(self selector: #testAssociationsSelect) run"

	| answer d|

	d _ Dictionary new.
	d at: (Array with: #hello with: #world) put: #fooBar.
	d at: Smalltalk put: #'Smalltalk is the key'.
	d at: #Smalltalk put: Smalltalk.

	answer _ d associationsSelect:
		[:assoc | (assoc key == #Smalltalk) and: [assoc value == Smalltalk]].
	self should: [answer isKindOf: Dictionary].
	self should: [answer size == 1].
	self should: [(answer at: #Smalltalk) == Smalltalk].

	answer _ d associationsSelect:
		[:assoc | (assoc key == #NoSuchKey) and: [assoc value == #NoSuchValue]].
	self should: [answer isKindOf: Dictionary].
	self should: [answer size == 0]
!

testComma
	"(self run: #testComma)"

	| dict1 dict2 dict3 |
	dict1 := Dictionary new.
	dict1 at: #a put:1 ; at: #b put: 2.
	dict2 := Dictionary new.
	dict2 at: #a put: 3 ; at: #c put: 4.
	dict3 := dict1, dict2.
	self assert: (dict3 at: #a) = 3.
	self assert: (dict3 at: #b) = 2.
	self assert: (dict3 at: #c) = 4.
!

testIncludesAssociation
	"self debug: #testIncludesAssociation"

	| d |
	d := Dictionary new
		at: #five put: 5;
		at: #givemefive put: 5;
		at: #six put: 6;
		yourself.

	self assert: (d includesAssociation: (d associationAt: #five)).
	self assert: (d includesAssociation: (#five -> 5)).
	self assert: (d includesAssociation: (#five -> 6)) not.
! !

!DictionaryTest class methodsFor:'documentation'!

version
    ^ '$Header$'
! !