"{ Package: 'stx:goodies/xtreams/substreams' }"

"{ NameSpace: Xtreams }"

ReadSubstream subclass:#PositionReadSubstream

	instanceVariableNames:'position'

	classVariableNames:''

	poolDictionaries:''

	category:'Xtreams-Substreams'

!

PositionReadSubstream comment:'This is an abstract substreams that keeps track of its own position and allows positioning if the underlying stream is positionable.

Instance Variables

	position        <Integer> current position within the substream

'

!

!PositionReadSubstream methodsFor:'accessing'!

get

	| object |

	object := super get.

	position := position + 1.

	^object

!

read: anInteger into: aSequenceableCollection at: startIndex

	[source read: anInteger into: aSequenceableCollection at: startIndex] on: Incomplete do: [:incomplete |

		sourceAtEnd := true.

		position := position + incomplete count.

		incomplete pass].

	position := position + anInteger.

	^anInteger

! !

!PositionReadSubstream methodsFor:'initialize-release'!

on: aSource

	super on: aSource.

	position := 0

! !

!PositionReadSubstream methodsFor:'seeking'!

++ anInteger

	| count |

	anInteger < 0 ifTrue: [ ^self -- anInteger negated ].

	count := self available min: anInteger.

	count := [source ++ count. count] on: Incomplete do: [ :ex | ex count ].

	position := position + count.

	count < anInteger ifTrue: [sourceAtEnd := true. (Incomplete count: count) raise].

	^anInteger

!

-- anInteger

	| count |

	anInteger < 0 ifTrue: [ ^self ++ anInteger negated ].

	count := anInteger min: position.

	count := [source -- count. count] on: Incomplete do: [ :ex | ex count ].

	position := position - count.

	count < anInteger ifTrue: [(Incomplete count: count) raise].

	anInteger isZero ifFalse: [sourceAtEnd := false].

	^anInteger

!

-= anInteger

	position := self length - anInteger max: 0.

	^source -= anInteger

!

length

	^source available + position

!

position

	^position

!

position: anInteger

	| delta available |

	self isPositionable ifFalse: [self error: 'This stream is not positionable.'].

	anInteger < 0 ifTrue: [Incomplete zero raise].

	available := anInteger min: self length.

	delta := available - position.

	[delta positive

		ifTrue: [source ++ delta]

		ifFalse:        [source -- delta negated]]

			on: Incomplete do: [sourceAtEnd := true].

	position := available.

	available = anInteger ifTrue: [^anInteger].

	(Incomplete count: available) raise

! !

!PositionReadSubstream methodsFor:'testing'!

isPositionable

	^source isPositionable

! !

!PositionReadSubstream class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !