"

 COPYRIGHT (c) 1993 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

AbstractString subclass:#TwoByteString

       instanceVariableNames:''

       classVariableNames:''

       poolDictionaries:''

       category:'Collections-Text'

!

TwoByteString comment:'

COPYRIGHT (c) 1993 by Claus Gittinger

             All Rights Reserved

TwoByteStrings are like strings, but storing 16bits per character.

The integration of them into the system is not completed ....

$Header: /cvs/stx/stx/libbasic/TwoByteString.st,v 1.6 1994-03-30 10:26:27 claus Exp $

'!

!TwoByteString class methodsFor:'instance creation'!

basicNew:anInteger

    "return a new empty string with anInteger characters"

    ^ (super basicNew:(anInteger*2)) atAllPut:(Character space)

! !

!TwoByteString methodsFor:'queries'!

basicSize

    "return the size of the receiver.

     (i.e. the number of characters in this String)"

    ^ super basicSize // 2

! !

!TwoByteString methodsFor:'accessing'!

basicAt:index

    "return the character at position index, an Integer

     - reimplemented here since we return 16-bit characters"

    |val i|

    i := (index * 2) - 1.

    "always msb first"

    val := (super basicAt:(i+1)) + ((super basicAt:i) * 256).

    ^ Character value:val

!

basicAt:index put:aCharacter

    "store the argument, aCharacter at position index, an Integer

     - reimplemented here since we store 16-bit characters"

    |val i|

    val := aCharacter asciiValue.

    i := (index * 2) - 1.

    "always msb first"

    super basicAt:(i+1) put:(val bitAnd:16rFF).

    super basicAt:i put:(val // 256).

    ^ aCharacter

! !