"{ Package: 'jv:smallsense' }"

"{ NameSpace: SmallSense }"

CompletionEngine subclass:#JavaCompletionEngineSimple

	instanceVariableNames:'class method'

	classVariableNames:''

	poolDictionaries:''

	category:'SmallSense-Java'

!

!JavaCompletionEngineSimple methodsFor:'completion'!

complete

    | line col scanner token tokens values maybeReceiverToken |

    line := codeView listAt: codeView cursorLine.

    col := codeView cursorCol.

    line isNil ifTrue:[ ^ nil ].

    line size < (col - 1) ifTrue:[ ^ nil ].

    "/ we need at least three characters in order to reduce

    "/ completions...

    line size < 3 ifTrue:[ ^ nil ]. 

    col - 3 to: col - 1 do:[:i|

        | c |

        c := line at: i.

        (c isLetterOrDigit or:[c == $_ or:[ c == $$ ] ]) ifFalse:[ ^ nil ] 

    ].

    "/ Setup some context vars

    method := codeView editedMethod.

    class := method notNil ifTrue:[method mclass] ifFalse:[codeView editedClass ].

    "/ ok, we got three character prefix, now scan the current line...

    scanner := JavaScanner for: line.

    tokens := OrderedCollection new.

    values := OrderedCollection new.

    [

        [ (token := scanner nextToken) ~~ #EOF and:[ scanner tokenStartPosition < (col - 1) ] ] whileTrue:[

            tokens add: token.

            values add: scanner tokenValue.

        ].

    ] on: Error do:[ 

        ^ nil 

    ].

    "/ now check whether the butlast token is dot...

    maybeReceiverToken := nil.

    (tokens size > 1 and:[(tokens at: tokens size - 1) == $.]) ifTrue:[

        "/ if so, it's likely a message send, then complete methods...

        tokens size > 2 ifTrue:[

            maybeReceiverToken := values at: values size - 2.

        ].

    ] ifFalse:[

        "/ if not, then complete local variables, fields and methods defined in the class itself.

        maybeReceiverToken := 'this'.

    ].

    maybeReceiverToken = 'this' ifTrue:[

        values last first isUppercase ifTrue:[      

            self addClassesStartingWith: values last.

        ] ifFalse:[

            self addFieldsStartingWith: values last.

            self addLocalsStartingWith: values last.

        ].

    ].

    self addMethodsForReceiver: maybeReceiverToken startingWith: values last.

    ^ result

    "Created: / 02-10-2013 / 13:55:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-10-2013 / 17:48:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaCompletionEngineSimple methodsFor:'completion-individual'!

addClassesStartingWith: prefix

    self allClassesDo:[:cls|

        | name i |

        name := cls name.

        i := name lastIndexOf: $/.

        ((name size >= (i + prefix size))

            and:[(name at: i + 1) == prefix first

            and:[(name at: i + prefix size) == prefix last

            and:[(2 to: prefix size - 1) allSatisfy:[:o| (name at: i + o) == (prefix at: o)]]]])

            ifTrue:[

                result add: (ClassPO new subject: cls).        

            ].

    ].

    "Created: / 03-10-2013 / 11:16:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-10-2013 / 18:10:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addFieldsStartingWith: prefix

    | klass |

    klass := class.

    [ klass notNil ] whileTrue:[

        klass instVarNames do:[:nm |

            result add: (VariablePO instanceVariable: nm in: klass).

        ].

        klass := klass superclass.

    ].

    "Created: / 03-10-2013 / 11:16:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addLocalsStartingWith: prefix

    "Created: / 03-10-2013 / 17:46:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addMethodsForReceiver: maybeReceiverToken startingWith: prefix    

    ^ self addMethodsStartingWith: prefix

    "Created: / 03-10-2013 / 17:46:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addMethodsStartingWith: prefix    

    ^ self addMethodsStartingWith: prefix filter: [:m | m isJavaMethod ]

    "Created: / 03-10-2013 / 18:01:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

allClassesDo: aBlock

    | loader loaders |

    loaders := Set new.

    loader := (class notNil and:[class isJavaClass]) ifTrue:[class classLoader] ifFalse:[JavaVM systemClassLoader].

    [ loader notNil ] whileTrue:[

        loaders add: loader.

        loader := loader instVarNamed: #parent.

    ].

    loaders add: nil.

    JavaVM registry  classesDo:[:cls|

        (loaders includes: cls classLoader) ifTrue:[

            aBlock value: cls.

        ].

    ].

    "Created: / 03-10-2013 / 17:52:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !