"{ Package: 'stx:goodies/xtreams/substreams' }"

"{ NameSpace: Xtreams }"

PositionWriteSubstream subclass:#LimitWriteSubstream

	instanceVariableNames:'limit'

	classVariableNames:''

	poolDictionaries:''

	category:'Xtreams-Substreams'

!

LimitWriteSubstream comment:'Limits the number of elements that can be written into the destination stream.

Instance Variables

	limit	<Integer> maximum number of elements that can be written into this stream

	position	<Integer> number of elements already written into the stream

'

!

!LimitWriteSubstream class methodsFor:'instance creation'!

on: aDestination limit: anInteger

	^self new on: aDestination limit: anInteger

! !

!LimitWriteSubstream methodsFor:'accessing'!

insert: anInteger from: aSequenceableCollection at: startIndex

	| count |

	count := anInteger min: self available.

	super insert: count from: aSequenceableCollection at: startIndex.

	count < anInteger ifTrue: [(Incomplete on: aSequenceableCollection count: count at: startIndex) raise].

	^anInteger

!

put: anObject

	position = limit ifTrue: [Incomplete zero raise].

	^super put: anObject

!

write: anInteger from: aSequenceableCollection at: startIndex

	| count |

	count := anInteger min: self available.

	super write: count from: aSequenceableCollection at: startIndex.

	count < anInteger ifTrue: [(Incomplete on: aSequenceableCollection count: count at: startIndex) raise].

	^anInteger

! !

!LimitWriteSubstream methodsFor:'initialize-release'!

on: aDestination limit: anInteger

	self on: aDestination.

	limit := anInteger

!

subseekend

	self isPositionable ifFalse: [^self].

	self -= 0

! !

!LimitWriteSubstream methodsFor:'seeking'!

-= anInteger

	| available |

	anInteger < 0 ifTrue: [Incomplete zero raise].

	available := anInteger min: limit.

	destination ++ (limit - position - available).

	position := limit - available.

	available = anInteger ifTrue: [^anInteger].

	^(Incomplete count: available) raise

!

length

	^limit

! !

!LimitWriteSubstream class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !