"{ Package: 'jn:refactoring_custom' }"

CustomTestCaseCodeGenerator subclass:#CustomCodeGeneratorOrRefactoringTestCaseCodeGenerator

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Refactoring-Custom'

!

!CustomCodeGeneratorOrRefactoringTestCaseCodeGenerator class methodsFor:'accessing-presentation'!

description

    ^ 'Generate CodeGeneratorOrRefactoringTestCase subclass for selected classes (code generators/refactorings)'

    "Modified: / 23-08-2014 / 19:50:52 / Jakub Nesveda <nesvejak@fit.cvut.cz>"

!

group

    "Returns a collection strings describing a group to which

     receiver belongs. A groups may be nested hence the array of

     strings. For example for subgroup 'Accessors' in group 'Generators'

     this method should return #('Generators' 'Accessors')."

    "/ By default return an empty array which means the item will appear

    "/ in top-level group.

    ^ #('Generators')

    "Created: / 22-08-2014 / 18:50:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

label

    ^ 'New Code Generator Testcase'

    "Modified: / 23-08-2014 / 19:50:58 / Jakub Nesveda <nesvejak@fit.cvut.cz>"

    "Modified: / 22-08-2014 / 18:50:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CustomCodeGeneratorOrRefactoringTestCaseCodeGenerator methodsFor:'executing'!

buildForClass: aClass testClass: aTestClass

    | source className |

    aTestClass superclassName: 'CustomCodeGeneratorOrRefactoringTestCase'.

    className := aClass theNonMetaClass name.

    source := 'test_code_generated

    | expectedSource |

    expectedSource := ''instanceVariable

    ^ instanceVariable''.

    self executeGeneratorInContext: #classWithInstanceVariable.

    self assertMethodSource: expectedSource atSelector: #instanceVariable'.

    codeBuilder

        class: aTestClass;

        protocol: 'tests';

        source: source;

        createMethod;

        protocol: 'accessing';

        source: 'generatorOrRefactoring

    ^ `className new';

        replace: '`className' with: className asString;

        createMethod

    "Created: / 13-06-2014 / 09:27:15 / Jakub Nesveda <nesvejak@fit.cvut.cz>"

    "Modified: / 23-08-2014 / 19:56:09 / Jakub Nesveda <nesvejak@fit.cvut.cz>"

! !

!CustomCodeGeneratorOrRefactoringTestCaseCodeGenerator class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !