"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Boolean subclass:#True

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Kernel-Objects'

!

!True class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    True has only one instance, true, representing logical truth.

    Some methods are implemented here and in False, instead of the common

    superclass Boolean. This has the advantage, that no truth-value checks

    are needed, but instead the thruth check is done in the method lookup.

    However, remember that some messages to booleans are inline coded in

    the compilers (both interpreted and machine code). Therefore redefinition

    of some methods here will not have any effect on compiled code.

    (redefining ifTrue: to something else will probably crash the smalltalk

     world anyway ...)

    [author:]

        Claus Gittinger

"

! !

!True methodsFor:'binary storage'!

storeBinaryOn: stream manager: manager

    "store a binary representation of the receiver on stream;

     redefined, since true is stored with a special type-code"

    stream nextPut: manager codeForTrue

! !

!True methodsFor:'conditional evaluation'!

and:aBlock

    "evaluate aBlock if the receiver is true.

     since the receiver is known to be true,

     return the value of evaluating the block.

     - open coded by compiler"

    ^ aBlock value

!

ifFalse:aBlock

    "return the true alternative, nil (since the receiver is true)

     - open coded by compiler"

    ^ nil

!

ifFalse:falseBlock ifTrue:trueBlock

    "return the value of evaluating trueBlock (since the receiver is true)

     - open coded by compiler"

    ^ trueBlock value

!

ifTrue:aBlock

    "return the value of evaluating aBlock (since the receiver is true)

     - open coded by compiler"

    ^ aBlock value

!

ifTrue:trueBlock ifFalse:falseBlock

    "return the value of evaluating trueBlock (since the receiver is true)

     - open coded by compiler"

    ^ trueBlock value

!

or:aBlock

    "evaluate aBlock if the receiver is false.

     since the receiver is known to be true simply return true.

     - open coded by compiler"

    ^ self

! !

!True methodsFor:'logical operations'!

& aBoolean

   "return true if both the receiver and the argument are true

    (since the receiver is true, return the argument, aBoolen)"

    ^ aBoolean

!

eqv:aBoolean

   "return true if both the receiver and the argument are the same truth value

    (since the receiver is true, return true if the argument is also)"

    ^ aBoolean

!

not

   "return true if the receiver is false, false otherwise

    (since the receiver is true, return false)"

    ^ false

!

xor:aBoolean

   "return true if the receiver and the argument are different truth values

    (since the receiver is true, return true, if the argument is not)"

    ^ aBoolean not

!

| aBoolean

   "return true if either the receiver or the argument are true

    (since the receiver is true, return true)"

    ^ true

! !

!True methodsFor:'printing & storing'!

printString

    "return character sequence representing the receiver"

    ^ 'true'

! !

!True class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libbasic/True.st,v 1.17 1996-04-25 16:51:53 cg Exp $'

! !