"{ Package: 'stx:goodies/smaCC' }"

"{ NameSpace: SmaCC }"

Object subclass:#SmaCCSymbol

	instanceVariableNames:'name precedence firstItems'

	classVariableNames:'EmptySymbol ErrorSymbol SentinelSymbol'

	poolDictionaries:''

	category:'SmaCC-Parser Generator'

!

SmaCCSymbol comment:'SmaCCSymbol is an abstract class that represents a symbol in the grammar.

Subclasses must implement the following messages:

	accessing

		calculateFirstTerminals

	testing

		isTerminal

Instance Variables:

	firstItems	<Collection of: SmaCCTerminalSymbol>	the first terminals that can be produced from us

	name	<String>	our name

	precedence	<Integer>	our precedence (in case of shift/reduce conflicts)

'

!

!SmaCCSymbol class methodsFor:'instance creation'!

empty

	EmptySymbol isNil 

		ifTrue: [EmptySymbol := SmaCCTerminalSymbol name: 'E O F'].

	^EmptySymbol

!

error

	ErrorSymbol isNil 

		ifTrue: [ErrorSymbol := SmaCCTerminalSymbol name: 'error'].

	^ErrorSymbol

!

name: aString 

	^(self new)

		name: aString;

		yourself

!

releaseObjects

	EmptySymbol := nil.

	SentinelSymbol := nil

!

sentinel

	SentinelSymbol isNil 

		ifTrue: [SentinelSymbol := SmaCCTerminalSymbol name: 'S e n t i n e l'].

	^SentinelSymbol

! !

!SmaCCSymbol methodsFor:'accessing'!

calculateFirstTerminals

	^self subclassResponsibility

!

createIdMethod

	^false

!

firstTerminals

	^firstItems

!

isEmptySymbol

	^self = self class empty

!

name

	^name

!

precedence

	^precedence

!

precedence: anInteger

	precedence := anInteger

!

productionsDo: aBlock

!

regularExpression

	^nil

! !

!SmaCCSymbol methodsFor:'initialize-release'!

name: aString 

	name := aString.

	firstItems := Set new

! !

!SmaCCSymbol methodsFor:'printing'!

printOn: aStream 

	aStream nextPutAll: name

! !

!SmaCCSymbol methodsFor:'public'!

isStartingSymbol

	^false

!

isTerminal

	^self subclassResponsibility

! !

!SmaCCSymbol class methodsFor:'documentation'!

version

    ^ '$Header: /opt/data/cvs/stx/goodies/smaCC/SmaCC__SmaCCSymbol.st,v 1.1 2006-02-09 21:14:28 vranyj1 Exp $'

!

version_SVN

    ^ '$Id$'

! !