"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Dictionary subclass:#IdentityDictionary

	 instanceVariableNames:''

	 classVariableNames:''

	 poolDictionaries:''

	 category:'Collections-Unordered'

!

!IdentityDictionary class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    same as a Dictionary but key must be identical - not just equal.

    Since compare is on identical keys (using ==), hashing is also done via

    #identityHash instead of #hash.

    IdentityDictionaries are especially useful, when symbols are used as keys.

"

! !

!IdentityDictionary methodsFor:'private'!

compareSame:element1 with:element2

    ^ element1 == element2

!

emptyCollectionForKeys

    "return an empty collection used for keys.

     Made a separate method to allow redefinition for different kind of

     containers in subclasses"

    ^ IdentitySet new:(self size)

!

find:key ifAbsent:aBlock

    "Look for the key in the receiver.  If it is found, return

     the index of the association containing the key, otherwise

     return the value of evaluating aBlock."

    |index  "{ Class:SmallInteger }"

     length "{ Class:SmallInteger }"

     startIndex

     probe|

    length := keyArray basicSize.

"/

"/    length < 10 ifTrue:[

"/	"assuming, that for small dictionaries the overhead of hashing

"/	 is large ... maybe that proves wrong (if overhead of comparing

"/	 is high)"

"/	^ keyArray identityIndexOf:key ifAbsent:aBlock.

"/    ].

"/

    index := key identityHash.

    index := index \\ length + 1.

    startIndex := index.

    [true] whileTrue:[

	probe := keyArray basicAt:index.

	probe == key ifTrue:[^ index].

	index == length ifTrue:[

	    index := 1

	] ifFalse:[

	    index := index + 1

	].

	(probe isNil or:[index == startIndex]) ifTrue:[^ aBlock value]

    ]

!

findKeyOrNil:key

    "Look for the key in the receiver.  

     If it is found, return return the index of the first unused slot. 

     Grow the receiver, if key was not found, and no unused slots were present"

    |index  "{ Class:SmallInteger }"

     length "{ Class:SmallInteger }"

     startIndex probe 

     delIndex "{ Class:SmallInteger }" |

    delIndex := 0.

    length := keyArray basicSize.

    index := key identityHash.

    index := index \\ length + 1.

    startIndex := index.

    [true] whileTrue:[

	probe := keyArray basicAt:index.

	key == probe ifTrue:[^ index].

	probe isNil ifTrue:[

	    delIndex == 0 ifTrue:[^ index].

	    keyArray basicAt:delIndex put:nil.

	    ^ delIndex

	].

	probe == DeletedEntry ifTrue:[

	    delIndex == 0 ifTrue:[

		delIndex := index

	    ]

	].

	index == length ifTrue:[

	    index := 1

	] ifFalse:[

	    index := index + 1

	].

	index == startIndex ifTrue:[

	    delIndex ~~ 0 ifTrue:[

		keyArray basicAt:delIndex put:nil.

		^ delIndex

	    ].

	    ^ self grow findKeyOrNil:key

	].

    ]

    "Modified: 26.3.1996 / 20:00:44 / cg"

!

findNil:key

    "Look for the next slot usable for key.  This method assumes that

     key is not already in the receiver - used only while growing/rehashing"

    |index  "{ Class:SmallInteger }"

     length "{ Class:SmallInteger }"|

    length := keyArray basicSize.

    index := key identityHash.

    index := index \\ length + 1.

    [(keyArray basicAt:index) notNil] whileTrue:[

	index == length ifTrue:[

	    index := 1

	] ifFalse:[

	    index := index + 1

	].

	"notice: no check for no nil found - we must find one since

	 this is only called after growing"

    ].

    ^ index

! !

!IdentityDictionary methodsFor:'testing'!

includesValue:aValue

    "return true, if the argument, aValue is stored in the dictionary,

     Redefined to use identity compare, NOT equality compare"

    ^ (valueArray identityIndexOf:aValue) ~~ 0

!

occurrencesOf:anObject

    "count & return how often anObject is stored in the dictionary.

     This counts values - not keys.

     Redefined to use identity compare, NOT equality compare."

    |cnt|

    cnt := 0.

    valueArray do:[:element |

       element == anObject ifTrue:[cnt := cnt + 1]

    ].

    ^ cnt

! !

!IdentityDictionary class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libbasic/Attic/IdDict.st,v 1.19 1996-03-26 20:45:04 cg Exp $'

! !