"{ Package: 'stx:goodies/xtreams/core' }"

"{ NameSpace: Xtreams }"

Error subclass:#Incomplete

	instanceVariableNames:'collection count start'

	classVariableNames:''

	poolDictionaries:''

	category:'Xtreams-Core'

!

Incomplete comment:'This error is raised when a read or write fails to complete. The parameters report the details about successfully written or read elements.

Instance Variables

	collection      <Collection | nil> when possible points at the collection with the successfully processed elements

	count   <Integer> number of successfully processed elements

	start   <Integer> if collection is set, this is the index where the successfully processed elements start

'

!

!Incomplete class methodsFor:'instance creation'!

count: anInteger

	^self new on: nil count: anInteger at: nil

!

on: collection count: count at: start

	^self new on: collection count: count at: start

!

zero

	^self count: 0

! !

!Incomplete methodsFor:'accessing'!

collection

	^collection

!

collection: anObject

	collection := anObject

!

contents

	^collection

		ifNil: [ self originator contentsSpecies withSize: count ]

		ifNotNil: [ collection copyFrom: start to: start + count - 1 ]

!

count

	^count

!

count: anObject

	count := anObject

!

start

	^start

!

start: anObject

	start := anObject

! !

!Incomplete methodsFor:'initialize-release'!

on: aCollection count: aCount at: aStart

	collection := aCollection.

	count := aCount.

	start := aStart

! !

!Incomplete methodsFor:'private'!

streamingInsert: anInteger into: aWriteStream

	| amount |

	collection ifNil: [(self class on: collection count: 0 at: start) raise].

	amount := anInteger min: count.

	aWriteStream insert: amount from: collection at: start.

	amount < anInteger ifTrue: [(self class on: collection count: amount at: start) raise].

!

streamingInsertInto: aWriteStream

	collection ifNil: [^0].

	aWriteStream insert: count from: collection at: start.

	^count

!

streamingWrite: anInteger into: aWriteStream

	| amount |

	collection ifNil: [(self class on: collection count: 0 at: start) raise].

	amount := anInteger min: count.

	aWriteStream write: amount from: collection at: start.

	amount < anInteger ifTrue: [(self class on: collection count: amount at: start) raise].

	^anInteger

!

streamingWriteInto: aWriteStream

	collection ifNil: [^0].

	aWriteStream write: count from: collection at: start.

	^count

! !

!Incomplete class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !