"{ Package: 'stx:goodies/xtreams/substreams' }"

"{ NameSpace: Xtreams }"

ReadSubstream subclass:#TestReadSubstream

	instanceVariableNames:'substreamAtEnd test inclusive'

	classVariableNames:''

	poolDictionaries:''

	category:'Xtreams-Substreams'

!

TestReadSubstream comment:'This is a substream bounded by an element matching the @test criteria.

Instance Variables

	substreamAtEnd	<Boolean> is this substream at end

	test	<BlockClosure> the bounding criteria

	inclusive	<Boolean> is the boundary part of the substream contents

'

!

!TestReadSubstream class methodsFor:'instance creation'!

on: aSource test: testBlock inclusive: aBoolean

	^self new on: aSource test: testBlock inclusive: aBoolean

! !

!TestReadSubstream methodsFor:'accessing'!

get

	| object |

	substreamAtEnd ifTrue: [Incomplete zero raise].

	object := [source get] on: Incomplete do: [:incomplete | sourceAtEnd := substreamAtEnd := true. incomplete pass].

	(substreamAtEnd := test value: object) ifTrue:

		[inclusive ifTrue: [^object].

		Incomplete zero raise].

	^object

!

read: anInteger into: aSequenceableCollection at: startIndex

	| object count |

	substreamAtEnd ifTrue: [(Incomplete on: aSequenceableCollection count: 0 at: startIndex) raise].

	count := 0.

	[[count = anInteger or: [substreamAtEnd]] whileFalse:

		[object := source get.

		((substreamAtEnd := test value: object) not or: [inclusive]) ifTrue:

			[aSequenceableCollection at: startIndex + count put: object.

			count := count + 1]]]

				on: Incomplete do: [sourceAtEnd := substreamAtEnd := true. (Incomplete on: aSequenceableCollection count: count at: startIndex) raise].

	count < anInteger ifTrue: [(Incomplete on: aSequenceableCollection count: count at: startIndex) raise].

	^anInteger

! !

!TestReadSubstream methodsFor:'initialize-release'!

on: aSource test: testBlock inclusive: aBoolean

	self on: aSource.

	test := testBlock.

	inclusive := aBoolean.

	substreamAtEnd := false

!

subseekend

	| object |

	substreamAtEnd ifTrue: [^self].

	[[substreamAtEnd] whileFalse:

		[object := source get.

		substreamAtEnd := test value: object]]

			on: Incomplete do: [sourceAtEnd := substreamAtEnd := true]

! !

!TestReadSubstream methodsFor:'private'!

streamingWrite: anInteger into: aWriteStream

	| object count |

	substreamAtEnd ifTrue: [Incomplete zero raise].

	count := 0.

	[[count = anInteger or: [substreamAtEnd]] whileFalse:

		[object := source get.

		((substreamAtEnd := test value: object) not or: [inclusive]) ifTrue:

			[aWriteStream put: object.

			count := count + 1]]]

				on: Incomplete do: [sourceAtEnd := substreamAtEnd := true. (Incomplete count: count) raise].

	count < anInteger ifTrue: [(Incomplete count: count) raise].

	^anInteger

!

streamingWriteInto: aWriteStream

	| object count |

	substreamAtEnd ifTrue: [^0].

	count := 0.

	^[	[	substreamAtEnd

		] whileFalse: [

			object := source get.

			(substreamAtEnd := test value: object)

				ifTrue:	[inclusive ifTrue: [aWriteStream put: object. count := count + 1]]

				ifFalse:	[aWriteStream put: object. count := count + 1]].

		count

	] on: Incomplete do: [sourceAtEnd := substreamAtEnd := true. count ]

! !

!TestReadSubstream methodsFor:'seeking'!

-= anInteger

	^anInteger isZero

		ifTrue:	[self subseekend. 0]

		ifFalse:	[super -= anInteger]

! !

!TestReadSubstream methodsFor:'testing'!

isPositionable

	^false

! !

!TestReadSubstream class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !