"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Geometric subclass:#Rectangle

	instanceVariableNames:'left top width height'

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Geometry'

!

!Rectangle class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Rectangles represent a rectangular area in 2D space.

    notice, my implementation does not use origin/corner as instance objects

    but left/top/width/height to save space and allocations. This means, that my

    Rectangles cannot be used to represent Rectangles in a higher than 2D

    space. (i.e. only valid if origin/corner are 2D Points)

    (aside from that, you will not see any difference from the outside)

    Instance variables:

        left           <Number>        the left coordinate (i.e origin x)

        top            <Number>        the top coordinate (i.e origin y)

        width          <Number>        the width of the rectangle

        height         <Number>        the height of the rectangle

    I am not certain, if implementing Rectangle different was a good idea - 

    subclasses may expect things to be different ...

    Therefore, this may change.

    [author:]

        Claus Gittinger

    [see also:]

        Point Polygon Circle EllipticalArc Spline

        LayoutOrigin LayoutFrame AlignmentOrigin Layout 

        View GraphicsContext StrokingWrapper FillingWrapper

"

! !

!Rectangle class methodsFor:'instance creation'!

decodeFromLiteralArray:anArray

    "create & return a new instance from information encoded in anArray.

     Redefined for faster creation."

    |l t w h|

    l := anArray at:2.

    t := anArray at:3.

    w := (anArray at:4) - l.

    h := (anArray at:5) - t.

    ^ self left:l top:t width:w height:h

    "

     Rectangle decodeFromLiteralArray:#(Rectangle 100 200 300 500) 

    "

    "Created: / 28.1.1998 / 17:46:52 / cg"

!

fromUser

    "let user specify a rectangle on the screen, return it"

    ^ Screen current rectangleFromUser

    "

     Rectangle fromUser     

    "

!

left:left right:right top:top bottom:bottom

    "create and return a new Rectangle giving left, top, right and bottom coordinates"

    ^ (self basicNew) left:left right:right top:top bottom:bottom

!

left:left top:top extent:extent

    "create and return a new Rectangle giving left, top, and

     an extent point."

    ^ (self basicNew) left:left top:top extent:extent

    "Created: 8.5.1996 / 20:56:29 / cg"

!

left:left top:top right:right bottom:bottom

    "create and return a new Rectangle giving left, top, right and bottom coordinates"

    ^ (self basicNew) left:left top:top right:right bottom:bottom

!

left:left top:top width:w height:h

    "create and return a new Rectangle giving left and top coordinates

     and width, height"

%{  /* NOCONTEXT */

    REGISTER OBJ newRect;

    OBJ t;

    int spc;

    if (__CanDoQuickNew(OHDR_SIZE + 4*sizeof(OBJ))) {	/* OBJECT ALLOCATION */

	if (self == Rectangle) {

	    /*

	     * short cut - rectangles are created so often ...

	     */

	    __qCheckedAlignedNew(newRect, OHDR_SIZE + 4*sizeof(OBJ));

	    __InstPtr(newRect)->o_class = Rectangle;

	    __InstPtr(newRect)->i_instvars[0] = left;

	    __InstPtr(newRect)->i_instvars[1] = top;

	    __InstPtr(newRect)->i_instvars[2] = w;

	    __InstPtr(newRect)->i_instvars[3] = h;

	    if (! (__bothSmallInteger(left, top) && 

		   __bothSmallInteger(w, h))) {

		spc = __qSpace(newRect);

		__STORE_SPC(newRect, left, spc);

		__STORE_SPC(newRect, top, spc);

		__STORE_SPC(newRect, w, spc);

		__STORE_SPC(newRect, h, spc);

	    }

	    RETURN ( newRect );

	}

    }

%}.

    ^ (self basicNew) left:left top:top width:w height:h

!

origin:origin corner:corner

    "create and return a new Rectangle giving top-left and bottom-right points"

    ^ (self basicNew) origin:origin corner:corner

!

origin:origin extent:extent

    "create and return a new Rectangle giving top-left point and extent point"

%{  /* NOCONTEXT */

    REGISTER OBJ newRect;

    OBJ t;

    int spc;

    if (__CanDoQuickNew(OHDR_SIZE + 4*sizeof(OBJ))) {	/* OBJECT ALLOCATION */

        /*

	 * short cut - rectangles are created so often ...

	 */

	if (self == Rectangle) {

	    if (__isPoint(origin) && __isPoint(extent)) {

		__qCheckedAlignedNew(newRect, OHDR_SIZE + 4*sizeof(OBJ));

		__InstPtr(newRect)->o_class = Rectangle;

		spc = __qSpace(newRect);

		t = __PointInstPtr(origin)->p_x;

		__InstPtr(newRect)->i_instvars[0] = t;

		__STORE_SPC(newRect, t, spc);

		t = __PointInstPtr(origin)->p_y;

		__InstPtr(newRect)->i_instvars[1] = t;

		__STORE_SPC(newRect, t, spc);

		t = __PointInstPtr(extent)->p_x;

		__InstPtr(newRect)->i_instvars[2] = t;

		__STORE_SPC(newRect, t, spc);

		t = __PointInstPtr(extent)->p_y;

		__InstPtr(newRect)->i_instvars[3] = t;

		__STORE_SPC(newRect, t, spc);

		RETURN ( newRect );

	    }

	}

    }

%}.

    ^ (self basicNew) origin:origin extent:extent

!

origin:origin width:w height:h

    "create and return a new Rectangle giving top-left and extent

     as individual width/height"

    ^ (self basicNew) origin:origin width:w height:h

    "Created: 8.5.1996 / 20:55:53 / cg"

!

vertex:vertex1Point vertex:vertex2Point 

    "create and return a new instance of the receiver,

     given two diagonally opposite vertices."

    ^ self

        origin: (vertex1Point min: vertex2Point)

        corner: (vertex1Point max: vertex2Point)

    "Created: 10.2.1997 / 12:14:32 / cg"

! !

!Rectangle methodsFor:'accessing'!

area

    "return the area 

     - for screen Rectangles this is the number of pixels"

    ^ width * height

!

bottom

    "return the y coordinate of the bottom"

    ^ (top + height)

!

bottom:aNumber

    height := aNumber - top

!

bottomCenter

    "return the bottom center point"

    ^ (left + (width / 2)) @ (top + height)

    "Modified: 4.6.1996 / 16:04:08 / cg"

!

bottomLeft

    "return the bottom-left point"

    ^ left @ (top + height)

!

bottomRight

    "return the bottom-right point"

    ^ (left + width) @ (top + height)

!

center

    "return the point in the center of the receiver"

    ^ (left + (width / 2)) @ (top + (height / 2))

    "Modified: 4.6.1996 / 16:03:53 / cg"

!

corner

    "return the corner"

    ^ (left + width) @ (top + height)

!

corner:aPoint

    width := aPoint x - left.

    height := aPoint y - top

!

extent

    "return the extent"

    ^ width @ height

!

extent:aPoint

    "set the extent from the argument, aPoint with width taken from aPoint x

    width := aPoint x.

    height := aPoint y

!

height

    "return the height of the rectangle"

    ^ height

!

height:aNumber

    "change the height of the rectangle.

    height := aNumber

    "Created: 3.3.1997 / 16:33:22 / cg"

!

left

    "return the x-coordinate of the top-left origin"

    ^ left

!

left:aNumber

    width := width + (left - aNumber).

    left := aNumber

!

left:newLeft right:right top:newTop bottom:bottom

    left := newLeft.

    top := newTop.

    width := right - left.

    height := bottom - top

!

left:newLeft top:newTop extent:extent

    left := newLeft.

    top := newTop.

    width := extent x.

    height := extent y

    "Created: 8.5.1996 / 20:55:10 / cg"

!

left:newLeft top:newTop right:right bottom:bottom

    left := newLeft.

    top := newTop.

    width := right - left.

    height := bottom - top

!

left:newLeft top:newTop width:newWidth height:newHeight

    left := newLeft.

    top := newTop.

    width := newWidth.

    height := newHeight

!

leftCenter

    "return the left center point"

    ^ left @ (top + (height / 2))

    "Modified: 4.6.1996 / 16:04:01 / cg"

!

origin

    "return the origin"

    ^ left @ top

!

origin:aPoint

    |newTop newLeft|

    newTop := aPoint y.

    newLeft := aPoint x.

    height := height + (top - newTop).

    width := width + (left - newLeft).

    left := newLeft.

    top := newTop

!

origin:origin corner:corner

    left := origin x.

    top := origin y.

    width := corner x - left.

    height := corner y - top

!

origin:origin extent:extent

    left := origin x.

    top := origin y.

    width := extent x.

    height := extent y

!

origin:origin width:w height:h

    "set both origin and extent; 

    left := origin x.

    top := origin y.

    width := w.

    height := h

    "Created: 8.5.1996 / 20:53:53 / cg"

!

right

    "return the x coordinate of the right"

    ^ (left + width)

!

right:aNumber

    width := aNumber - left

!

rightCenter

    "return the right center point"

    ^ (left + width) @ (top + (height / 2))

    "Modified: 4.6.1996 / 16:09:05 / cg"

!

setLeft:newLeft

    left := newLeft.

    "Modified: / 22.1.1998 / 09:40:35 / av"

    "Created: / 3.2.1998 / 19:01:06 / cg"

!

setTop:newTop

    top := newTop.

    "Modified: / 20.1.1998 / 18:25:35 / av"

    "Created: / 3.2.1998 / 19:01:01 / cg"

!

top

    "return the y-coordinate of the top-left"

    ^ top

!

top:aNumber

    height := height + (top - aNumber).

    top := aNumber

!

topCenter

    "return the top center point"

    ^ (left + (width / 2)) @ top