"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

ArithmeticValue subclass:#Number

	instanceVariableNames:''

	classVariableNames:'DecimalPointCharacterForPrinting DecimalPointCharactersForReading

		DefaultDisplayRadix'

	poolDictionaries:''

	category:'Magnitude-Numbers'

!

!Number class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    abstract superclass for all kinds of numbers

    [class variables:]

	DecimalPointCharacterForPrinting          <Character>                     used when printing

	DecimalPointCharactersForReading          <Collection of Character>       accepted as decimalPointChars when reading

	DefaultDisplayRadix     the radix in which integers present their

				displayString (which is used in inspectors)

				If you are to look at many hex numbers, bitmasks

				etc. you may set this to 2 or 16.

				(avoids typing printStringRadix:.. all the time

				 - I know - I am lazy ;-). Default is 10.

    [author:]

	Claus Gittinger

    [see also:]

	Integer LargeInteger SmallInteger

	LimitedPrecisionReal Float ShortFloat

	Fraction FixedPoint

"

! !

!Number class methodsFor:'instance creation'!

coerce:aNumber

    "convert the argument aNumber into an instance of the receiver (class) and return it."

    self == Number ifTrue:[

        self assert:(aNumber isNumber).

        ^ aNumber

    ].

    ^ super coerce:aNumber

    "Created: / 21-06-2017 / 08:58:38 / cg"

!

fastFromString:aString

    "return the next Float, Integer or ShortFloat from the string.

     No spaces are skipped.

     This is a specially tuned entry (using a low-level C-call), which

     returns garbage if the argument string is not a valid float number.

     It has been added to allow high speed string decomposition into numbers,

     especially for mass-data."

    ^ self fastFromString:aString at:1

    "

     Float fromString:'12345.0'

     Float fastFromString:'12345.0'

     Integer fromString:'12345'

     Integer fastFromString:'12345'

     should be roughly 10times faster than the general method:

     Time millisecondsToRun:[

	100000 timesRepeat:[ Float fromString:'12345.0' ]

     ].

     Time millisecondsToRun:[

	100000 timesRepeat:[ Float fastFromString:'12345.0' ]

     ].

     Time millisecondsToRun:[

	100000 timesRepeat:[ Integer fromString:'12345' ]

     ].

     Time millisecondsToRun:[

	100000 timesRepeat:[ Integer fastFromString:'12345' ]

     ].

    "

!

fastFromString:aString at:startIndex

    "return the next Float, Integer or ShortFloat from the string.

     No spaces are skipped.

     This is a specially tuned entry (using a low-level C-call), which

     returns garbage if the argument string is not a valid float number.

     It has been added to allow high speed string decomposition into numbers,

     especially for mass-data."

    self subclassResponsibility

    "

     Float fromString:'12345.0'

     Float fastFromString:'12345.0'

     Integer fromString:'12345'

     Integer fastFromString:'12345'

     should be roughly 10times faster than the general method:

     Time millisecondsToRun:[

        100000 timesRepeat:[ Float fromString:'12345.0' ]

     ].

     Time millisecondsToRun:[

        100000 timesRepeat:[ Float fastFromString:'12345.0' ]

     ].

     Time millisecondsToRun:[

        100000 timesRepeat:[ Integer fromString:'12345' ]

     ].

     Time millisecondsToRun:[

        100000 timesRepeat:[ Integer fastFromString:'12345' ]

     ].

    "

    "Created: / 21-07-2019 / 19:17:17 / Claus Gittinger"

!

fromNumber:aNumber

    "return aNumber coerced to myself"

    self isAbstract ifTrue:[^ aNumber]. 

    ^ self coerce:aNumber

    "Created: / 21-06-2017 / 08:57:00 / cg"

!

fromString:aString

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self

	fromString:aString

	decimalPointCharacters:(self decimalPointCharactersForReading)

    "

     Number fromString:'12345'

     Number fromString:'abc'

     Number fromString:'1abc'   -> raises an error

     Number readFrom:'1abc'     -> reads a 1

     Number readFrom:'10/2'     -> reads a 10

     Number fromString:'10/2'   -> raises an error

     Number fromString:'(1/2)'  -> reads a fraction

     Number readFrom:'(1/2)'    -> reads a fraction

     Number readFrom:'(10/2)'   -> reads a 5

     '12345' asNumber

    "

    "Modified: / 3.8.1998 / 20:05:11 / cg"

!

fromString:aString decimalPointCharacter:decimalPointCharacter

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self fromString:aString decimalPointCharacters:(decimalPointCharacter asString)

    "

     Number fromString:'12345.99' decimalPointCharacter:$.

     Number fromString:'12345,99' decimalPointCharacter:$,

    "

    "Created: / 21-07-2019 / 13:09:13 / Claus Gittinger"

    "Modified (comment): / 21-07-2019 / 18:04:30 / Claus Gittinger"

!

fromString:aString decimalPointCharacter:decimalPointCharacter onError:exceptionBlock

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self 

        fromString:aString 

        decimalPointCharacters:(decimalPointCharacter asString) 

        onError:exceptionBlock.

    "

     Number fromString:'12,345' decimalPointCharacter:',' onError:0

     Number fromString:'12,345' decimalPointCharacter:$, onError:0

     Number fromString:'12,345,456' decimalPointCharacter:$. thouseandsSeparator:$, onError:0

     Number fromString:'12,345,45' decimalPointCharacter:$. thouseandsSeparator:$, onError:0

    "

    "Created: / 21-07-2019 / 13:07:39 / Claus Gittinger"

    "Modified (comment): / 21-07-2019 / 18:50:18 / Claus Gittinger"

!

fromString:aString decimalPointCharacter:decimalPointCharacter thousandsSeparator:thousandsSeparator onError:exceptionBlock

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self 

        fromString:aString 

        decimalPointCharacters:(decimalPointCharacter asString) 

        thousandsSeparator:thousandsSeparator

        onError:exceptionBlock.

    "

     Number fromString:'12,345' decimalPointCharacter:',' onError:0

     Number fromString:'12,345' decimalPointCharacter:$, onError:0

     Number fromString:'12345,456' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12,345,456' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12,345,456,789' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12,345,456,789.89' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12.345.456.789,89' decimalPointCharacter:$, thousandsSeparator:$. onError:0

    these report an error:

     Number fromString:'12,345,45' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12.345.456.789' decimalPointCharacter:$. thousandsSeparator:$, onError:0

     Number fromString:'12.345.456.78' decimalPointCharacter:$. thousandsSeparator:$, onError:0

    "

    "Created: / 21-07-2019 / 18:50:57 / Claus Gittinger"

!

fromString:aString decimalPointCharacters:decimalPointCharacters

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    |s num|

    s := aString readStream.

    num := self 

            readFrom:s 

            decimalPointCharacters:decimalPointCharacters 

            onError:[^ ConversionError raiseRequestErrorString:' - invalid number'].

    s atEnd ifFalse:[

        s skipSeparators.

        s atEnd ifFalse:[

            ^ ConversionError raiseRequestErrorString:' - garbage at end of number'

        ].

    ].

    ^ num.

    "

     Number fromString:'12345'

     Number fromString:'abc'

     Number fromString:'1abc'

     '12345' asNumber

    "

    "Modified: / 03-08-1998 / 20:05:11 / cg"

    "Modified (format): / 21-07-2019 / 18:04:58 / Claus Gittinger"

!

fromString:aString decimalPointCharacters:decimalPointCharacters onError:exceptionBlock

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self

        fromString:aString 

        decimalPointCharacters:decimalPointCharacters 

        thousandsSeparator:nil 

        onError:exceptionBlock

    "

     Number fromString:'12345' onError:0

     Number fromString:'12,345' decimalPointCharacters:',' onError:0

     Number fromString:'12,345' decimalPointCharacters:',' onError:0

     Number fromString:'fooBarBaz' onError:0

     Number fromString:'123fooBarBaz' onError:0

     Number fromString:'123,fooBarBaz' decimalPointCharacters:',' onError:0

    "

    "Modified: / 03-08-1998 / 20:05:34 / cg"

    "Modified: / 21-07-2019 / 18:02:55 / Claus Gittinger"

!

fromString:aString decimalPointCharacters:decimalPointCharacters thousandsSeparator:thousandsSeparator onError:exceptionBlock

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    |s num|

    s := aString readStream.

    num := self readFrom:s 

            decimalPointCharacters:decimalPointCharacters 

            thousandsSeparator:thousandsSeparator

            onError:[^ exceptionBlock value].

    s atEnd ifFalse:[

        s skipSeparators.

        s atEnd ifFalse:[

            ^ exceptionBlock value "/ - garbage at end of number'

        ].

    ].

    ^ num.

    "

     Number fromString:'12345' onError:0

     Number fromString:'12,345' decimalPointCharacters:',' onError:0

     Number fromString:'12,345' decimalPointCharacters:',' onError:0

     Number fromString:'fooBarBaz' onError:0

     Number fromString:'123fooBarBaz' onError:0

     Number fromString:'123,fooBarBaz' decimalPointCharacters:',' onError:0

    "

    "Created: / 21-07-2019 / 18:02:32 / Claus Gittinger"

!

fromString:aString onError:exceptionBlock

    "return a number by reading from aString.

     In contrast to readFrom:, no garbage is allowed after the number.

     I.e. the string must contain exactly one valid number (with optional separators around)"

    ^ self fromString:aString decimalPointCharacters:(self decimalPointCharactersForReading) onError:exceptionBlock

    "

     Number fromString:'12345' onError:0

     Number fromString:'fooBarBaz' onError:0

     Number fromString:'123fooBarBaz' onError:0

    "

    "Modified: / 3.8.1998 / 20:05:34 / cg"

!

readFrom:aStringOrStream decimalPointCharacter:decimalPointCharacter

    "return the next Number from the (character-)stream aStream;

     skipping all whitespace first.

     Return the value of exceptionBlock, if no number can be read.

     This method is less strict than the smalltalk number reader; it

     allows for prefixed + and also allows missing fractional part after eE.

     It also allows garbage after the number - i.e. it reads what it can.

     See #fromString: , which is more strict and does not allow garbage at the end."

    ^ self

        readFrom:aStringOrStream

        decimalPointCharacters:(decimalPointCharacter asString)

    "

     Number readFrom:'0' decimalPointCharacter:$.  

     Number readFrom:'123.456' decimalPointCharacter:$.

     Number readFrom:'123,456' decimalPointCharacter:$,

    "

    "Created: / 21-07-2019 / 13:09:52 / Claus Gittinger"

    "Modified (comment): / 17-12-2019 / 14:42:47 / Stefan Reise"

!

readFrom:aStringOrStream decimalPointCharacter:decimalPointCharacter onError:exceptionBlock

    "return the next Number from the (character-)stream aStream;

     skipping all whitespace first.

     Return the value of exceptionBlock, if no number can be read.

     This method is less strict than the Smalltalk number reader; 

     it allows for prefixed + and also allows missing fractional part after eE.

     It supports the regular Smalltalk radix prefix xr.

     It also allows garbage after the number - i.e. it reads what it can.

     See #fromString: , which is more strict and does not allow garbage at the end.

     Notice (see examples below): 

        if sent to Number, it will decide which type of number to return (depending on the exponent character);

        if sent to a concrete number-class, an instance of that class will be returned (independent of the exponent character)

    "

    ^ self readFrom:aStringOrStream decimalPointCharacters:(decimalPointCharacter asString) onError:exceptionBlock

    "

     Number readFrom:(ReadStream on:'54.32e-01') decimalPointCharacter:$. onError:[self halt].

     Number readFrom:(ReadStream on:'54,32e-01') decimalPointCharacter:$, onError:[self halt].

    "

    "Created: / 21-07-2019 / 13:11:12 / Claus Gittinger"

!

readFrom:aStringOrStream decimalPointCharacters:decimalPointCharacters

    "return the next Number from the (character-)stream aStream;

     skipping all whitespace first.

     Return the value of exceptionBlock, if no number can be read.

     This method is less strict than the smalltalk number reader; it

     allows for prefixed + and also allows missing fractional part after eE.

     It also allows garbage after the number - i.e. it reads what it can.

     See #fromString: , which is more strict and does not allow garbage at the end."

    ^ self

	readFrom:aStringOrStream

	decimalPointCharacters:decimalPointCharacters

	onError:[self error:'conversion error for: ' , self name]

    "

     Number readFrom:'123.456' decimalPointCharacters:'.'

     Number readFrom:'123,456' decimalPointCharacters:'.,'

     Number readFrom:'123,456' decimalPointCharacters:'.'

    "

!

readFrom:aStringOrStream decimalPointCharacters:decimalPointCharacters allowCStyle:allowCStyle onError:exceptionBlock

    "return the next Number from the (character-)stream aStream;

     skipping all whitespace first.

     Return the value of exceptionBlock, if no number can be read.

     This method is less strict than the Smalltalk number reader; 

     it allows for prefixed + and also allows missing fractional part after eE.

     It supports 0x, 0o and 0b prefixes (hex, octal and binary)

     and the regular Smalltalk radix prefix xr.

     If also allows for strings like '1.0×1015' to be read (as 1E+15).

     It also allows garbage after the number - i.e. it reads what it can.

     See #fromString: , which is more strict and does not allow garbage at the end.

     Notice (see examples below): 

        if sent to Number, it will decide which type of number to return (depending on the exponent character);

        if sent to a concrete number-class, an instance of that class will be returned (independent of the exponent character)

    "

    ^ self

        readFrom:aStringOrStream 

        decimalPointCharacters:decimalPointCharacters

        thousandsSeparator:nil

        allowCStyle:allowCStyle onError:exceptionBlock

    "

     Number readFrom:(ReadStream on:'1.234.567,99') 

        decimalPointCharacter:$,

        thousandsSeparator:$.

        onError:[self halt].

    "

    "Created: / 27-10-2018 / 09:21:11 / Claus Gittinger"

    "Modified: / 21-07-2019 / 13:06:54 / Claus Gittinger"

!

readFrom:aStringOrStream decimalPointCharacters:decimalPointCharacters onError:exceptionBlock

    "return the next Number from the (character-)stream aStream;

     skipping all whitespace first.

     Return the value of exceptionBlock, if no number can be read.

     This method is less strict than the Smalltalk number reader; 

     it allows for prefixed + and also allows missing fractional part after eE.

     It supports the regular Smalltalk radix prefix xr.

     It also allows garbage after the number - i.e. it reads what it can.

     See #fromString: , which is more strict and does not allow garbage at the end.

     Notice (see examples below): 

        if sent to Number, it will decide which type of number to return (depending on the exponent character);

        if sent to a concrete number-class, an instance of that class will be returned (independent of the exponent character)

    "

    ^ self 

        readFrom:aStringOrStream 

        decimalPointCharacters:decimalPointCharacters 

        thousandsSeparator:nil

        allowCStyle:true 

        onError:exceptionBlock

    "

     Number readFrom:(ReadStream on:'54.32e-01') decimalPointCharacters:'.' onError:[self halt].

     Number readFrom:(ReadStream on:'12345') decimalPointCharacters:'.' onError:[self halt].

     Number readFrom:(ReadStream on:'12345.0') decimalPointCharacters:'.' onError:[self halt].

     Number readFrom:(ReadStream on:'12345.0f') decimalPointCharacters:'.' onError:[self halt].

     Number readFrom:(ReadStream on:'12345.0e') decimalPointCharacters:'.' onError:[self halt].

     Number readFrom:(ReadStream on:'12345.0q') decimalPointCharacters:'.' onError:[self halt].