"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ExternalStream subclass:#FileStream

	instanceVariableNames:'pathName canPosition removeOnClose'

	classVariableNames:'OpenErrorSignal'

	poolDictionaries:''

	category:'Streams-External'

!

!FileStream primitiveDefinitions!

%{

#ifdef __openVMS__

# undef __new

#endif

#include <stdio.h>

#define _STDIO_H_INCLUDED_

#include <errno.h>

#define _ERRNO_H_INCLUDED_

#ifdef transputer

# include <iocntrl.h>

# ifndef fileno

   /* kludge: inmos forgot fileno */

#  define fileno(f)     ((f)->__file)

# endif

#else

# include <sys/types.h>

# include <sys/stat.h>

#endif

#ifdef hpux

# define fileno(f)      ((f->__fileH << 8) | (f->__fileL))

#endif

#ifndef SEEK_SET

# define SEEK_SET       0

#endif

#ifndef SEEK_CUR

# define SEEK_CUR       1

#endif

#ifndef SEEK_END

# define SEEK_END       2

#endif

/*

 * not all systems have off_t

 * explicit add of those we know to have ...

 */

#ifdef __osf__

# define OFF_T  off_t

#endif

#ifndef OFF_T

# define OFF_T  long

#endif

#ifdef __VMS__

/*

 * get those VMS definitions ...

 */

# include <rms.h>

#endif

#ifdef WIN32

# if 1

#  define NO_STDIO

# else

#  undef __BEGIN_INTERRUPTABLE__

#  undef __END_INTERRUPTABLE__

#  define __BEGIN_INTERRUPTABLE__

#  define __END_INTERRUPTABLE__

# endif

# ifdef i386

#  define _X86_

# endif

# undef INT

# undef Array

# undef Number

# undef Method

# undef Point

# undef Rectangle

# undef Block

# define NOATOM

# define NOGDICAPMASKS

# define NOMETAFILE

# define NOMINMAX

//# define NOOPENFILE

# define NOSOUND

# define NOWH

//# define NOCOMM

# define NOKANJI

# define NOCRYPT

//# define NOMCX

# define WIN32_LEAN_AND_MEAN

# include <windows.h>

# include <winsock.h> /* */

# if !defined(__BORLANDC__)

#  define stat _stat

# endif

# ifdef __DEF_Array

#   define Array __DEF_Array

# endif

# ifdef __DEF_Number

#   define Number __DEF_Number

# endif

# ifdef __DEF_Method

#   define Method __DEF_Method

# endif

# ifdef __DEF_Point

#   define Point __DEF_Point

# endif

# ifdef __DEF_Block

#   define Block __DEF_Block

# endif

# define INT int

#endif /* WIN32 */

#ifdef NO_STDIO

/*# define HFILE HANDLE*/

# define HFILE FILE *

//# define fileno(f) f

# define TELL(currentPosition,f,buffered)                               \

    if (buffered) {                                             \

	currentPosition = ftell(f);                             \

    } else {                                                    \

      OBJ rA = __INST(readAhead);                                       \

      if (rA != nil) {                                                  \

	  __INST(readAhead) = nil;                                      \

	currentPosition = lseek(fileno(f), -1L, SEEK_CUR);                      \

      }                                                                 \

      else \

	currentPosition = lseek(fileno(f), 0L, SEEK_CUR);                       \

    }

# define SEEK(ret,f,nP,buffered)                                        \

	  if (buffered) {                                     \

	      ret = fseek(f, nP, SEEK_SET);                   \

	  } else {                                            \

	    OBJ rA = __INST(readAhead);                                 \

	    if (rA != nil) {                                            \

		__INST(readAhead) = nil;                                \

	    }                                                           \

	    ret = lseek(fileno(f), nP, SEEK_SET);                       \

	  }

# define TOEND(ret,f,buffered) \

	  if (buffered) {                                             \

	      ret = fseek(f, 0L, SEEK_END);                           \

	  } else {                                                    \

	    OBJ rA = __INST(readAhead);                                 \

	    if (rA != nil) {                                            \

		__INST(readAhead) = nil;                                \

	    }                                                           \

	    ret = lseek(fileno(f), 0L, SEEK_END);                       \

	  }

#else

# define HFILE FILE *

# define TELL(currentPosition,f,buffered) \

	    if (buffered) {                                             \

		currentPosition = ftell(f);                             \

	    } else {                                                    \

		currentPosition = lseek(fileno(f), 0L, SEEK_CUR);       \

	    }

# define SEEK(ret,f,nP,buffered)                                        \

		    if (buffered) {                                     \

			ret = fseek(f, nP, SEEK_SET);                   \

		    } else {                                            \

			ret = lseek(fileno(f), nP, SEEK_SET);           \

		    }

# define TOEND(ret,f,buffered) \

	    if (buffered) {                                             \

		ret = fseek(f, 0L, SEEK_END);                           \

	    } else {                                                    \

		ret = lseek(fileno(f), 0L, SEEK_END);                   \

	    }

 extern long ftell(), lseek();

#endif

/*

 * on some systems errno is a macro ... check for it here

 */

#ifndef errno

 extern errno;

#endif

%}

! !

!FileStream class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class provides access to the operating systems underlying file

    system (i.e. its an interface to the stdio library).

    Notice, that on some systems, the standard I/O library has performance

    problems when a file is opened for readwrite. 

    For best results, open files either readonly or writeonly.

    Also notice, that some OperatingSystems do not fully support

    positioning a file stream.

    For example, poor VMS does not allow positioning onto arbitrary

    byte boundaries if the file is a variable-record-RMS file.

    (stupid enough, this is the default for textfiles as created by

     some tools ...)

    Therefore, the instance variable canPosition is set according to

    this and an error is raised, if a position: is attemted.

    I know, this is ugly, but what else could we do ?

    [instance variables:]

	pathName        <String>        the files path (if known)

	canPosition     <Boolean>       positionable - read above comment

    [author:]

	Claus Gittinger

    [see also:]

	Filename DirectoryStream PipeStream Socket

"

!

examples

"

  for VMS users only:

    The #openWithMode:attributes: entry allows additional RMS attributes

    to be passed in the second argument, which must be an array of strings

    as described in the 'creat' RTL Library documentation.

    For example, to create a file with fixed records and recordLength of 100,

    use:

	|newFile|

	newFile := FileStream new pathName:'<nameOfFile>'.

	newFile setMode:#writeonly.

	newFile openWithMode:'w' attributes:#('rfm=fix' 'fsz=100').

    since all of the above is private protocol, and it is considered bad style to

    access these from user programs, we recommend subclassing FileStream as

    something like VMSFixedRecordFileStream, and redefine the instance creation

    method(s) there as appropriate. 

    This will retain VMS specifics in one place and enhance maintanability.

"

! !

!FileStream class methodsFor:'initialization'!

initialize

    OpenErrorSignal isNil ifTrue:[

	"/

	"/ this is temporary - for now allow an openError to

	"/ be unhandled and proceed by returning a nil from the

	"/ stream creation method.

	"/ In the future, this will be a hard signal.

	"/

	OpenErrorSignal := QuerySignal new.

	OpenErrorSignal parent:(super openErrorSignal) mayProceed:true.

	OpenErrorSignal nameClass:self message:#openErrorSignal.

	OpenErrorSignal notifierString:'open error'.

    ]

    "Modified: 8.10.1997 / 11:56:39 / cg"

! !

!FileStream class methodsFor:'instance creation'!

appendingOldFileNamed:filename

    "return a FileStream for existing file named filename, aString.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename.

    newStream openForAppending isNil ifTrue:[^nil].

"

    this is not a good idea; I might like to read the written stuff ...

    newStream readLimit:(newStream size).

"

    ^ newStream

!

appendingOldFileNamed:filename in:aDirectory

    "return a FileStream for existing file named filename, aString

     in aDirectory, a FileDirectory.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    newStream openForAppending isNil ifTrue:[^nil].

"

    this is not a good idea; I might like to read the written stuff ...

    newStream readLimit:(newStream size).

"

    ^ newStream

!

fileNamed:filename

    "return a stream on file filename - if the file does not

     already exist, create it.

     The file is opened for read/write access."

    |stream|

    stream := self oldFileNamed:filename.

    stream isNil ifTrue:[

	stream := self newFileNamed:filename

    ].

    ^ stream

!

fileNamed:filename in:aDirectory

    "return a stream on file filename - if the file does not

     already exist, create it.

     The file is opened for read/write access."

    |stream|

    stream := self oldFileNamed:filename in:aDirectory.

    stream isNil ifTrue:[

	stream := self newFileNamed:filename in:aDirectory

    ].

    ^ stream

!

newFileForWritingNamed:filename

    "return a FileStream for new file named filename, aString.

     If the file exists, it is truncated, otherwise created.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename.

    newStream createForWriting isNil ifTrue:[^nil].

    ^ newStream

!

newFileForWritingNamed:filename in:aDirectory

    "return a FileStream for new file named filename, aString

     in aDirectory, a FileDirectory.

     If the file exists, it is truncated, otherwise created.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    newStream createForWriting isNil ifTrue:[^nil].

    ^ newStream

!

newFileNamed:filename

    "return a FileStream for new file named filename, aString.

     If the file exists, it is truncated, otherwise created.

     The file is opened for read/write access."

    |newStream|

    newStream := self new pathName:filename.

    newStream createForReadWrite isNil ifTrue:[^nil].

    ^ newStream

    "Modified: / 28.10.1997 / 14:28:08 / cg"

!

newFileNamed:filename in:aDirectory

    "return a FileStream for new file named filename, aString

     in aDirectory, a FileDirectory.

     If the file exists, it is truncated, otherwise created.

     The file is opened for read/write access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    newStream createForReadWrite isNil ifTrue:[^nil].

    ^ newStream

!

oldFileNamed:filename

    "return a FileStream for existing file named filename, aString.

     The file is opened for read/write access."

    |newStream|

    (OperatingSystem isReadable:filename) ifFalse:[^nil].

    newStream := self new pathName:filename.

    newStream readwrite.

    newStream openForReadWrite isNil ifTrue:[^nil].

"

    this is not a good idea; someone else might be appending ...

    newStream readLimit:(newStream size).

"

    ^ newStream

!

oldFileNamed:filename in:aDirectory

    "return a FileStream for existing file named filename, aString

     in aDirectory, a FileDirectory.

     The file is opened for read/write access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    newStream openForReadWrite isNil ifTrue:[^nil].

"

    this is not a good idea; someone else might be appending ...

    newStream readLimit:(newStream size).

"

    ^ newStream

!

readonlyFileNamed:filename

    "return a readonly FileStream for existing file named filename, aString"

    |newStream|

    (OperatingSystem isReadable:filename) ifFalse:[^nil].

    newStream := self new pathName:filename.

    newStream openForReading isNil ifTrue:[^nil].

"

    this is not a good idea; someone else might be appending ...

    newStream readLimit:(newStream size).

"

    ^ newStream

!

readonlyFileNamed:filename in:aDirectory

    "return a readonly FileStream for existing file named filename, aString

     in aDirectory, a FileDirectory"

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    newStream openForReading isNil ifTrue:[^nil].

"

    this is not a good idea; someone else might be appending ...

    newStream readLimit:(newStream size).

"

    ^ newStream

! !

!FileStream class methodsFor:'Signal constants'!

openErrorSignal

    "return the FileStream specific openErrorSignal.

     This is different from ExternalStream>>OpenErrorSignal!!"

    ^ OpenErrorSignal

    "Created: / 28.1.1998 / 14:41:18 / stefan"

! !

!FileStream methodsFor:'Squeak compatibility'!

fullName

    "Squeak compatibility: return the full pathname"

    ^ pathName asFilename pathName

    "Created: 17.10.1997 / 17:04:12 / cg"

    "Modified: 20.10.1997 / 19:22:44 / cg"

! !

!FileStream methodsFor:'accessing'!

directoryName

    "return the name of the directory I'm in as a string"

    ^ pathName asFilename directoryName

!

name

    "return my name without leading direcory-path (i.e. the plain fileName)

     as a string"

    ^ pathName asFilename baseName

!

pathName

    "return the pathname"

    ^ pathName

!

removeOnClose:aBoolean

    "set/clear the removeOnClose flag.

     If set, the file will be removed when closed.

     Provided mostly for OS's which do not allow an

     open file to be removed (i.e. non unixes),