"{ Package: 'jv:smallsense' }"

Object subclass:#SmallSenseRecognizer

	instanceVariableNames:'resultSet collector'

	classVariableNames:''

	poolDictionaries:''

	category:'SmallSense-Core'

!

!SmallSenseRecognizer class methodsFor:'utilities'!

old_resultSetFor: mode source: source class: class row: row column: col 

    | parser tree |

    mode == #method ifTrue:[

        parser := SmallSenseParser new.

        parser 

            parseMethod:source asString

            in: class

            ignoreErrors:false

            ignoreWarnings:false.

    ] ifFalse:[

        parser := SmallSenseParser for: (source asString readStream).

        "JV@2011-06-13: HACK, use polymorphism"

        tree := parser

            parseExpressionWithSelf:nil 

            notifying:nil 

            ignoreErrors:false 

            ignoreWarnings:false 

            inNameSpace:nil.

        parser tree: tree.

    ].

    ^ self new

        recognize:row

        position:col

        collector:parser

    "Modified: / 07-04-2011 / 22:55:58 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 14:40:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

resultSetFor: mode source: source class: class line: line column: col 

    | inferencer tree |

    mode == #method ifTrue:[

        inferencer := SmallSenseInferencer forClass: class methodSource: source asString.

        inferencer parserClass: SmallSenseParser.

        inferencer process.

    ] ifFalse:[

        self breakPoint: #jv.

        ^self.

        inferencer := SmallSenseParser for: (source asString readStream).

        "JV@2011-06-13: HACK, use polymorphism"

        tree := inferencer

            parseExpressionWithSelf:nil 

            notifying:nil 

            ignoreErrors:false 

            ignoreWarnings:false 

            inNameSpace:nil.

        inferencer tree: tree.

    ].

    ^ self new

        completeAtLine:line

        column:col

        collector:inferencer

    "Modified: / 07-04-2011 / 22:55:58 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 17:53:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!SmallSenseRecognizer methodsFor:'adding'!

addClassVariables

    | class |

    class := collector klass theNonMetaclass.

    class classVarNames do:[:nm|

        resultSet add:(SmallSenseVariablePO classVariable: nm in: class).

    ].

    "Created: / 24-07-2013 / 17:00:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 30-07-2013 / 23:32:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addGlobalsStartingWith: prefix

    | class ns cls |

    class := collector klass.

    ns := class nameSpace.

    "nameSpace may return private class, sigh"

    [ ns isNameSpace ] whileFalse:[ ns := ns nameSpace ].

    ns keysDo:[:nm|

        (nm startsWith: prefix) ifTrue:[

            cls := ns classNamed: nm.

            cls notNil ifTrue:[

                cls isBehavior ifTrue:[

                    resultSet add:(SmallSenseClassPO new subject: cls; name: nm).

                ] ifFalse:[

                    resultSet add:(SmallSenseVariablePO globalVariable: cls).

                ]

            ]

        ].

    ].

    ns ~~ Smalltalk ifTrue:[

        Smalltalk keysDo:[:nm|

            (nm startsWith: prefix) ifTrue:[

                cls := Smalltalk classNamed: nm.

                cls notNil ifTrue:[

                    cls isBehavior ifTrue:[

                        resultSet add:(SmallSenseClassPO new subject: cls; name: nm ).

                    ] ifFalse:[

                        resultSet add:(SmallSenseVariablePO globalVariable: cls).

                    ]

                ]

            ]

        ].

    ]

    "Created: / 26-11-2011 / 17:29:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 24-07-2013 / 17:00:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addMethods: type

    type classesDo:[:each|

        | class |

        class := each.

        [ class isNil ] whileFalse:[

            class 

                selectorsAndMethodsDo:[:selector :met | 

                    resultSet add:(SmallSenseMethodPO 

                                name:selector

                                description:"met source"nil

                                class:class).

                ].

            class := class superclass.

        ].

    ].

    "Created: / 26-11-2011 / 17:03:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addMethodsStartingWith: prefix

    Smalltalk allClassesDo:[:class|

        class selectorsAndMethodsDo:[:selector :met | 

            (selector startsWith: prefix) ifTrue:[

                resultSet add:(SmallSenseMethodPO 

                            name:selector

                            description:"met source"nil

                            class:class).

            ]

        ].

    ].

    "Created: / 24-07-2013 / 13:10:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addPools

    | class |

    class := collector klass theNonMetaclass.

    class theNonMetaclass sharedPools do:[:pool|

        pool theNonMetaclass classVarNames do:[:nm|

            resultSet add:(SmallSenseVariablePO classVariable: nm in: pool).

        ]

    ].

    "Created: / 24-07-2013 / 16:59:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 30-07-2013 / 23:32:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addVariablesFor: node

    | n |

    "Add Instance variables"

    collector klass allInstVarNames do:[:nm|

        resultSet add: (SmallSenseVariablePO instanceVariable: nm in: collector klass).

    ].

    "Add pseudo variables"

    #(self super here thisContext) do:[:nm|

        resultSet add: (SmallSenseVariablePO new name: nm).

    ].

    "Add arguments"

    collector parser methodArgs ? #() do:[:nm|

        resultSet add: (SmallSenseVariablePO argument: nm).

    ].

    "Add temporaries"

    collector parser methodVars ? #() do:[:nm|

        resultSet add: (SmallSenseVariablePO variable: nm).

    ].

    n := node.

    [ n notNil ] whileTrue:[

        n isBlockNode ifTrue:[

            n arguments ? #() do:[:barg|resultSet add: (SmallSenseVariablePO variable: barg name)].

            n variables ? #() do:[:bvar|resultSet add: (SmallSenseVariablePO variable: bvar name)].

        ].

        n := n parent.

    ]

    "Created: / 31-07-2013 / 00:32:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!SmallSenseRecognizer methodsFor:'completion'!

completeAtLine:line column:col collector:coll 

    "find most possible codeCompletion object"

    | position |

    resultSet := SmallSenseResultSet new.

    collector := coll.

    (collector tree isNil or:[collector tree == #Error]) ifTrue:[ 

        ^ resultSet 

    ].

    position := SmallSenseFinder new 

                    findNodeIn: collector source tree: collector tree 

                    line: line column: col.

    resultSet position: position.

    (position afterNode) ifTrue:[

        self completeAfter:position node.

    ] ifFalse:[

    (position inNode) ifTrue:[

        self completeIn:position node.

    ] ifFalse:[

    (position beforeNode) ifTrue:[

        self completeBefore:position node.

    ]]].

    resultSet isEmpty ifTrue:[

        nil "/Only to set breakpoint here

    ].

    ^resultSet.

    "Created: / 04-03-2011 / 13:01:14 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 10:52:59 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 17:05:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 24-07-2013 / 16:00:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!SmallSenseRecognizer methodsFor:'completion-private'!

completeAfter:node

    "return collection of completion items after given node"

    self addMethods: node inferedType

    "Created: / 04-03-2011 / 15:45:28 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 10:55:09 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 17:07:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

completeBefore:node

    self breakPoint: #jv. "Not yet implemented"

    "Created: / 04-03-2011 / 15:45:28 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 10:55:09 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 17:07:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

completeIn:node

    "return collection which can be afterNode"

    node isVariableNode ifTrue:[

        node name first isUppercase ifTrue:[

            self addGlobalsStartingWith: node name.

            self addClassVariables.

            self addPools.

        ] ifFalse:[

            self addVariablesFor: node

        ].

        ^self.

    ].

    node isMessage ifTrue:[

        | type |

        type := node receiver inferedType.

        type isUnknownType ifFalse:[

            self addMethods:  type

        ] ifTrue:[

            self addMethodsStartingWith: node selector

        ].

        ^self.

    ].

    self breakPoint: #jv.

    "Created: / 07-03-2011 / 18:59:02 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 09:31:51 / Jakub <zelenja7@fel.cvut.cz>"

    "Created: / 26-11-2011 / 17:07:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-07-2013 / 00:32:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!SmallSenseRecognizer methodsFor:'obsolete'!

addSendsAndMethodFromAssignmentsFromRoelTyperResult:result 

    "we have roelTyperResult for exact node we add all sends and all methods which we can find in assignments"

    |retCollection class|

    retCollection := SmallSenseResultSet new.

    "

    (result interface) do:[:send|

        retCollection add: (SmallSenseMethod name:send description:'Used sender.'). 

    ].

    "

    result assignments do:[:assignment | 

         class := assignment.

        [ class isNil ] whileFalse:[

            class 

                selectorsAndMethodsDo:[:selector :met | 

                    retCollection add:(SmallSenseMethodPO 

                                name:selector

                                description:"met source"nil

                                class:class).

                ].

            class := class superclass.

        ].

    ].

    ^ retCollection.

    "Created: / 07-03-2011 / 18:20:15 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 10:15:20 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 08-04-2011 / 18:51:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

before

    "BasicCollection for allNode which are before "

    |retCollection|

    retCollection := SmallSenseResultSet new.

    retCollection join:(self beforeConstant).

    retCollection join:(self beforeBlock).

    ^ retCollection.

    "Created: / 04-03-2011 / 12:36:56 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 17-03-2011 / 18:32:38 / Jakub <zelenja7@fel.cvut.cz>"

!

before:foundNode collector:collector 

    "BasicCollection for allNode which are before node"

    |retCollection helper receiver node helperNode ret|

    "Check nil node"

    retCollection := SmallSenseResultSet new.

    (foundNode isNil) ifTrue:[

        retCollection join:(self beforeConstant).

        retCollection join:(self beforeBlock).

        retCollection join:(self beforeVariable:collector).

        ^ retCollection.

    ].

    (foundNode node isNil) ifTrue:[

        node := foundNode statement.

    ] ifFalse:[

        node := foundNode node.

    ].

    helperNode := foundNode node.

    (node isErrorNode) ifTrue:[

        helper := foundNode beforeStatement.

        (helper notNil) ifTrue:[

            foundNode node:helper.

            foundNode beforeNode:false.

            foundNode afterNode:true.

            ret := self after:foundNode collector:collector.

            foundNode node:helperNode.

            ^ ret.

        ]

    ].

    node isSelector ifTrue:[

        receiver := self getReceiverinNodeForSelector:node

                    node:foundNode statement.

        (receiver notNil) ifTrue:[

            (receiver isMessage 

                or:[

                    receiver isAssignment 

                        or:[ receiver isErrorNode or:[ receiver isSelector ] ]

                ]) 

                    ifFalse:[

                        foundNode node:receiver.

                        foundNode beforeNode:false.

                        foundNode afterNode:true.

                        ret := self after:foundNode collector:collector.

                        foundNode node:helperNode.

                        ^ ret.

                    ]

        ].

    ].

    retCollection join:(self beforeBlockVariable:foundNode).

    retCollection join:(self beforeConstant).

    retCollection join:(self beforeBlock).

    retCollection join:(self beforeVariable:collector).

    ^ retCollection.

    "Created: / 04-03-2011 / 13:02:42 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 06-04-2011 / 18:48:29 / Jakub <zelenja7@fel.cvut.cz>"

!

beforeBlock

    "There is some basic blocks which can be before node"

    |retCollection|

    retCollection := SmallSenseResultSet new.

    retCollection add:(SmallSenseSnippetPO name:'()ifTrue:[].'

                description:'True block

                     ()ifTrue:[].').

    retCollection add:(SmallSenseSnippetPO name:'()ifFalse:[].'

                description:'False block

                     ()ifFalse:[].').

    retCollection add:(SmallSenseSnippetPO name:'[]whileTrue:[].'

                description:'WhileTrue block

                     ()whileTrue:[].').

    retCollection add:(SmallSenseSnippetPO name:'[]whileFalse:[].'

                description:'WhileFalse block

                     ()whileFalse:[].').

    retCollection 

        add:(SmallSenseSnippetPO name:'[]' description:'Closure to block').

    retCollection add:(SmallSenseSnippetPO name:'()' description:'Brackets').

    ^ retCollection.

    "Created: / 04-03-2011 / 12:46:15 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 17-03-2011 / 17:31:25 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 04-04-2011 / 13:42:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

beforeBlockVariable:foundNode 

    "Add variables from Block Node"

    |retCollection|

    retCollection := SmallSenseResultSet new.

    (foundNode blockVariables notNil) ifTrue:[

        foundNode blockVariables do:[:each | 

            retCollection add:(SmallSenseVariablePO name:each name

                        description:'Variables in the method. Defined in block  [:val| ]').

        ].

    ].

    ^ retCollection

    "Created: / 06-04-2011 / 18:48:29 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 20-05-2011 / 14:36:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

beforeConstant

    "There is some basic constant which can be before node"

    |retCollection|

    retCollection := SmallSenseResultSet new.

    retCollection add:(SmallSenseConstantPO name:'^'

                description:'Return symbol from method.

For example: ^ nil').

    retCollection 

        add:(SmallSenseConstantPO name:':=' description:'Assignment to variable').

    retCollection add:(SmallSenseConstantPO name:'self'

                description:'Reference to self class. 

Access to method from this class. 

For example: self someMethod.').

    retCollection add:(SmallSenseConstantPO name:'super'

                description:'Reference to super class. 

Access to method from super class. 

For example: super someMethod.').

    retCollection add:(SmallSenseConstantPO name:'nil'

                description:'Nil. In c# or java null. Something empty').

    retCollection add:(SmallSenseConstantPO name:'true' description:'True.').

    retCollection add:(SmallSenseConstantPO name:'false' description:'False').

    retCollection add:(SmallSenseConstantPO name:'#'

                description:'Symbol reference. 

For example: #Symbol').

    retCollection add:(SmallSenseConstantPO name:'$'

                description:'Character symbol. 

For example #a').

    ^retCollection.

    "Created: / 04-03-2011 / 12:40:45 / Jakub <zelenja7@fel.cvut.cz>"

    "Modified: / 04-04-2011 / 13:44:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 07-04-2011 / 23:01:55 / Jakub <zelenja7@fel.cvut.cz>"

!

beforeVariable:collector 

    "There is some variables which can be before node"

    |retCollection roelTyper helper class|

    retCollection := SmallSenseResultSet new.

    (collector isNil) ifTrue:[

        ^ retCollection.

    ].

    (collector methodArgs notNil) ifTrue:[

        collector methodArgs do:[:each | 

            retCollection add:(SmallSenseVariablePO name:each

                        description:'Arguments in the method. Defined in method:val').

        ].

    ].

    roelTyper := self doForSource:collector.

    roelTyper instVars do:[:var | 

        retCollection add:(SmallSenseVariablePO name:var

                    description:'Instance variables. Variables defined in instanceVariableNames')

    ].