"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

ExternalStream subclass:#FileStream

	instanceVariableNames:'pathName canPosition removeOnClose'

	classVariableNames:'UserInitiatedFileSaveQuerySignal'

	poolDictionaries:''

	category:'Streams-External'

!

!FileStream primitiveDefinitions!

%{

#include "stxOSDefs.h"

#undef String

#undef Character

#include <stdio.h>

#define _STDIO_H_INCLUDED_

#include <errno.h>

#define _ERRNO_H_INCLUDED_

#ifdef transputer

# include <iocntrl.h>

# ifndef fileno

   /* kludge: inmos forgot fileno */

#  define fileno(f)     ((f)->__file)

# endif

#else /* not transputer */

# include <sys/types.h>

# include <sys/stat.h>

#endif /* not transputer */

#ifdef hpux

# define fileno(f)      ((f->__fileH << 8) | (f->__fileL))

#endif

#ifdef __VMS__

# include <rms.h>

#endif

#define String  __STX_String

#define Character __STX_Character

#ifdef WIN32

# define NO_STDIO

# ifdef __i386__

#  define _X86_

# endif

# undef INT

# undef UINT

# undef Array

# undef Number

# undef Method

# undef Point

# undef Rectangle

# undef Block

# undef Time

# undef Date

# undef Set

# undef Signal

# undef Delay

# undef Context

# undef Message

# undef Process

# undef Processor

# undef String

# undef Character

# define NOATOM

# define NOGDICAPMASKS

# define NOMETAFILE

# define NOMINMAX

//# define NOOPENFILE

# define NOSOUND

# define NOWH

//# define NOCOMM

# define NOKANJI

# define NOCRYPT

//# define NOMCX

# define WIN32_LEAN_AND_MEAN

# include <windows.h>

# if 1 // defined(__MINGW64__)

#  include <fcntl.h>

# endif

# if defined(__BORLANDC__)

#  include <io.h>

# else

#  define lseek _lseek

# endif

# ifdef __DEF_Array

#  define Array __DEF_Array

# endif

# ifdef __DEF_Number

#  define Number __DEF_Number

# endif

# ifdef __DEF_Method

#  define Method __DEF_Method

# endif

# ifdef __DEF_Point

#  define Point __DEF_Point

# endif

# ifdef __DEF_Block

#  define Block __DEF_Block

# endif

# ifdef __DEF_Time

#  define Time __DEF_Time

# endif

# ifdef __DEF_Date

#  define Date __DEF_Date

# endif

# ifdef __DEF_Set

#  define Set __DEF_Set

# endif

# ifdef __DEF_Signal

#  define Signal __DEF_Signal

# endif

# ifdef __DEF_Delay

#  define Delay __DEF_Delay

# endif

# ifdef __DEF_Context

#  define Context __DEF_Context

# endif

# ifdef __DEF_Message

#  define Message __DEF_Message

# endif

# ifdef __DEF_Process

#  define Process __DEF_Process

# endif

# ifdef __DEF_Processor

#  define Processor __DEF_Processor

# endif

# ifdef __DEF_String

#  define String __DEF_String

# endif

# ifdef __DEF_Character

#  define Character __DEF_Character

# endif

# define INT  STX_INT

# define UINT STX_UINT

# if 0

# ifndef DO_WRAP_CALLS

#  define STX_C_CALL0(__nm__, __f__)                            __f__((__a1__))

#  define STX_C_CALL1(__nm__, __f__, __a1__)                    __f__((__a1__))

#  define STX_C_CALL2(__nm__, __f__, __a1__, __a2__)            __f__((__a1__), (__a2__))

#  define STX_C_CALL3(__nm__, __f__, __a1__, __a2__, __a3__)    __f__((__a1__), (__a2__), (__a3__))

# else

#  define STX_C_CALL0(__nm__, __f__)                            __STX_C_CALL0(__nm__, (void*)__f__)

#  define STX_C_CALL1(__nm__, __f__, __a1__)                    __STX_C_CALL1(__nm__, (void*)__f__, (void*)(__a1__))

#  define STX_C_CALL2(__nm__, __f__, __a1__, __a2__)            __STX_C_CALL2(__nm__, (void*)__f__, (void*)(__a1__), (void*)(__a2__))

#  define STX_C_CALL3(__nm__, __f__, __a1__, __a2__, __a3__)    __STX_C_CALL3(__nm__, (void*)__f__, (void*)(__a1__), (void*)(__a2__), (void*)(__a3__))

# endif

# endif

/* #  define HFILE HANDLE */

#  define HFILE FILE *

/* #  define fileno(f) f */

#else /* not WIN32 */

# define HFILE FILE *

#endif /* ! WIN32 */

//#define DO_WRAP_CALL_FSEEK

#include "stxOSDefs.h"

#ifndef SEEK_SET

# define SEEK_SET       0

#endif

#ifndef SEEK_CUR

# define SEEK_CUR       1

#endif

#ifndef SEEK_END

# define SEEK_END       2

#endif

%}

! !

!FileStream class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class provides access to the operating systems underlying file

    system (i.e. its an interface to the stdio library).

    Notice, that on some systems, the standard I/O library has performance

    problems when a file is opened for readwrite.

    For best results, open files either readonly or writeonly.

    Also notice, that some OperatingSystems do not fully support

    positioning a file stream.

    For example, poor VMS does not allow positioning onto arbitrary

    byte boundaries if the file is a variable-record-RMS file.

    (stupid enough, this is the default for textfiles as created by some tools ...)

    Therefore, the instance variable canPosition is set according to

    this and an error is raised, if a position: is attemted.

    I know, this is ugly, but what else could we do ?

    Late note: who cares for VMS these days?

               (and how much useless effort has been put in the past,

                to support lousy operating systems?)

    [instance variables:]

        pathName        <String>        the file's path (if known)

        canPosition     <Boolean>       positionable - read above comment

    [author:]

        Claus Gittinger

    [see also:]

        Filename DirectoryStream PipeStream Socket

"

!

examples

"

  for VMS users only:

    The #openWithMode:attributes: entry allows additional RMS attributes

    to be passed in the second argument, which must be an array of strings

    as described in the 'creat' RTL Library documentation.

    For example, to create a file with fixed records and recordLength of 100,

    use:

	|newFile|

	newFile := FileStream new pathName:'<nameOfFile>'.

	newFile setMode:#writeonly.

	newFile openWithMode:'w' attributes:#('rfm=fix' 'fsz=100').

    since all of the above is private protocol, and it is considered bad style to

    access these from user programs, we recommend subclassing FileStream as

    something like VMSFixedRecordFileStream, and redefine the instance creation

    method(s) there as appropriate.

    This will retain VMS specifics in one place and enhance maintanability.

"

! !

!FileStream class methodsFor:'initialization'!

initialize

    UserInitiatedFileSaveQuerySignal isNil ifTrue:[

	"/

	"/ this is temporary - for now allow an openError to

	"/ be unhandled and proceed by returning a nil from the

	"/ stream creation method.

	"/ In the future, this will be a hard signal.

	"/ THE FUTURE IS NOW!!!!

	"/

"/        OpenErrorSignal := QuerySignal new.

"/        OpenErrorSignal parent:(super openErrorSignal) mayProceed:true.

"/        OpenErrorSignal nameClass:self message:#openErrorSignal.

"/        OpenErrorSignal notifierString:'open error'.

	UserInitiatedFileSaveQuerySignal := QuerySignal new defaultAnswer:true.

	UserInitiatedFileSaveQuerySignal nameClass:self message:#userInitiatedFileSaveQuerySignal.

    ]

    "Modified: 8.10.1997 / 11:56:39 / cg"

! !

!FileStream class methodsFor:'instance creation'!

appendingOldFileNamed:filename

    "return a FileStream for existing file named filename, aString.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename.

    ^ newStream openForAppending.

    "

     FileStream appendingOldFileNamed:'adasdasasd'

    "

!

appendingOldFileNamed:filename in:aDirectory

    "return a FileStream for existing file named filename, aString

     in aDirectory, a FileDirectory.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    ^ newStream openForAppending.

!

fileNamed:filename

    "return a stream on file filename - if the file does not

     already exist, create it.

     The file is opened for read/write access."

    [

	^ self oldFileNamed:filename.

    ] on:self openErrorSignal do:[:ex| ].

    ^ self newFileNamed:filename

!

fileNamed:filename in:aDirectory

    "return a stream on file filename - if the file does not

     already exist, create it.

     The file is opened for read/write access."

    [

	^ self oldFileNamed:filename in:aDirectory.

    ] on:self openErrorSignal do:[:ex| ].

    ^ self newFileNamed:filename in:aDirectory

!

newFileForWritingNamed:filename

    "return a FileStream for new file named filename, aString.

     If the file exists, it is truncated, otherwise created.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename.

    ^ newStream createForWriting.

!

newFileForWritingNamed:filename in:aDirectory

    "return a FileStream for new file named filename, aString

     in aDirectory, a FileDirectory.

     If the file exists, it is truncated, otherwise created.

     The file is opened for writeonly access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    ^ newStream createForWriting.

!

newFileNamed:filename

    "return a FileStream for new file named filename, aString.

     If the file exists, it is truncated, otherwise created.

     The file is opened for read/write access."

    |newStream|

    newStream := self new pathName:filename.

    ^ newStream createForReadWrite.

    "Modified: / 28.10.1997 / 14:28:08 / cg"

!

newFileNamed:filename in:aDirectory

    "return a FileStream for new file named filename, aString

     in aDirectory, a FileDirectory.

     If the file exists, it is truncated, otherwise created.

     The file is opened for read/write access."

    |newStream|

    newStream := self new pathName:filename in:aDirectory.

    ^ newStream createForReadWrite.

!

newTemporary

    "create atomically a new file and return the file stream - use this for temporary files.

     The created file has the name '/tmp/stxtmp_xx_nn' where xx is our

     unix process id, and nn is a unique number, incremented with every call to this method.

     If any of the environment variables ST_TMPDIR or TMPDIR is set,

     its value defines the temp directory."

    ^ self newTemporaryIn:Filename tempDirectory

    "

     FileStream newTemporary

     FileStream newTemporary

    "

!

newTemporaryIn:aDirectoryOrNil

    "create atomically a new file and return the file stream - use this for temporary files.

     The created file is in aDirectoryPrefix and named 'stxtmp_xx_nn',

     where xx is our unix process id, and nn is a unique number, incremented

     with every call to this method."

    ^ self newTemporaryIn:aDirectoryOrNil nameTemplate:Filename tempFileNameTemplate

    "temp files in '/tmp':

     FileStream newTemporary

    "

    "temp files somewhere

     (not recommended - use above since it can be controlled via shell variables):

     FileStream newTemporaryIn:'/tmp'

     FileStream newTemporaryIn:'/tmp'

     FileStream newTemporaryIn:'/usr/tmp'

     FileStream newTemporaryIn:'/'

    "

    "a local temp file:

     FileStream newTemporaryIn:''

     FileStream newTemporaryIn:nil

     FileStream newTemporaryIn:'.'

     FileStream newTemporaryIn:('source' asFilename)

    "

!

newTemporaryIn:aDirectoryOrNil nameTemplate:template

    "create atomically a new file and return the file stream - use this for temporary files.

     The created file is in aDirectoryOrNil and named after the given template,

     in which %1 and %2 are expanded to the unix process id, and a unique number, incremented

     with every call to this method respectively.

     See also: #newTemporary which looks for a good temp directory."

    |nameString random prevRandom prevNameString newTempFilename stream|

    [

        prevRandom := random.

        prevNameString := nameString.

        "Use random numbers in order to improve the security

         by making the generated names less predictable"

        [

            random := RandomGenerator new nextInteger.

        ] doWhile:[random = prevRandom].

        nameString := template bindWith:(OperatingSystem getProcessId) with:random.

        aDirectoryOrNil isNil ifTrue:[

            newTempFilename := nameString.

        ] ifFalse:[

            newTempFilename := aDirectoryOrNil asFilename constructString:nameString.

        ].

        [

            stream := self open:newTempFilename withMode:#(CREATE_NEW GENERIC_READ_WRITE).

        ] on:OpenError do:[:ex|

           ex errorCategory ~~ #existingReferentSignal ifTrue:[

                "some fundamental error, raise exception"

                ex reject.

            ].

            prevNameString = nameString ifTrue:[

                "no more names - probably a bad template"

                ex reject.

            ].

            "file exists, retry another one"

        ].

    ] doWhile:[

        stream isNil and:[prevNameString ~= nameString]   "/ if namestring didn't change, the template is bad

    ].

    ^ stream