"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

LimitedPrecisionReal variableByteSubclass:#Float

	instanceVariableNames:''

	classVariableNames:'DefaultPrintFormat Pi E Halfpi HalfpiNegative Twopi

		RadiansPerDegree Ln2 Ln10 Sqrt2'

	poolDictionaries:''

	category:'Magnitude-Numbers'

!

!Float primitiveDefinitions!

%{

#include <stdio.h>

#include <errno.h>

#ifndef __OPTIMIZE__

# define __OPTIMIZE__

#endif

#define __USE_ISOC9X 1

#define __USE_ISOC99 1

#include <math.h>

/*

 * on some systems errno is a macro ... check for it here

 */

#ifndef errno

 extern errno;

#endif

#if !defined (WIN32)

# include <locale.h>

#endif

#if defined (_AIX)

# include <float.h>

#endif

#if defined(IRIX)

# include <nan.h>

#endif

#if defined(LINUX)

# ifndef NAN

#  include <bits/nan.h>

# endif

#endif

#if defined(solaris) || defined(sunos)

# include <nan.h>

#endif

/*

 * sigh - some systems define that stuff; others dont.

 * (AIX even declares them as macros, so an external decl

 *  will not work below ...

 */

#if !defined(_AIX) && !defined(NEXT3)

# ifdef acos

  double acos();

# endif

# ifdef asin

  double asin();

# endif

# ifndef atan

  double atan();

# endif

# ifndef cos

  double cos();

# endif

# ifndef sin

  double sin();

# endif

# ifndef pow

  double pow();

# endif

# ifndef log

  double log();

# endif

# ifndef exp

  double exp();

# endif

# ifndef sqrt

  double sqrt();

# endif

# ifndef tan

  double tan();

# endif

#endif /* not AIX */

#ifdef WIN32

/*

 * no finite(x) ?

 * no isnan(x) ?

 */

# ifndef isnan

#  define isnan(x)      \

	((((unsigned int *)(&x))[0] == 0x00000000) && \

	 (((unsigned int *)(&x))[1] == 0xFFF80000))

# endif

# ifndef isPositiveInfinity

#  define isPositiveInfinity(x) \

	((((unsigned int *)(&x))[0] == 0x00000000) && \

	 (((unsigned int *)(&x))[1] == 0x7FF00000))

# endif

# ifndef isNegativeInfinity

#  define isNegativeInfinity(x) \

	((((unsigned int *)(&x))[0] == 0x00000000) && \

	 (((unsigned int *)(&x))[1] == 0xFFF00000))

# endif

# ifndef isinf

#  define isinf(x) \

	((((unsigned int *)(&x))[0] == 0x00000000) && \

	 ((((unsigned int *)(&x))[1] & 0x7FF00000) == 0x7FF00000))

# endif

# ifndef isfinite

#  define isfinite(x) (!isinf(x) && !isnan(x))

# endif

# define NO_ASINH

# define NO_ACOSH

# define NO_ATANH

# ifdef __MINGW__

#  include <string.h>

# endif

#endif /* WIN32 */

#ifdef solaris

# ifndef isfinite

#  define isfinite(f) finite((double)(f))

# endif

#endif

#ifdef realIX

# ifndef isfinite

#  define isfinite(x)     1

# endif

#endif

#ifndef NEXT3

# ifndef ceil

double ceil();

double floor();

# endif

#endif

%}

! !

!Float class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1988 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Floats represent rational numbers with limited precision.

    They use the C-compilers 'double' format, which is usually the 8byte IEE double float format.

    Floats give you 64 bit floats.

    In contrast to ShortFloats (32bit) and LongFloats (>=64bit).

    WARNING:

	The layout of Float instances is known by the runtime system and the compiler;

	you may not add instance variables here.

	Also, subclassing is complicated by the fact, that the VM creates floats/shortFloats,

	and does some float-checks by an identity compare with the Float-class.

	(i.e. your subclasses instances may not be recognized as float-like objects,

	 thus mixed mode arithmetic will always coerce them, effectively slowing things down).

    Notice, that Floats are defined as Byte-array to prevent the garbage collector

    from going into the value ... otherwise I needed a special case in many places.

    Also notice, that ST/X Floats are what Doubles are in ST-80 - this may change

    in one of the next versions (at least on machines, which provide different float

    and double types in their C-compiler).

    The reason for doing this was to be compatible to both Digitalk, Squeak AND ParcPlace smalltalk

    implementations

    (ParcPlace uses a 4-byte Float and an 8-byte Double class, in contrast to

     Digitalk and Squeak, which have an 8-byte Float class).

    Thus, by providing an 8-byte Float class, code would not loose precicion

    (although some memory is wasted when porting from VW).

    Notice that ST/X provides an alias called Double, and an extra ShortFloat class, which has 4-byte

    instances.

    Mixed mode arithmetic:

	float op float       -> float

	float op fix         -> float

	float op fraction    -> float

	float op integer     -> float

	float op shortFloat  -> float

	float op longFloat   -> longFloat

	float op complex     -> complex

    Representation:

	    64bit double precision IEE floats

	    53 bit mantissa,

	    11 bit exponent,

	    15 decimal digits (approx)

    Range and Precision of Storage Formats: see LimitedPrecisionReal >> documentation

    [author:]

	Claus Gittinger

    [see also:]

	Number

	ShortFloat LongFloat Fraction FixedPoint Integer Complex

	FloatArray DoubleArray

"

!

errorHandling

"

    Floating point error handling and signalling depends on the systems

    (actually: the C-runtime systems) ability to handle floating point errors.

    Most systems report errors by raising an OS floatingPoint exception,

    which is mapped to a fpExceptionInterrupt in ST/X.

    However, some systems do return NaN as result.

    Currently, ST/X does not care specially for these systems - it maybe added

    easily, if there is sufficient customer interest, though.

    Try:

	|f1 f2|

	f1 := 1.0.

	f2 := 0.0.

	f1 / f2

    or:

	2 arcSin

"

! !

!Float class methodsFor:'instance creation'!

basicNew

    "return a new float - here we return 0.0

     - floats are usually NOT created this way ...

     Its implemented here to allow things like binary store & load

     of floats. (but even this support will go away eventually, its not

     a good idea to store the bits of a float - the reader might have a

     totally different representation - so floats will eventually be

     binary stored in a device independent format."

%{  /* NOCONTEXT */

    OBJ newFloat;

    __qMKFLOAT(newFloat, 0.0);

    RETURN (newFloat);

%}

!

coerce:aNumber

    ^ aNumber asFloat.

!

fastFromString:aString at:startIndex

    "return the next Float from the string starting at startIndex.

     No spaces are skipped.

     This is a specially tuned entry (using a low-level C-call), which

     returns garbage if the argument string is not a valid float number.

     It has been added to allow high speed string decomposition into numbers,

     especially for mass-data."

%{   /* NOCONTEXT */

     if (__isStringLike(aString) && __isSmallInteger(startIndex)) {

	char *cp = (char *)(__stringVal(aString));

	int idx = __intVal(startIndex) - 1;

	double atof();

	double val;

	if ((unsigned)idx < __stringSize(aString)) {

	    val = atof(cp + idx);

	    RETURN (__MKFLOAT(val));

	}

     }

%}.

     self primitiveFailed.

    "

     Float fastFromString:'123.45' at:1

     Float fastFromString:'123.45' at:2

     Float fastFromString:'123.45E4' at:1

     Float fastFromString:'hello123.45E4' at:6

     Float fastFromString:'12345' at:1

     Float fastFromString:'12345' at:2

     Float fastFromString:'12345' at:3

     Float fastFromString:'12345' at:4

     Float fastFromString:'12345' at:5

     Float fastFromString:'12345' at:6

     Float fastFromString:'12345' at:0

     Float fastFromString:'hello123.45E4' at:1

     Time millisecondsToRun:[

	100000 timesRepeat:[

	    Float readFrom:'123.45'

	]

     ]

    "

    "

     Time millisecondsToRun:[

	100000 timesRepeat:[

	    Float fastFromString:'123.45' at:1

	]

     ]

    "

!

fromIEEE32Bit: anInteger

    "creates a double, given the four native float bytes as an integer"

%{  /* NOCONTEXT */

    REGISTER union {

	unsigned int    i;

	float           f;

    } r;

    r.i = __unsignedLongIntVal( anInteger );

    RETURN( __MKFLOAT((double)(r.f)) );

%}

!

fromVAXFloatBytes:b1 b2:b2 b3:b3 b4:b4

    "creates a double, given the four vax float bytes to an ieee double.

     For NaNs and Infinity, nil is returned.

    "

%{  /* NOCONTEXT */

    REGISTER union {

	unsigned char   b[4];

	unsigned int    l;

	float           f;

    } r;

#ifdef __LSBFIRST__

    r.b[3] = __intVal( b2 );

    r.b[2] = __intVal( b1 );

    r.b[1] = __intVal( b4 );

    r.b[0] = __intVal( b3 );

#else

    r.b[0] = __intVal( b2 );

    r.b[1] = __intVal( b1 );

    r.b[2] = __intVal( b4 );

    r.b[3] = __intVal( b3 );

#endif

    if( (r.l & 0xff800000) != 0x80000000 )

    {

	if( (r.l & 0x7f800000) > 0x01000000 )

	    r.l -= 0x01000000;

	else

	    r.l = 0;

	RETURN( __MKFLOAT(r.f) );

    }

%}.

    ^ nil

! !

!Float class methodsFor:'accessing'!

defaultPrintFormat

    ^ DefaultPrintFormat

!

defaultPrintFormat:something

    DefaultPrintFormat := something.

! !

!Float class methodsFor:'binary storage'!

readBinaryIEEEDoubleFrom:aStream

    "read a float from the binary stream, aStream,

     interpreting the next bytes as an IEEE formatted 8-byte float.

     The bytes are read in the native byte order (i.e.lsb on intel)"

    |f|

    f := self basicNew.

    self readBinaryIEEEDoubleFrom:aStream into:f MSB:(UninterpretedBytes isBigEndian).

    ^ f

    "not part of libboss, as this is also used by others (TIFFReader)"

    "Created: / 16-04-1996 / 20:59:59 / cg"

    "Modified: / 23-08-2006 / 16:00:42 / cg"

!

readBinaryIEEEDoubleFrom:aStream MSB:msbFirst

    "read a float from the binary stream, aStream,

     interpreting the next bytes as an IEEE formatted 8-byte float.

     The bytes are read in the specified byte order"

    |f|

    f := self basicNew.

    self readBinaryIEEEDoubleFrom:aStream into:f MSB:msbFirst.

    ^ f

    "not part of libboss, as this is also used by others (TIFFReader)"

!

readBinaryIEEEDoubleFrom:aStream into:aFloat

    "read the receiver's value from the binary stream, aStream,

     interpreting the next bytes as an IEEE formatted 8-byte float.

     The bytes are read in the native byte order (i.e.lsb on intel)"

    ^ self readBinaryIEEEDoubleFrom:aStream into:aFloat MSB:(UninterpretedBytes isBigEndian)

!

readBinaryIEEEDoubleFrom:aStream into:aFloat MSB:msb

    "read the receiver's value from the binary stream, aStream,

     interpreting the next bytes as an IEEE formatted 8-byte float.

     If msb is true, the stream bytes are most-significant-first."

    "

     this implementation is wrong: does not work on non-IEEE machines

     (to date all machines where ST/X is running on use

      IEEE float format. Will need more here, when porting ST/X to 370's)

    "

    self isIEEEFormat ifFalse:[self error:'unsupported operation'].

    (UninterpretedBytes isBigEndian == msb) ifFalse:[

	"swap the bytes"

	8 to:1 by:-1 do:[:i |

	    aFloat basicAt:i put:(aStream next)

	].

	^ self

    ].

    1 to:8 do:[:i |

	aFloat basicAt:i put:aStream next

    ]

    "not part of libboss, as this is also used by others (TIFFReader)"

    "Modified: / 23-08-2006 / 16:00:37 / cg"

!

storeBinaryIEEEDouble:aFloat on:aStream

    "store aFloat as an IEEE formatted 8-byte float

     onto the binary stream, aStream.

     The bytes are written in the native byte order (i.e.lsb on intel)"

    self storeBinaryIEEEDouble:aFloat on:aStream MSB:(UninterpretedBytes isBigEndian)

!

storeBinaryIEEEDouble:aFloat on:aStream MSB:msb

    "store aFloat as an IEEE formatted 8-byte float

     onto the binary stream, aStream.

     If msb is true, the stream bytes are written most-significant-first."