"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

Collection subclass:#FileDirectory

	instanceVariableNames:'pathName lazy'

	classVariableNames:'PathOfCurrentDirectory'

	poolDictionaries:''

	category:'Compatibility-Squeak'

!

ArrayedCollection subclass:#DirectoryEntry

	instanceVariableNames:'name creationTime modificationTime dirFlag fileSize'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileDirectory

!

!FileDirectory class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Notice:

        This class is obsolete and does work only under UNIX. 

        Use Filename instead. It is left here for squeak compatibility.

        This class is not available in other ST-systems;

        in contrast, VisualWorks provides a Filename class.

        Therefore, Filename has taken over the functionality.

    FileDirectories represent directories in the underlying host system.

    They provide various methods to create/delete and query for files and/or

    directories. Also, since FileDirectory inherits from Collection, it

    provides all enumeration and testing protocol. For example, you can

    loop over the filenames in a directory using 'aFileDirectory do:[:nm | ...]'.

    [author:]

        Claus Gittinger

    [see also:]

        Filename

        FileStream DirectoryStream OperatingSystem

"

! !

!FileDirectory class methodsFor:'initialization'!

initialize

    "/

    "/ want to know about image restart

    "/

    ObjectMemory addDependent:self

!

update:something with:aParameter from:changedObject

    "/

    "/ currentDirectory may be different when restarted

    "/

    something == #earlySystemInstallation ifTrue:[

        PathOfCurrentDirectory := nil

    ]

    "Created: / 15.6.1996 / 15:20:21 / cg"

    "Modified: / 11.12.1998 / 16:28:40 / cg"

! !

!FileDirectory class methodsFor:'instance creation'!

currentDirectory

    "create and return a new FileDirectory for the current directory"

    "/ self obsoleteMethodWarning:'use Filename'.

    ^ self on:(Filename currentDirectory name)

    "

     FileDirectory currentDirectory contents

     FileDirectory currentDirectory files

     FileDirectory currentDirectory isReadable

     FileDirectory currentDirectory pathName

    "

    "Modified: / 20-08-2011 / 12:19:51 / cg"

!

directoryNamed:name

    "create and return a new FileDirectory for the directory

     with given pathname"

    "/ self obsoleteMethodWarning:'use Filename'.

    name asString = '.' ifTrue:[

        Filename currentDirectory name ~= '.' ifTrue:[

            ^ self currentDirectory

        ]

    ].

    ^ self on:(name asFilename constructString:'')

    "

     (FileDirectory directoryNamed:'..') pathName

     (FileDirectory directoryNamed:'../..') files

    "

    "Modified: / 20-08-2011 / 12:19:57 / cg"

!

directoryNamed:name in:aFileDirectory

    "create and return a new FileDirectory for the directory with given name

     in another FileDirectory"

    |baseName|

    "/ self obsoleteMethodWarning:'use Filename'.

    name asFilename isAbsolute ifTrue:[

        ^ self directoryNamed:name

    ].

    (aFileDirectory isKindOf:FileDirectory) ifTrue:[

        baseName := aFileDirectory pathName

    ] ifFalse:[

        baseName := aFileDirectory

    ].

    ^ self on:((Filename named:baseName) constructString:name)

    "Modified: / 28-04-1997 / 22:34:47 / dq"

    "Modified: / 20-08-2011 / 12:20:03 / cg"

!

on:aDirectoryPathName

    ^ (self basicNew) pathName:aDirectoryPathName

    "Created: / 20-08-2011 / 12:19:28 / cg"

!

rootDirectory

    "create and return a new FileDirectory for the root directory"

    "/ self obsoleteMethodWarning:'use Filename'.

    ^ self on:(Filename rootDirectory name)

    "

     FileDirectory rootDirectory contents

     FileDirectory rootDirectory files

     FileDirectory rootDirectory isReadable

    "

    "Modified: / 20-08-2011 / 12:20:09 / cg"

! !

!FileDirectory class methodsFor:'Compatibility-Squeak'!

default

    ^ (self basicNew) pathName:(Filename defaultDirectory name)

!

localNameFor:aFileNameString

    ^ aFileNameString asFilename baseName

!

pathNameDelimiter

    ^ Filename separator

!

slash

    ^ Filename separator asString

    "Created: / 20-08-2011 / 12:18:27 / cg"

! !

!FileDirectory class methodsFor:'private'!

fullPathNameOf:name in:path

    |sep|

    sep := OperatingSystem fileSeparator asString.

    "/ is it an absolute path ?

    (name startsWith:sep) ifTrue:[

        ^ name

    ].

    "/ temporary kludge; this and the previous should

    "/ go into OS isAbsolutePath ..

    OperatingSystem isMSDOSlike ifTrue:[

        ('[a-zA-Z]:*' match:name) ifTrue:[

            "/ drive spec ...

            ^ name

        ]

    ].                  

    ^ path , sep , name

    "Modified: 28.4.1997 / 22:06:17 / cg"

    "Modified: 28.4.1997 / 22:34:18 / dq"

! !

!FileDirectory methodsFor:'Compatibility-Squeak'!

assureExistence

    self asFilename recursiveMakeDirectory

!

containingDirectory

    ^ self class

        directoryNamed:(self asFilename directory pathName)

!

deleteDirectory:dirName

    "Squeak/ST80 compatibility"

    ^ self removeDirectory:dirName

!

deleteFileNamed:fileName

    "Squeak/ST80 compatibility"

    ^ self removeFile:fileName

!

directoryEntryFor:name

    |info|

    info := self infoOf:name.

    info isNil ifTrue:[

        info := (self filenameFor:name) linkInfo.

    ].

    ^ DirectoryEntry new

        name:name

        creationTime:(info creationTime)

        modificationTime:(info modificationTime)

        dirFlag:(info isDirectory)

        fileSize:(info isDirectory)

    "

     (FileDirectory directoryNamed:'.') entries

    "

    "Modified: / 29-08-2011 / 08:19:48 / cg"

!

directoryExists:dir

    "Squeak/ST80 compatibility"

    |f|

    f := self filenameFor:dir.

    ^ f exists and:[f isDirectory ].

!

directoryNames

    "Squeak/ST80 compatibility"

    ^ self directories

!

entries

    ^ self contents collect:[:nm | self directoryEntryFor:nm].

!

fileExists:dir

    "Squeak/ST80 compatibility"

    |f|

    f := self filenameFor:dir.

    ^ f exists and:[f isDirectory not ].

!

fileNames

    "Squeak/ST80 compatibility"

    ^ self files

!

forceNewFileNamed:fn

    "Squeak/ST80 compatibility"

    |f|

    f := self filenameFor:fn.

    ^ f writeStream

!

includesKey:name

    "Squeak/ST80 compatibility"

    ^ self exists:name

!

oldFileNamed:fn

    "Squeak/ST80 compatibility"

    |f|

    f := self filenameFor:fn.

    ^ f readStream

!

readOnlyFileNamed:fn

    "Squeak/ST80 compatibility"

    |f|

    f := self filenameFor:fn.

    ^ f readStream

!

recursiveDelete

    self asFilename recursiveRemove

! !

!FileDirectory methodsFor:'accessing'!

baseName

    "return my baseName

     - thats the directory name without leading parent-dirs"

    lazy ifTrue:[self getFullPathName].

    ^ pathName asFilename baseName

!

contents 

    "return a collection with all files and subdirectories in the receiver.

     Skips any '.' or '..' entries (UNIX)"

    |coll|

    coll := OrderedCollection new.

    self do:[:name |

        name ~= '.' ifTrue:[

            name ~= '..' ifTrue:[

                coll add:name

            ]

        ]

    ].

    coll sort.

    ^ coll

    "Modified: 20.6.1997 / 17:05:43 / cg"

!

directories

    "return a collection with all subdirectories in the receiver directory"

    |coll|

    coll := OrderedCollection new.

    self directoriesDo:[:name |

	coll add:name

    ].

    coll sort.

    ^ coll

!

directoryName

    "return my directoryName

     - thats the directory name where I'm in"

    lazy ifTrue:[self getFullPathName].

    ^ pathName asFilename directoryName

!

files

    "return a collection with all plain files in the receiver directory"

    |coll|

    coll := OrderedCollection new.

    self filesDo:[:name |

	coll add:name

    ].

    coll sort.

    ^ coll

!

pathName

    "return my full pathname"

    lazy ifTrue:[self getFullPathName].

    ^ pathName

!

pathName:dirName

    "set my pathname; return nil if not a valid path; self otherwise"

    pathName := dirName.

    (dirName startsWith:OperatingSystem fileSeparator) ifFalse:[

	lazy := true

    ] ifTrue:[

	(dirName startsWith:'./') ifFalse:[

"/        (dirName includes:$.) ifTrue:[

	    lazy := true

	]

    ].

    ^ self

! !

!FileDirectory methodsFor:'basic'!

createDirectory:newName

    "create a new filedirectory as a subdirectory of myself;

     return true if successful"

    |realName|

    (newName notNil and:[newName notEmpty]) ifTrue:[

	(newName ~= '.' and:[newName ~= '..']) ifTrue:[

	    ((newName at:1) == OperatingSystem fileSeparator) ifTrue:[

		realName := newName copyFrom:2

	    ] ifFalse:[

		realName := newName

	    ].

	    ^ (self filenameFor:realName) makeDirectory

	]

    ].

    ^ false

!

link:oldFileName to:newFileName

    "link oldFileName to newFileName in myself, return true if successful"

    |path1 path2|

    path1 := self pathNameOf:oldFileName.

    path2 := self pathNameOf:newFileName.

    ^ OperatingSystem linkFile:path1 to:path2

!

remove:aFileOrDirectoryName

    "remove the file or directory from myself; return true if successful"

    ^ (self filenameFor:aFileOrDirectoryName) remove

!

removeDirectory:dirName

    "remove the directory 'dirName' from myself; return true if successful.

     If the directory is not empty, the containing files/directories are also

     removed."

    ^ (self filenameFor:dirName) recursiveRemove

!

removeFile:fileName

    "remove the file 'fileName' from myself; return true if successful"

    ^ (self filenameFor:fileName) remove

!

renameFile:oldFileName newName:newFileName

    "rename the file; return true if successful"

    |f1 f2|

    f1 := self filenameFor:oldFileName.

    f2 := self filenameFor:newFileName.

    ^ f1 renameTo:f2

! !

!FileDirectory methodsFor:'converting'!

asFilename

    "return myself as a filename"

    ^ self pathName asFilename

!

asFilename:someFile