"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 2012-2014 by Jan Vrany & eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

Object subclass:#MiniLogger

	instanceVariableNames:''

	classVariableNames:'ALL DEBUG ENTER ERROR FATAL INFO Instance LEAVE NONE Severities

		TRACE TRACE0 TRACE1 TRACE2 TRACE3 Threshold WARN WARNING

		LogOnTranscript LogOnStderr LogFormat TimestampFormat'

	poolDictionaries:''

	category:'System-Debugging-Support'

!

Magnitude subclass:#Severity

	instanceVariableNames:'name value'

	classVariableNames:''

	poolDictionaries:''

	privateIn:MiniLogger

!

!MiniLogger class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2012-2014 by Jan Vrany & eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"   

    A very simple logger for Smalltalk/X. This one is always present.

    It mimics the protocol of the loggers found in stx:goodies/loggia,

    which can be activated by setting the global 'Logger' to an instance of

    one of them.

    All 

        'Transcript show: 'Processor [info]: xxx' 

    should be rewritten over time to use the Logger.

    'Object infoPrint' and 'Object debugPrint' have been changed to

    forward their message to the global 'Logger' if not nil.

    Usage:

        Logger info: 'Hello world'.

        Logger debug: 'Hello world'.

        Logger warning: 'Hello world'.

        Logger error: 'Hello world'.

    to disable logging:

        MiniLogger logOnTranscript:false.

        MiniLogger logOnStderr:false.

    for selective logging:

        Logger loggingThreshold: Logger severityALL.

        Logger loggingThreshold: Logger severityINFO.

        Logger loggingThreshold: Logger severityNONE.

    For more examples, see #examples.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

        Loggia logging framrwork (stx:goodies/loggia)

"

!

examples

"   

    Simple logging (make sure logging threshold is lower or equal then

    Logger severityDEBUG, see #loggingThreshold:)

                                                                        [exBegin]    

        Logger debug: 'Hello world!!'

                                                                        [exEnd]

    You may use #<severity>:with:with: utility to format log message:

                                                                        [exBegin]    

        | hostname port |

        hostname := 'www.google.com'.

        port := 80.

        Logger error: 'Cannot connect to %1 port %2' with: hostname with: port

                                                                        [exEnd]

    When a log message is costly to construct, you may pass a block returning

    the message instead of string. Then the log message creation os deferred until

    really needed (i.e., if the severity is not logged, block is not evaluated.

    Useful for trace messages (severities DEBUG and TRACE?):

                                                                        [exBegin]    

        | hostname port |

        hostname := 'www.google.com'.

        Logger trace: [ 'Connecting to %1' bindWith: (IPSocketAddress hostName:hostname) address ]

                                                                        [exEnd]

"

! !

!MiniLogger class methodsFor:'initialization'!

initialize

    LogOnStderr := true.

    LogOnTranscript := true.

    ALL := Severity new initializeWithName:#all value:0.

    ENTER := Severity new initializeWithName:#enter value:10.

    LEAVE := Severity new initializeWithName:#leave value:10.

    TRACE3 := Severity new initializeWithName:#trace3 value:20.

    TRACE2 := Severity new initializeWithName:#trace2 value:30.

    TRACE1 := Severity new initializeWithName:#trace1 value:40.

    TRACE0 := Severity new initializeWithName:#trace0 value:50.

    TRACE := Severity new initializeWithName:#trace value:50.

    DEBUG := Severity new initializeWithName:#debug value:60.

    INFO := Severity new initializeWithName:#info value:70.

    WARN := Severity new initializeWithName:#warn value:88.

    WARNING := Severity new initializeWithName:#warning value:88.

    ERROR := Severity new initializeWithName:#error value:99.

    FATAL := Severity new initializeWithName:#fatal value:100.

    NONE := Severity new initializeWithName:#none value:65535.

    Severities := {ENTER. LEAVE. TRACE3. TRACE2. TRACE1. TRACE0. TRACE. DEBUG. INFO. WARN. WARNING. ERROR. FATAL.}.

    Threshold := InfoPrinting ifTrue:[INFO] ifFalse:[WARN].

    (Smalltalk at:#Logger) isNil ifTrue:[

        Smalltalk at:#Logger put:self

    ].

    "Modified: / 13-08-2014 / 14:36:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!MiniLogger class methodsFor:'accessing-log format'!

logFormat

    "will be used for the log message as:

        %1 [%2] (%3): %4

    with %1: facility (area)

    with %2: secerity (area)

    with %3: timestamp 

    with %4: caller/originator 

    with %5: message"

    ^ LogFormat ? '%1 [%2] (%3): %5'

    "

     MiniLogger logFormat:'%1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:'%3 %1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:nil.

     'hello' errorPrintCR.

    "

!

logFormat:aFormatString

    "will be used for the log message as:

        %1 [%2] (%3): %4

            with %1: facility (area)

            with %2: secerity (area)

            with %3: timestamp 

            with %4: caller/originator 

            with %5: message.

     Pass anil argument to return to the default format.        

    "

    LogFormat := aFormatString

    "

     MiniLogger logFormat:'%1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:'%3 %1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:nil.

     'hello' errorPrintCR.

    "

!

logOnStderr 

    ^ LogOnStderr

!

logOnStderr:aBoolean

    "enable/disable loggin on stderr"

    LogOnStderr := aBoolean

    "

     MiniLogger logOnStderr:false

     MiniLogger logOnTranscript:false

     MiniLogger logOnStderr:true

     MiniLogger logOnTranscript:true

    "

!

logOnTranscript

    ^ LogOnTranscript 

!

logOnTranscript:aBoolean

    "enable/disable loggin on the Transcript"

    LogOnTranscript := aBoolean

    "

     MiniLogger logOnStderr:false

     MiniLogger logOnTranscript:false

     MiniLogger logOnStderr:true

     MiniLogger logOnTranscript:true

    "

!

timestampFormat

    "will be used for the log message"

    ^ TimestampFormat ? '%(year)-%(mon)-%(day) %h:%m:%s.%i'.

!

timestampFormat:aTimestampFormatString

    "will be used for the log message"

    TimestampFormat := aTimestampFormatString

! !

!MiniLogger class methodsFor:'accessing-severities'!

severities

    ^ Severities.

!

severityDEBUG

    ^ DEBUG

    "Created: / 13-08-2014 / 14:15:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityENTER

    ^ ENTER

    "Created: / 13-08-2014 / 14:14:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityERROR

    ^ ERROR

    "Created: / 13-08-2014 / 14:15:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityFATAL

    ^ FATAL

    "Created: / 13-08-2014 / 14:15:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityINFO

    ^ INFO

    "Created: / 13-08-2014 / 14:15:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityLEAVE

    ^ LEAVE

    "Created: / 13-08-2014 / 14:14:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityTRACE

    ^ TRACE

    "Created: / 13-08-2014 / 14:15:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityTRACE0

    ^ TRACE0

    "Created: / 13-08-2014 / 14:14:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityTRACE1

    ^ TRACE1

    "Created: / 13-08-2014 / 14:14:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityTRACE2

    ^ TRACE2

    "Created: / 13-08-2014 / 14:14:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityTRACE3

    ^ TRACE3

    "Created: / 13-08-2014 / 14:14:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityWARN

    ^ WARN

    "Created: / 13-08-2014 / 14:15:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!MiniLogger class methodsFor:'accessing-severities-special'!

severityALL

    ^ ALL

    "Created: / 13-08-2014 / 14:14:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

severityNONE

    ^ NONE

    "Created: / 13-08-2014 / 14:15:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!MiniLogger class methodsFor:'configuration'!

loggingThreshold

    "Return the logging threshold. No messages with severity lower than 

     threshold will be logged."

    ^ Threshold

    "Created: / 13-08-2014 / 14:36:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

loggingThreshold:severity 

    "Sets logging threshold. No severity lower than given one will be logged.

     Use `Logger severityNONE` to suppress logging completely or

     `Logger severityALL` to log all messages"

    ((Severities includes:severity) 

        or:[ severity == ALL or:[ severity == NONE ] ]) 

            ifFalse:[

                self error:'Invalid severity. Use of Logger severityXXX'.

                ^ self.

            ].

    Threshold := severity

    "

    Logger loggingThreshold: Logger severityALL.

    Logger loggingThreshold: Logger severityINFO.

    Logger loggingThreshold: Logger severityNONE.

    "

    "Created: / 13-08-2014 / 14:34:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 26-08-2014 / 08:23:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 09-10-2014 / 09:35:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!MiniLogger class methodsFor:'logging'!

log: message

    self log: message severity: DEBUG originator: thisContext sender receiver.

    "Created: / 15-09-2011 / 10:27:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-12-2014 / 10:52:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message facility: facility

    self log: message severity: DEBUG facility: facility originator: thisContext sender receiver

    "Created: / 14-09-2011 / 21:22:27 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-12-2014 / 10:53:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message severity: severity

    self log: message severity: severity originator: thisContext sender receiver

    "Created: / 15-09-2011 / 10:25:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-12-2014 / 10:53:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message severity: severity attachment: attachment

    | originator |

    originator := thisContext sender receiver.

    self log: message severity: severity facility: (self facilityOf: originator) originator: originator attachment: attachment

    "Created: / 15-09-2011 / 11:47:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 15-03-2013 / 11:20:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 26-08-2014 / 08:23:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message severity: severity facility: facility

    self log: message severity: severity facility: facility originator: thisContext sender receiver

    "Created: / 14-09-2011 / 21:20:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message severity: severity facility: facility originator: originator

    self log: message severity: severity facility: facility originator: originator attachment: nil

    "Created: / 14-09-2011 / 21:20:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

log: message severity: severity facility: facility originator: originator attachment: attachment

    "Pricipal logging method. This mimics VM __stxLog__()"

    | severityXlated messageXlated logOnStderr logOnTranscript prevLogOnTranscript |

    logOnStderr := self logOnStderr.

    logOnTranscript := self logOnTranscript and:[Transcript isView].

    (logOnStderr or:[logOnTranscript]) ifFalse:[^ self].

    severityXlated := severity.

    "/ Be backward compatible, allow for symbolic severities

    "/ but when encountered, issue a warning...

    severity isSymbol ifTrue:[

        severityXlated := Severities detect:[:each| each name == severity] ifNone:[].

        "/ This will be enabled later, so far it generates

        "/ way to much warnings. at least stx:libjava & exept:jdi has to be rewritten

        "/ self log: 'using symbols as severity is deprecated, use Logger severityXXX to get severity object' severity: WARN facility: 'STX' originator: self.

        "/ caller := thisContext sender.

        "/ [ caller notNil and: [ caller receiver ~~ originator ] ] whileTrue:[ caller := caller sender ].

        "/ self log: 'caller is ', caller printString severity: INFO facility: 'STX' originator: self.

    ].

    "/ Now check whether the severity is one of the predefined ones,

    "/ if not, issue an error

    (Severities includesIdentical: severityXlated) ifFalse:[ 

        | caller |

        caller := thisContext sender.

        [caller notNil and:[caller receiver ~~ originator]] whileTrue:[ 

            caller := caller sender

        ].

        self log:('no such severity (%1, called from %2), use one from predefined severities. Original message will be logged as INFO' bindWith:severityXlated with:caller) 

             severity: ERROR facility: 'STX' originator: self.

        severityXlated := INFO.

    ].

    severityXlated < Threshold ifTrue:[ ^ self ].

    messageXlated := message value asString.

    "/ to avoid recursion, turn off logOnTranscript while logging

    "/ had this problem with RecursionLock, which wanted to issue a warning

    "/ ("cleanup for dead process") from inside Transcript code.

    [

        prevLogOnTranscript := LogOnTranscript.

        LogOnTranscript := false.

        logOnStderr ifTrue:[

            self log:messageXlated severity:severityXlated facility:facility 

                 originator:originator attachment:attachment on:Stderr.

        ].

        logOnTranscript ifTrue:[

            Transcript nextPutLine:messageXlated.

        ].

    ] ensure:[

        LogOnTranscript := prevLogOnTranscript.

    ].

    "

     Logger log:'test message' severity:self severityINFO facility: 'TEST'

     Logger log:'test message' severity:#info facility: 'TEST'

     Logger log:'test message' severity:#bla facility: 'TEST'

     Logger log:'test message' severity:123 facility: 'TEST'

    "