"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

CompiledCode variableSubclass:#Method

	instanceVariableNames:'source sourcePosition category package mclass'

	classVariableNames:'PrivateMethodSignal LastFileReference LastSourceFileName

		LastWhoClass LastFileLock LastMethodSources LastMethodSourcesLock

		CompilationLock'

	poolDictionaries:''

	category:'Kernel-Methods'

!

Object subclass:#MethodWhoInfo

	instanceVariableNames:'myClass mySelector'

	classVariableNames:''

	poolDictionaries:''

	privateIn:Method

!

!Method class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class defines protocol for executable methods;

    both compiled and interpreted methods are represented by this class.

    Compiled methods have a non-nil code field, while interpreted methods have

    a nil code field and non-nil byteCode field.

    If there are both non-nil code and bytecode fields, the VM will execute

    the machine-code of a method. If both are nil when executed, a noByteCode

    message is sent by the VM to the method where a signal is raised.

    The methods sourcecode is represented by source and sourcePosition:

    - if sourcePosition is a Number, the source-field is the fileName and

      sourcePosition is the character offset of the source-chunk in this source file.

    - If sourcePosition is nil, the source is the string in the source field.

    (an old version used ExternalString instances here, but that lead to

     10000 additional little objects ...)

    The flags field defines things like the number of method-locals,

    method arguments and stack requirements (for interpreted methods).

    Do not depend on any value in the flags field - it may change without

    notice.

    Notice, that in ST/X, method can be subclassed; executable code is

    identified not by being an instance of Block or Method, but instead by

    having the executable flag bit set in the class. The VM can execute anything

    which is identified as executable (assuming that the first instance variable

    is the machine-code address) - this allows for easy future extension.

    [Instance variables:]

        source          <String>        the source itself (if sourcePosition isNil)

                                        or the fileName where the source is found

        sourcePosition  <Integer>       the position of the methods chunk in the file

        category        <Symbol>        the methods category

        package         <Symbol>        the package, in which the methods was defined

        mclass          <Class>         the class in which I am defined

        indexed slots                   literals

    [Class variables:]

        PrivateMethodSignal             raised on privacy violation (see docu)

        LastFileReference               weak reference to the last sourceFile

        LastSourceFileName              to speedup source access via NFS

    WARNING: layout known by compiler and runtime system - dont change

    [author:]

        Claus Gittinger

"

!

dynamicMethods

"

    On systems which support dynamic loading of stc-compiled machine code (SYS5.4, Linux),

    methods may now be compiled to machine code from within the browser,

    and the resulting machine code object be loaded in.

    The ObjectFileLoader keeps (weak) handles to the resulting methods and

    invalidates the corresponding method objects, if the underlying methods

    object code is unloaded.

    Invalid methods will trap into the debugger when executed;

    also, the browser marks them as '(* not executable *)' in its method list.

    Notice: this has nothing to do with JIT compilation, which is always possible.

    JIT-compilation is done from bytecodes to a machineCode cache.

    In contrast, dynamic loading of stc-compiled code goes via intermediate C-code

    which is compiled by the machines native C-compiler.

    As opposed to JITted code, this allows for embedded primitive C-code.

"

!

privacy

"

    ST/X includes an EXPERIMENTAL implementation of method privacy.

    Individual methods may be set to private or protected via the

    privacy:#private and privacy:#protected messages. Also, categories may be

    filedIn as a whole as private using #privateMethodsFor: or as

    protected using #protectedMethodsFor: instead of the well known #methodsFor:.

    The additional #publicMethodsFor: is for documentation purposes, and

    is equivalent to #methodsFor: (also to support fileIn of ENVY methods).

    Protected methods may be executed only when called via a self-send

    from the superclass-methods and self or super-sends from methods in the

    class itself or subclasses.

    Private methods may not be called from subclasses-methods,

    i.e. they may only be called via self sends from within the current class.

    (i.e. protected methods are less private than private ones)

    When such a situation arises, the VM (runtime system) will raise the

    PrivateMethodSignal exception (if nonNil), which usually brings you into the

    debugger.

    If PrivateMethodSignal is nil, the VM will not check for this, and

    execution is as usual. (you may want to nil-it for production code,

    and leave it non nil during development).

    NOTICE: there is no (not yet ?) standard defined for method privacy,

    however, the definition protocol was designed to be somewhat ENVY compatible

    (from what can be deduced by reading PD code).

    Also, the usability of privacy is still to be tested.

    This interface, the implementation and the rules for when a privacy violation

    may change (in case of some ANSI standard being defined).

    Be warned and send me suggestions & critics (constructive ;-)

    Late note (Feb 2000):

        the privacy feature has new been in ST/X for some years and was NOT heavily

        used - neither at eXept, nor by customers.

        In Smalltalk, it seems to be a very questionable feature, actually limiting

        code reusability.

        The privacy features are left in the system to demonstrate that it can be

        done in Smalltalk (for religious C++ fans ... to avoid useless discussions)

        (the check is not expensive, w.r.t. the VM runtime behavior).

"

! !

!Method class methodsFor:'initialization'!

initialize

    "create signals"

    PrivateMethodSignal isNil ifTrue:[

        "EXPERIMENTAL"

        PrivateMethodSignal := ExecutionError newSignalMayProceed:true.

        PrivateMethodSignal nameClass:self message:#privateMethodSignal.

        PrivateMethodSignal notifierString:'attempt to execute private/protected method'.

    ].

    LastFileLock isNil ifTrue:[

        LastFileLock := RecursionLock new name:'Method-LastFile'.

        LastMethodSourcesLock := RecursionLock new name:'Method-LastMethodSources'.

        "LastFileReference used to be a WeakArray. The problem was, that

         during some operations (generating project definition methods), lots of

         methods and classes are accessed. GC (scavenge) is done heavily,

         while finalization is a low prio process, so that the file limit

         is reached before finalization did close the old streams."

        LastFileReference := Array new:1.

        LastFileReference at:1 put:nil.

    ].

    CompilationLock := RecursionLock new name:'MethodCompilation'.

    "Modified: 22.4.1996 / 16:34:38 / cg"

    "Modified: 3.1.1997 / 16:58:16 / stefan"

!

lastMethodSourcesLock

    LastMethodSourcesLock isNil ifTrue:[

        self initialize

    ].

    ^ LastMethodSourcesLock

! !

!Method class methodsFor:'Signal constants'!

privateMethodSignal

    "return the signal raised when a private/protected method is called

     by some other object (i.e. not a self- or super send)"

    ^ PrivateMethodSignal

! !

!Method class methodsFor:'queries'!

isBuiltInClass

    "return true if this class is known by the run-time-system.

     Here, true is returned for myself, false for subclasses."

    ^ self == Method

    "Modified: 23.4.1996 / 15:59:50 / cg"

!

methodDefinitionTemplateForSelector:aSelector

    "given a selector, return a prototype definition string"

    |nA argNames|

    (nA := aSelector numArgs) == 1 ifTrue:[

        argNames := #('arg')

    ] ifFalse:[

        argNames := (1 to:nA) collect:[:i | 'arg' , i printString].

    ].

    ^ self

        methodDefinitionTemplateForSelector:aSelector

        andArgumentNames:argNames.

    "

     Method methodDefinitionTemplateForSelector:#foo

     Method methodDefinitionTemplateForSelector:#+

     Method methodDefinitionTemplateForSelector:#foo:bar:baz:

    "

!

methodDefinitionTemplateForSelector:aSelector andArgumentNames:argNames

    "given a selector, return a prototype definition string"

    aSelector numArgs > 0 ifTrue:[

        aSelector isKeyword ifTrue:[

            ^ String streamContents:[:stream |

                aSelector keywords with:argNames do:[:eachKeyword :eachArgName|

                    stream nextPutAll:eachKeyword; nextPutAll:eachArgName; space.

                ].

                stream backStep.   "remove the last space"

             ].

        ].

        ^ aSelector , ' ' , (argNames at:1)

    ].

    ^ aSelector

    "

     Method methodDefinitionTemplateForSelector:#foo          andArgumentNames:#()

     Method methodDefinitionTemplateForSelector:#+            andArgumentNames:#('aNumber')

     Method methodDefinitionTemplateForSelector:#foo:bar:baz: andArgumentNames:#('fooArg' 'barArg' 'bazArg')

    "

!

methodPrivacySupported

    "return true, if the system was compiled to support methodPrivacy.

     You should not depend on that feature being available."

%{  /* NOCONTEXT */

#if defined(F_PRIVATE) || defined(F_CLASSPRIVATE)

    RETURN (true);

#else

    RETURN (false);

#endif

%}

!

resourceTypes

    "get the types of resources for which a spec definition and corresponding editor exist"

    ^ #(canvas menu image fileImage help hierarchicalList tabList tableColumns)

! !

!Method class methodsFor:'special'!

flushSourceStreamCache

    LastFileLock critical:[

        LastSourceFileName := LastMethodSources := nil.

        LastFileReference at:1 put:0.

    ].

    "

     Method flushSourceStreamCache

    "

    "Created: 9.2.1996 / 19:05:28 / cg"

! !

!Method methodsFor:'Compatibility-VW'!

classIsMeta

    "return true, if this method is a class method"

    ^ self mclass isMeta

!

sendsSelector:aSelectorSymbol

    "return true, if this method contains a message-send

     with aSelectorSymbol as selector."

    ^ self sends:aSelectorSymbol

! !

!Method methodsFor:'accessing'!

category

    "return the methods category or nil"

    ^ category

!

category:aStringOrSymbol

    "set the methods category"

    |newCategory oldCategory cls|

    aStringOrSymbol notNil ifTrue:[

        newCategory := aStringOrSymbol.

        newCategory ~= (oldCategory := category) ifTrue:[

            self setCategory:newCategory.

            cls := self mclass.

            cls notNil ifTrue:[

                cls addChangeRecordForMethodCategory:self category:newCategory.

                self changed:#category with:oldCategory.            "/ will vanish

                cls changed:#organization with:self selector.       "/ will vanish

                Smalltalk changed:#methodCategory with:(Array with:cls with:self with:oldCategory).

            ]

        ]

    ]

    "Modified: / 25-09-2007 / 16:15:24 / cg"

!

comment

    "return the methods comment.

     This is done by searching for and returning the first comment

     from the methods source (excluding any double-quotes).

     Returns nil if there is no comment (or source is not available)."

    |src|

    src := self source.

    src isNil ifTrue:[^ nil].

    ^ self programmingLanguage parserClass methodCommentFromSource:src

    "

     (Method compiledMethodAt:#comment) comment  

     (Object class compiledMethodAt:#infoPrinting:) comment

    "

    "Modified: / 23-02-1998 / 10:26:08 / stefan"

    "Modified: / 17-07-2010 / 14:23:56 / cg"

!

getPackage

    "return the package-ID of the method"

    ^ package

!

getSource

    "low-level access to the source instance-variable.

     For internal (compiler) use only.

     This is NOT always the methods source string"

    ^ source

!

getSourcePosition

    "low-level access to the sourcePosition instance-variable.

     For internal (compiler) use only.

     This is NOT always the methods sourcePosition"

    ^ sourcePosition

!

localSourceFilename:aFileName position:aNumber

    "set the methods sourcefile/position indicating, that

     this is a local file."

    source := aFileName.

    sourcePosition := aNumber negated

    "Created: 16.1.1997 / 01:25:52 / cg"

!

makeLocalStringSource

    "assure that the methods source code is stored locally as a string

     within the method (as opposed to an external string, which is accessed

     by reading the source code file).

     This is required, when a methods package is changed, to assure that its

     sourceCode is not lost."

    source notNil ifTrue:[

        sourcePosition notNil ifTrue:[

            "/ this looks wierd - but (self source) will retrieve the external source

            "/ (from the file) and store it. So afterwards, we will have the string and

            "/ sourcePosition will be nil

            self source:(self source)

        ]

    ].

!

mclass:aClass

    "set the method's class"

    mclass == aClass ifTrue:[ ^ self ].

"/     (mclass notNil and:[aClass notNil]) ifTrue:[

"/         'Method [warning]: mclass already set' errorPrintCR.

"/     ].

    mclass := aClass.

    "Modified: / 28-11-2006 / 12:12:27 / cg"

!

package

    "return the package-ID of the method (nil is translated to noProject here)"

    |cls|

    package notNil ifTrue:[ ^ package ].

    (cls := self mclass) isNil ifTrue:[

        ^ PackageId noProjectID.

    ].

    "/ set it.

    package := cls getPackage.

    package isNil ifTrue:[

        ^ PackageId noProjectID.

    ].

    ^ package

    "Modified: / 28-11-2006 / 12:12:43 / cg"

!

package:aSymbol

    "set the package-symbol"

    |cls oldPackage newPackage|

    aSymbol == PackageId noProjectID ifTrue:[

        newPackage := nil

    ] ifFalse:[

        newPackage := aSymbol

    ].

    package ~~ newPackage ifTrue:[

        oldPackage := package.

        "/ this is required, because otherwise I would no longer be able to

        "/ reconstruct my sourcecode (as the connection to the source-file is lost).

        self makeLocalStringSource.

        package := newPackage.

        cls := self mclass.

        self changed:#package.                                              "/ will vanish

        cls changed:#methodPackage with:self selector.                      "/ will vanish

        Smalltalk changed:#projectOrganization with:(Array with:cls with:self with:oldPackage).

        cls addChangeRecordForMethodPackage:self package:newPackage.

    ]

    "Modified: / 23-11-2006 / 17:01:02 / cg"

!

setCategory:aStringOrSymbol

    "set the methods category (without change notification)"