"
COPYRIGHT (c) 1988 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
"{ Package: 'stx:libbasic' }"
nil subclass:#Object
instanceVariableNames:''
classVariableNames:'ErrorSignal HaltSignal MessageNotUnderstoodSignal
UserInterruptSignal RecursionInterruptSignal
ExceptionInterruptSignal SubscriptOutOfBoundsSignal
IndexNotFoundSignal NonIntegerIndexSignal NotFoundSignal
KeyNotFoundSignal ElementOutOfBoundsSignal UserNotificationSignal
InformationSignal WarningSignal PrimitiveFailureSignal
DeepCopyErrorSignal AbortSignal ErrorRecursion Dependencies
InfoPrinting ActivityNotificationSignal InternalErrorSignal
NonWeakDependencies SynchronizationSemaphores ObjectAttributes
OSSignalInterruptSignal FinalizationLobby
RecursiveStoreStringSignal AbortAllSignal'
poolDictionaries:''
category:'Kernel-Objects'
!
!Object class methodsFor:'documentation'!
copyright
"
COPYRIGHT (c) 1988 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
!
dependencies
"
ST/X dependencies are slightly modified from ST-80's
(we think they are better ;-).
One problem occuring very often in ST-80 is that some object
cannot be garbage collected because some dependency is present,
having the object as a dependent of some other object.
In ST-80, this association remains alive (because a Dictionary
is used to hold dependents) - even if no other references exist to
to dependent or the dependee.
This means, that in ST-80, a #release is mandatory in order to
prevent memory leaks.
We think, that this is a bad solution, since after all, exactly that
kind of work should be performed by a garbage collector - you should not
need to care about dependencies.
From a philosophical point of view, why should some object depend on
something that the programmer considers a dead object ?
(well - worse than that: it seems that some ST-80 code even depends on
that behavior)
In order to limit the trouble, ST-80 reimplemented the way dependents
are stored in the model class - this one keeps the dependents locally,
so these dependents go away, once the model is reclaimed.
That may make things even more confusing: with models, no #release is
needed, with general objects it is mandatory.
In ST/X, dependencies are implemented using a WeakDictionary; this means,
that once the dependee dies, the dependency association is removed automatically,
and the dependent can be reclaimed by the garbage collector, if no other
references exist to the dependent.
In order to (at least) provide a mechanism for the old behavior
(in case your application heavily depends on the ST-80 mechanism), complementary
protocol to add nonWeak dependencies is provided
(see #addNonWeakDependent / #removeNonWeakDependent).
Caveat:
since interests are implemented using InterestConverter (which are simply
forwarding messages), these must use the nonWeak mechanism (as done in ST-80
automatically).
The reason is that there are usually no direct references to the converters,
and those would be reclaimed if stored in a weakDictionary.
This means, that those interests MUST be removed with #retractInterest
(which is bug-compatible to ST-80).
We rewrite things to provide a more convenient mechanism in the future ...
I like to hear comments on the above - do you think its better ?
"
!
documentation
"
Object is the superclass of most other classes.
(except for nil-subclasses, which inherit nothing,
to catch any message into their #doesNotUnderstand: method)
Protocol which is common to every object is defined here.
Also some utility stuff (like notify) and error handling is implemented here.
Object has no instance variables (and may not get any added). One reason is, that
UndefinedObject and SmallInteger are also inheriting from Object - these two cannot
have instance variables (due to their implementation).
The other reason is that the runtime system (VM) knows about the layout of some built-in
classes (think of Class, Method, Block and also Integer or Float).
If you were allowed to add instance variables to Object, the VM had to be recompiled
(and also rewritten in some places).
[Class variables:]
ErrorSignal <Signal> Signal raised for error/error: messages
also, parent of all other signals.
HaltSignal <Signal> Signal raised for halt/halt: messages
MessageNotUnderstoodSignal Signals raised for various error conditions
UserInterruptSignal
RecursionInterruptSignal
ExceptionInterruptSignal
SubscriptOutOfBoundsSignal
NonIntegerIndexSignal
NotFoundSignal
KeyNotFoundSignal
ElementOutOfBoundsSignal
InformationSignal
WarningSignal
DeepCopyErrorSignal
InternalErrorSignal
AbortSignal <Signal> Signal raised by debugger, to abort a computation
BUT, the debugger will only raise it if it is handled.
By handling the abortSignal, you can control where the
debuggers abort-function resumes execution in case of
an error.
ErrorRecursion <Boolean> controls behavior when recursive errors occur (i.e.
an error while handling an error).
Dependencies <WeakDependencyDictionary>
keeps track of object dependencies.
InfoPrinting <Boolean> controls weather informational messages
are printed.
ActivityNotificationSignal <QuerySignal>
raised on #activityNotification:
NonWeakDependencies <Dictionary> keeps track of object dependencies.
Dependents stay alive.
SynchronizationSemaphores <WeakIdentityDictionary>
Semaphores for per-object-monitor.
[author:]
Claus Gittinger
"
! !
!Object class methodsFor:'initialization'!
initSignals
"called only once - initialize signals"
ErrorSignal := Error.
ControlInterrupt notifierString:'control interrupted'.
"/ HaltSignal := ControlInterrupt newSignalMayProceed:true.
"/ HaltSignal nameClass:self message:#haltSignal.
HaltSignal := HaltInterrupt.
HaltSignal notifierString:'halt encountered'.
"/ MessageNotUnderstoodSignal := ErrorSignal newSignalMayProceed:true.
"/ MessageNotUnderstoodSignal nameClass:self message:#messageNotUnderstoodSignal.
MessageNotUnderstoodSignal := MessageNotUnderstood.
MessageNotUnderstoodSignal notifierString:'message not understood'.
"/ PrimitiveFailureSignal := ErrorSignal newSignalMayProceed:true.
"/ PrimitiveFailureSignal nameClass:self message:#primitiveFailureSignal.
PrimitiveFailureSignal := PrimitiveFailure.
PrimitiveFailureSignal notifierString:'primitive failed'.
InternalErrorSignal := ErrorSignal newSignalMayProceed:false.
InternalErrorSignal nameClass:self message:#internalErrorSignal.
InternalErrorSignal notifierString:'VM internal error: '.
"/ UserInterruptSignal := (Signal new) mayProceed:true.
"/ UserInterruptSignal := ControlInterrupt newSignalMayProceed:true.
"/ UserInterruptSignal nameClass:self message:#userInterruptSignal.
UserInterruptSignal := UserInterrupt.
UserInterruptSignal notifierString:'user Interrupt'.
"/ RecursionInterruptSignal := ErrorSignal newSignalMayProceed:false.
"/ RecursionInterruptSignal := (Signal new) mayProceed:true.
"/ RecursionInterruptSignal nameClass:self message:#recursionInterruptSignal.
RecursionInterruptSignal := RecursionError.
RecursionInterruptSignal notifierString:'recursion limit reached'.
ExceptionInterruptSignal := ErrorSignal newSignalMayProceed:true.
ExceptionInterruptSignal nameClass:self message:#exceptionInterruptSignal.
ExceptionInterruptSignal notifierString:'exception Interrupt'.
"/ NotFoundSignal := ErrorSignal newSignalMayProceed:true.
"/ NotFoundSignal nameClass:self message:#notFoundSignal.
NotFoundSignal := NotFoundError.
NotFoundSignal notifierString:'no such element'.
"/ IndexNotFoundSignal := NotFoundSignal newSignalMayProceed:true.
"/ IndexNotFoundSignal nameClass:self message:#indexNotFoundSignal.
IndexNotFoundSignal := IndexNotFoundError.
IndexNotFoundSignal notifierString:'bad index: '.
"/ SubscriptOutOfBoundsSignal := IndexNotFoundSignal newSignalMayProceed:true.
"/ SubscriptOutOfBoundsSignal nameClass:self message:#subscriptOutOfBoundsSignal.
SubscriptOutOfBoundsSignal := SubscriptOutOfBoundsError.
SubscriptOutOfBoundsSignal notifierString:'subscript out of bounds: '.
"/ NonIntegerIndexSignal := IndexNotFoundSignal newSignalMayProceed:true.
"/ NonIntegerIndexSignal nameClass:self message:#nonIntegerIndexSignal.
NonIntegerIndexSignal := NonIntegerIndexError.
NonIntegerIndexSignal notifierString:'index must be integer'.
KeyNotFoundSignal := NotFoundSignal newSignalMayProceed:true.
KeyNotFoundSignal nameClass:self message:#keyNotFoundSignal.
KeyNotFoundSignal notifierString:'no such key: '.
ElementOutOfBoundsSignal := ErrorSignal newSignalMayProceed:false.
ElementOutOfBoundsSignal nameClass:self message:#elementOutOfBoundsSignal.
ElementOutOfBoundsSignal notifierString:'element not appropriate or out of bounds'.
UserNotificationSignal := QuerySignal new.
UserNotificationSignal nameClass:self message:#userNotificationSignal.
UserNotificationSignal notifierString:'user notifiaction wanted'.
InformationSignal := UserNotificationSignal newSignalMayProceed:true.
InformationSignal nameClass:self message:#informationSignal.
InformationSignal notifierString:'information'.
WarningSignal := UserNotificationSignal newSignalMayProceed:true.
WarningSignal nameClass:self message:#warningSignal.
WarningSignal notifierString:'warning'.
ActivityNotificationSignal := UserNotificationSignal newSignalMayProceed:true.
ActivityNotificationSignal nameClass:self message:#activityNotificationSignal.
ActivityNotificationSignal notifierString:'activity'.
DeepCopyErrorSignal := ErrorSignal newSignalMayProceed:true.
DeepCopyErrorSignal nameClass:self message:#deepCopyErrorSignal.
DeepCopyErrorSignal notifierString:'object cannot be deepCopy-ed'.
"
AbortSignal is not a child of ErrorSignal -
this would complicate abort from within a signal handler
"
"/ AbortSignal := Signal genericSignal newSignalMayProceed:true.
"/ AbortSignal nameClass:self message:#abortSignal.
AbortSignal := AbortOperationRequest.
AbortSignal notifierString:'unhandled abort signal'.
"/ AbortAllSignal := Signal genericSignal newSignalMayProceed:true.
"/ AbortAllSignal nameClass:self message:#abortAllSignal.
AbortAllSignal := AbortAllOperationRequest.
AbortAllSignal notifierString:'unhandled abortAll signal'.
"
OSSignalInterruptSignal is not a child of ErrorSignal -
it requires explicit catching.
If unhandled, a debugger is entered.
"
OSSignalInterruptSignal := Signal genericSignal newSignalMayProceed:true.
OSSignalInterruptSignal nameClass:self message:#osSignalInterruptSignal.
OSSignalInterruptSignal notifierString:'OS signal interrupt'.
RecursiveStoreStringSignal := QuerySignal new.
RecursiveStoreStringSignal nameClass:self message:#recursiveStoreStringSignal.
RecursiveStoreStringSignal notifierString:'attempt to generate storeString of recursive object'.
SubclassResponsibilityError notifierString:'subclass responsibility'.
"
Object initSignals
"
"Modified: / 22.1.1998 / 21:23:40 / av"
"Modified: / 4.8.1999 / 08:54:06 / stefan"
"Modified: / 16.11.2001 / 16:30:08 / cg"
!
initialize
"called only once - initialize signals"
ErrorSignal isNil ifTrue:[
self initSignals
].
ObjectAttributes isNil ifTrue:[
ObjectAttributes := WeakIdentityDictionary new.
].
Dependencies isNil ifTrue:[
Dependencies := WeakDependencyDictionary new.
].
NonWeakDependencies isNil ifTrue:[
NonWeakDependencies := IdentityDictionary new.
].
SynchronizationSemaphores isNil ifTrue:[
SynchronizationSemaphores := WeakIdentityDictionary new.
].
FinalizationLobby isNil ifTrue:[
FinalizationLobby := Registry new.
].
"/ initialize InfoPrinting to the VM's infoPrint setting
"/ (which can be turned off via a command line argument)
InfoPrinting := ObjectMemory infoPrinting.
"Object initialize"
"Modified: / 22.1.1998 / 21:23:40 / av"
"Modified: / 3.2.1998 / 18:55:09 / cg"
"Modified: / 4.8.1999 / 08:54:06 / stefan"
! !
!Object class methodsFor:'Compatibility - ST80'!
rootError
"return the signal used for error/error: - handling.
Same as errorSignal for ST80 compatibility."
^ ErrorSignal
"Created: / 15.1.1998 / 23:47:05 / stefan"
! !
!Object class methodsFor:'Signal constants'!
abortAllSignal
"return the signal used to abort user actions (much like AbortSignal).
This signal is supposed to abort multiple operation actions, and get out of
the loop (such as when confirming multiple class deletions etc.)"
^ AbortAllSignal
!
abortSignal
"return the signal used to abort user actions. This signal is only
raised if caught (by the debugger), and will lead way out of the
currently active doIt/printIt or inspectIt. (also some others use
this for a save abort)"
^ AbortSignal
!
activityNotificationSignal
"return the signal used for activity notifications.
A handler for this signal gets all #activityNotification: sends"
^ ActivityNotificationSignal
!
deepCopyErrorSignal
"return the signal raised when a deepcopy is asked for
an object which cannot do this (for example, BlockClosures
or Contexts)."
^ DeepCopyErrorSignal
!
elementOutOfBoundsSignal
"return the signal used for element error reporting
(this signal is used for example when a value not in 0..255 is to
be put into a bytearray)"
^ ElementOutOfBoundsSignal
!
errorSignal
"return the signal used for error/error: - handling"
^ ErrorSignal
!
exceptionInterruptSignal
"return the signal used for exception (display errors) error handling"
^ ExceptionInterruptSignal
!
haltSignal
"return the signal used for halt/halt: - handling"
^ HaltSignal
!
indexNotFoundSignal
"return the signal used for bad index error reporting.
This is also the parentSignal of the nonIntegerIndex- and
subscriptOutOfBoundsSignal"
^ IndexNotFoundSignal
"Created: / 8.11.1997 / 19:15:48 / cg"
!
informationSignal
"return the signal used for informations.
A handler for this signal gets all #information: sends"
^ InformationSignal
!
internalErrorSignal
"return the signal used to report internal (VM-) errors."
^ InternalErrorSignal
!
keyNotFoundSignal
"return the signal used for no such key error reporting"
^ KeyNotFoundSignal
!
messageNotUnderstoodSignal
"return the signal used for doesNotUnderstand: - error handling"
^ MessageNotUnderstoodSignal
!
nonIntegerIndexSignal
"return the signal used for bad subscript error reporting"
^ NonIntegerIndexSignal
!
notFoundSignal
"return the signal used for no element found error reporting"
^ NotFoundSignal
!
osSignalInterruptSignal
"return the signal used for OS-signal error reporting;
This is only raised if handled - otherwise, a debugger is entered."
^ OSSignalInterruptSignal
"Modified: / 12.6.1998 / 16:27:26 / cg"
!
primitiveFailureSignal
"return the signal used for primitiveFailed - error handling"
^ PrimitiveFailureSignal
!
privateMethodSignal
"return the signal used for privateMethod - error handling"
^ MessageNotUnderstoodSignal
!
recursionInterruptSignal
"return the signal used for recursion overflow error handling"
^ RecursionInterruptSignal
!
recursiveStoreStringSignal
"return the query signal used to report storeString generation of recursive objects"
^ RecursiveStoreStringSignal
"
Object recursiveStoreStringSignal handle:[:ex |
self halt
] do:[
|a|
a := Array new:1.
a at:1 put:a.
a storeOn:Transcript
]
"
"
|a|
a := Array new:1.
a at:1 put:a.
a storeOn:Transcript
"
!
subclassResponsibilitySignal
"return the signal used for subclassResponsibility error reporting.
(this signal is used to signal incomplete subclasses - i.e. a programmers error)"
^ SubclassResponsibilityError
!
subscriptOutOfBoundsSignal
"return the signal used for subscript error reporting.
(this signal is used for example when an array is accessed with an
index less than 1 or greater than the array size)"
^ SubscriptOutOfBoundsSignal
!
userInterruptSignal
"return the signal used for ^C interrupts handling"
^ UserInterruptSignal
!
userNotificationSignal
"the parent signal used with information and warnings.
Handling this allows handling of both information- and warning notifications."
^ UserNotificationSignal
!
warningSignal
"return the signal used for warnings.
A handler for this signal gets all #warn: sends"
^ WarningSignal
! !
!Object class methodsFor:'info messages'!
infoPrinting
"return the flag which controls information messages."
^ InfoPrinting
!
infoPrinting:aBoolean
"{ Pragma: +optSpace }"
"turn on/off printing of information messages.
If the argument, aBoolean is false, infoPrint will not output
messages. The default is true."
InfoPrinting := aBoolean
! !
!Object class methodsFor:'queries'!
isBuiltInClass
"return true, if this class is known by the run-time-system,
i.e. you cannot add/remove instance variables without recompiling
the VM.
Here, true is returned for myself, false for subclasses."
^ self == Object
"Modified: 23.4.1996 / 16:00:07 / cg"
! !
!Object methodsFor:'Compatibility - ST80'!
isMetaclass
^ self isMeta
!
oneWayBecome:anotherObject
^ self becomeSameAs:anotherObject
"
|arr o1 o2|
arr := Array new:2.
arr at:1 put:(o1 := Object new).
arr at:2 put:(o2 := Point new).
o1 oneWayBecome:o2.
(arr at:1) ~~ o2 ifTrue:[self halt].
"
"
|arr o1 o2|
arr := Array new:2.
arr at:1 put:(o1 := Object new).
arr at:2 put:(o2 := Point new).
o1 becomeSameAs:o2.
(arr at:1) ~~ o2 ifTrue:[self halt].
"
! !
!Object methodsFor:'Compatibility - Squeak'!
as:aSimilarClass
"If the receivers class is not aSimilarClass,
create and return an object of class aSimilarClass that has the same contents
as the receiver.
Otherwise, return the receiver."
self class == aSimilarClass ifTrue:[^ self].
^ aSimilarClass newFrom:self
"
#[1 2 3 4] as:ByteArray
#[1 2 3 4] as:Array
"
!
asString
^ self printString
!
clone
^ self shallowCopy
!
copyTwoLevel
"one more level than a shallowCopy"
^ self copyToLevel:2
"
|original copy elL1 elL2 elL3 copyOfElL1|
original := Array new:3.
original at:1 put:1234.
original at:2 put:'hello'.
original at:3 put:(elL1 := Array new:3).
elL1 at:1 put:1234.
elL1 at:2 put:'hello'.
elL1 at:3 put:(elL2 := Array new:3).
elL2 at:1 put:1234.
elL2 at:2 put:'hello'.
elL2 at:3 put:(elL3 := Array new:3).
elL3 at:1 put:1234.
elL3 at:2 put:'hello'.
elL3 at:3 put:(Array new:3).
copy := original copyTwoLevel.
(original at:2) ~~ (copy at:2) ifFalse:[self halt].
(original at:3) ~~ (copy at:3) ifFalse:[self halt].
copyOfElL1 := copy at:3.
(elL1 at:2) == (copyOfElL1 at:2) ifFalse:[self halt].
(elL1 at:3) == (copyOfElL1 at:3) ifFalse:[self halt].
"
!
currentHand
"Return a usable HandMorph -- the one associated with the object's current environment. This method will always return a hand, even if it has to conjure one up as a last resort. If a particular hand is actually handling events at the moment (such as a remote hand or a ghost hand), it will be returned."
|w h|
w := self currentWorld.
h := w activeHand.
h isNil ifTrue:[
h := w hands first
].
^ h
!
currentWorld
^ Utilities currentWorld
!
newTileMorphRepresentative
^ TileMorph new setLiteral: self
!
stringForReadout
^ self stringRepresentation
!
stringRepresentation
"Answer a string that represents the receiver. For most objects this is simply its printString, but for strings themselves, it's themselves. 6/12/96 sw"
^ self printString
!
veryDeepCopy
^(self deepCopyUsing:(IdentityDictionary new)) postDeepCopyFrom:self
! !
!Object methodsFor:'accessing'!
at:index
"return the indexed instance variable with index, anInteger;
this method can be redefined in subclasses."
^ self basicAt:index
!
at:index put:anObject
"store the 2nd arg, anObject as indexed instvar with index, anInteger.
this method can be redefined in subclasses. Returns anObject (sigh)"
^ self basicAt:index put:anObject
"Modified: 19.4.1996 / 11:13:29 / cg"
!
basicAt:index
"return the indexed instance variable with index, anInteger.
Trigger an error if the receiver has no indexed instance variables.
This method should NOT be redefined in any subclass (except with great care, for tuning)"
%{ /* NOCONTEXT */
REGISTER int nbytes, indx;
OBJ myClass;
REGISTER char *pFirst;
#ifdef alpha64
# define int32 int
#else
# define int32 long
#endif
REGISTER int n;
/*
* notice the missing test for self being a nonNilObject -
* this can be done since basicAt: is defined both in UndefinedObject
* and SmallInteger
*/
if (__isSmallInteger(index)) {
myClass = __qClass(self);
indx = __intVal(index) - 1;
n /* nInstVars */ = __intVal(__ClassInstPtr(myClass)->c_ninstvars);
n /* nInstBytes */ = OHDR_SIZE + __OBJS2BYTES__(n /* nInstVars */);
nbytes = __qSize(self) - n /* nInstBytes */;
pFirst = (char *)(__InstPtr(self)) + n /* nInstBytes */;
switch ((INT)(__ClassInstPtr(myClass)->c_flags) & __MASKSMALLINT(ARRAYMASK)) {
case __MASKSMALLINT(POINTERARRAY):
case __MASKSMALLINT(WKPOINTERARRAY):
/*
* pointers
*/
if ((unsigned)indx < (__BYTES2OBJS__(nbytes))) {
OBJ *op;
op = (OBJ *)pFirst + indx;
RETURN ( *op );
}
break;
case __MASKSMALLINT(BYTEARRAY):
/*
* (unsigned) bytes
*/
if ((unsigned)indx < nbytes) {
unsigned char *cp;
cp = (unsigned char *)pFirst + indx;
RETURN ( __MKSMALLINT( (INT)(*cp & 0xFF)) );
}
break;
case __MASKSMALLINT(FLOATARRAY):
/*
* native floats
*/
if ((unsigned)indx < (nbytes / sizeof(float))) {
float *fp;
float f;
OBJ v;
fp = (float *)pFirst + indx;
f = *fp;
if (f == 0.0) {
v = __float0;
} else {
__qMKSFLOAT(v, f);
}
RETURN (v);
}
break;
case __MASKSMALLINT(DOUBLEARRAY):
/*
* native doubles
*/
#ifdef __NEED_DOUBLE_ALIGN
if ((INT)pFirst & (__DOUBLE_ALIGN-1)) {
int delta = __DOUBLE_ALIGN - ((INT)pFirst & (__DOUBLE_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
if ((unsigned)indx < (nbytes / sizeof(double))) {
double *dp;
double d;
OBJ v;
dp = (double *)pFirst + indx;
d = *dp;
if (d == 0.0) {
v = __float0;
} else {
__qMKFLOAT(v, d);
}
RETURN (v);
}
break;
case __MASKSMALLINT(WORDARRAY):
/*
* unsigned 16bit ints
*/
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the short-size of the machine
*/
if ((unsigned)indx < (nbytes>>1)) {
unsigned short *sp;
sp = (unsigned short *)(pFirst + (indx<<1));
RETURN ( __MKSMALLINT( (INT)(*sp & 0xFFFF)) );
}
break;
case __MASKSMALLINT(SWORDARRAY):
/*
* signed 16bit ints
*/
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the short-size of the machine
*/
if ((unsigned)indx < (nbytes>>1)) {
short *ssp;
ssp = (short *)(pFirst + (indx<<1));
RETURN ( __MKSMALLINT( (INT)(*ssp) ));
}
break;
case __MASKSMALLINT(LONGARRAY):
/*
* unsigned 32bit ints
*/
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the int-size of the machine
*/
if ((unsigned)indx < (nbytes>>2)) {
unsigned int32 ul;
unsigned int32 *lp;
lp = (unsigned int32 *)(pFirst + (indx<<2));
ul = *lp;
#ifdef alpha64
{
unsigned INT ull = (unsigned INT)ul;
RETURN ( __MKSMALLINT(ull) );
}
#else
if (ul <= _MAX_INT) {
RETURN ( __MKSMALLINT(ul) );
}
RETURN ( __MKULARGEINT(ul) );
#endif
}
break;
case __MASKSMALLINT(SLONGARRAY):
/*
* signed 32bit ints
*/
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the int-size of the machine
*/
if ((unsigned)indx < (nbytes>>2)) {
int32 *slp;
int32 l;
slp = (int32 *)(pFirst + (indx<<2));
l = *slp;
#ifdef alpha64
{
INT ll = (INT)l;
RETURN ( __MKSMALLINT(ll) );
}
#else
if (__ISVALIDINTEGER(l)) {
RETURN ( __MKSMALLINT(l) );
}
RETURN ( __MKLARGEINT(l) );
#endif
}
break;
case __MASKSMALLINT(SLONGLONGARRAY):
/*
* signed 64bit longlongs
*/
#ifdef __NEED_LONGLONG_ALIGN
if ((INT)pFirst & (__LONGLONG_ALIGN-1)) {
int delta = __LONGLONG_ALIGN - ((INT)pFirst & (__LONGLONG_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the long/longlong-size of the machine
*/
if ((unsigned)indx < (nbytes>>3)) {
#ifdef alpha64
INT *slp, ll;
slp = (INT *)(pFirst + (indx<<3));
ll = *slp;
if (__ISVALIDINTEGER(ll)) {
RETURN ( __MKSMALLINT(ll) );
}
RETURN ( __MKLARGEINT(ll) );
#else
__int64__ *llp;
extern OBJ __MKINT64();
llp = (__int64__ *)(pFirst + (indx<<3));
RETURN (__MKINT64(llp));
#endif
}
break;
case __MASKSMALLINT(LONGLONGARRAY):
/*
* unsigned 64bit longlongs
*/
#ifdef __NEED_LONGLONG_ALIGN
if ((INT)pFirst & (__LONGLONG_ALIGN-1)) {
int delta = __LONGLONG_ALIGN - ((INT)pFirst & (__LONGLONG_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
/* Notice: the hard coded shifts are by purpose;
* it makes us independent of the long/longlong-size of the machine
*/
if ((unsigned)indx < (nbytes>>3)) {
#ifdef alpha64
unsigned INT *ulp, ul;
ulp = (unsigned INT *)(pFirst + (indx<<3));
ul = *ulp;
if (ul <= _MAX_INT) {
RETURN ( __MKSMALLINT(ul) );
}
RETURN ( __MKULARGEINT(ul) );
#else
__uint64__ *llp;
extern OBJ __MKUINT64();
llp = (__uint64__ *)(pFirst + (indx<<3));
RETURN (__MKUINT64(llp));
#endif
}
break;
}
}
# undef int32
%}.
index isInteger ifFalse:[
^ self indexNotInteger
].
^ self subscriptBoundsError:index
!
basicAt:index put:anObject
"store the 2nd arg, anObject as indexed instvar with index, anInteger.
Returns anObject (sigh).
Trigger an error if the receiver has no indexed instance variables.
This method should NOT be redefined in any subclass (except with great care, for tuning)"
%{ /* NOCONTEXT */
register int nbytes, indx;
OBJ myClass;
register char *pFirst;
#ifdef alpha64
# define int32 int
#else
# define int32 long
#endif
/* int nInstBytes, ninstvars, flags; */
REGISTER int n;
unsigned int u;
int val;
/* notice the missing test for self being a nonNilObject -
this can be done since basicAt: is defined both in UndefinedObject
and SmallInteger */
if (__isSmallInteger(index)) {
indx = __intVal(index) - 1;
myClass = __qClass(self);
n /* ninstvars */ = __intVal(__ClassInstPtr(myClass)->c_ninstvars);
n /* nInstBytes */ = OHDR_SIZE + __OBJS2BYTES__(n /* ninstvars */);
nbytes = __qSize(self) - n /* nInstBytes */;
pFirst = (char *)(__InstPtr(self)) + n /* nInstBytes */;
switch ((INT)(__ClassInstPtr(myClass)->c_flags) & __MASKSMALLINT(ARRAYMASK)) {
case __MASKSMALLINT(POINTERARRAY):
case __MASKSMALLINT(WKPOINTERARRAY):
if ((unsigned)indx < (__BYTES2OBJS__(nbytes))) {
OBJ *op;
op = (OBJ *)pFirst + indx;
*op = anObject;
__STORE(self, anObject);
RETURN ( anObject );
}
break;
case __MASKSMALLINT(BYTEARRAY):
if (__isSmallInteger(anObject)) {
val = __intVal(anObject);
if ((val & ~0xFF) == 0 /* i.e. (val >= 0) && (val <= 255) */) {
if ((unsigned)indx < nbytes) {
char *cp;
cp = pFirst + indx;
*cp = val;
RETURN ( anObject );
}
}
}
break;
case __MASKSMALLINT(FLOATARRAY):
if ((unsigned)indx < (nbytes / sizeof(float))) {
float *fp;
fp = (float *)pFirst + indx;
if (anObject != nil) {
if (! __isSmallInteger(anObject)) {
if (__qIsFloatLike(anObject)) {
*fp = (float)(__floatVal(anObject));
RETURN ( anObject );
}
if (__qIsShortFloat(anObject)) {
*fp = __shortFloatVal(anObject);
RETURN ( anObject );
}
} else {
*fp = (float) __intVal(anObject);
RETURN ( anObject );
}
}
}
break;
case __MASKSMALLINT(DOUBLEARRAY):
#ifdef __NEED_DOUBLE_ALIGN
if ((INT)pFirst & (__DOUBLE_ALIGN-1)) {
int delta = __DOUBLE_ALIGN - ((INT)pFirst & (__DOUBLE_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
if ((unsigned)indx < (nbytes / sizeof(double))) {
double *dp;
dp = (double *)pFirst + indx;
if (anObject != nil) {
if (! __isSmallInteger(anObject)) {
if (__qIsFloatLike(anObject)) {
*dp = __floatVal(anObject);
RETURN ( anObject );
}
if (__qIsShortFloat(anObject)) {
*dp = (double)__shortFloatVal(anObject);
RETURN ( anObject );
}
} else {
*dp = (double) __intVal(anObject);
RETURN ( anObject );
}
}
}
break;
case __MASKSMALLINT(WORDARRAY):
if (__isSmallInteger(anObject)) {
val = __intVal(anObject);
if ((unsigned)val <= 0xFFFF) {
if ((unsigned)indx < (nbytes>>1)) {
unsigned short *sp;
sp = (unsigned short *)(pFirst + (indx<<1));
*sp = val;
RETURN ( anObject );
}
}
}
break;
case __MASKSMALLINT(SWORDARRAY):
if (__isSmallInteger(anObject)) {
val = __intVal(anObject);
if ((val >= -32768) && (val < 32768)) {
if ((unsigned)indx < (nbytes>>1)) {
short *ssp;
ssp = (short *)(pFirst + (indx<<1));
*ssp = val;
RETURN ( anObject );
}
}
}
break;
case __MASKSMALLINT(SLONGARRAY):
if ((unsigned)indx < (nbytes>>2)) {
int32 *slp;
slp = (int32 *)(pFirst + (indx<<2));
if (__isSmallInteger(anObject)) {
*slp = __intVal(anObject);
RETURN ( anObject );
}
n = __signedLongIntVal(anObject);
/*
* zero means failure for an int larger than 4 bytes
* (would be a smallInteger)
*/
if (n) {
*slp = n;
RETURN ( anObject );
}
}
break;
case __MASKSMALLINT(LONGARRAY):
if ((unsigned)indx < (nbytes>>2)) {
unsigned int32 *lp;
lp = (unsigned int32 *)(pFirst + (indx<<2));
if (anObject == __MKSMALLINT(0)) {
*lp = 0;
RETURN ( anObject );
}
u = __longIntVal(anObject);
/*
* zero means failure for an int larger than 4 bytes
* (would be a smallInteger)
*/
if (u) {
*lp = u;
RETURN ( anObject );
}
}
break;
case __MASKSMALLINT(SLONGLONGARRAY):
#ifdef __NEED_LONGLONG_ALIGN
if ((INT)pFirst & (__LONGLONG_ALIGN-1)) {
int delta = __LONGLONG_ALIGN - ((INT)pFirst & (__LONGLONG_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
if ((unsigned)indx < (nbytes>>3)) {
__int64__ ll;
__int64__ *sllp;
sllp = (__int64__ *)(pFirst + (indx<<3));
if (anObject == __MKSMALLINT(0)) {
ll.lo = ll.hi = 0;
*sllp = ll;
RETURN ( anObject );
}
if (__signedLong64IntVal(anObject, &ll)) {
*sllp = ll;
RETURN ( anObject );
}
}
break;
case __MASKSMALLINT(LONGLONGARRAY):
#ifdef __NEED_LONGLONG_ALIGN
if ((INT)pFirst & (__LONGLONG_ALIGN-1)) {
int delta = __LONGLONG_ALIGN - ((INT)pFirst & (__LONGLONG_ALIGN-1));
pFirst += delta;
nbytes -= delta;
}
#endif
if ((unsigned)indx < (nbytes>>3)) {
__uint64__ ll;
__uint64__ *llp;
llp = (__uint64__ *)(pFirst + (indx<<3));
if (anObject == __MKSMALLINT(0)) {
ll.lo = ll.hi = 0;
*llp = ll;
RETURN ( anObject );
}
if (__unsignedLong64IntVal(anObject, &ll)) {
*llp = ll;
RETURN ( anObject );
}
}
break;
}
}
# undef int32
%}.
index isInteger ifFalse:[
"
the index should be an integer number
"
^ self indexNotInteger
].
(index between:1 and:self size) ifFalse:[
"
the index is less than 1 or greater than the size of the
receiver collection
"
^ self subscriptBoundsError:index
].
(self class isFloatsOrDoubles) ifTrue:[
anObject isNumber ifTrue:[
^ self basicAt:index put:(anObject asFloat)
]
].
anObject isInteger ifFalse:[
"
the object to put into the receiver collection
should be an integer number
"
^ self elementNotInteger
].
"
the object to put into the receiver collection
is not an instance of the expected element class,
or the value is not within the elements valid range.
"
^ self elementBoundsError
"Modified: 19.4.1996 / 11:14:10 / cg"
!
byteAt:index
"return the byte at index.
This is only allowed for non-pointer indexed objects
(i.e. byteArrays, wordArrays, floatArrays etc.).
The receivers indexed instvars are treated as an uninterpreted
collection of bytes.
Only useful with binary storage."
%{ /* NOCONTEXT */
REGISTER int indx;
int nIndex;
REGISTER OBJ slf;
REGISTER OBJ cls;
if (__isSmallInteger(index)) {
slf = self;
if (__isNonNilObject(slf)) {
unsigned char *pFirst;
int nIndex;
cls = __qClass(slf);
pFirst = __byteArrayVal(slf);
pFirst += __OBJS2BYTES__(__intVal(__ClassInstPtr(cls)->c_ninstvars));
nIndex = __byteArraySize(slf);
indx = __intVal(index) - 1;
switch ((INT)(__ClassInstPtr(cls)->c_flags) & __MASKSMALLINT(ARRAYMASK)) {
case __MASKSMALLINT(DOUBLEARRAY):
#ifdef __NEED_DOUBLE_ALIGN
if ((INT)pFirst & (__DOUBLE_ALIGN-1)) {
int delta = __DOUBLE_ALIGN - ((INT)pFirst & (__DOUBLE_ALIGN-1));
pFirst += delta;
nIndex -= delta;
}
#endif
/* fall into */
case __MASKSMALLINT(BYTEARRAY):
case __MASKSMALLINT(WORDARRAY):
case __MASKSMALLINT(LONGARRAY):
case __MASKSMALLINT(SWORDARRAY):
case __MASKSMALLINT(SLONGARRAY):
case __MASKSMALLINT(FLOATARRAY):
if ((unsigned)indx < (unsigned)nIndex) {
RETURN ( __MKSMALLINT( (INT)(pFirst[indx])) );
}
break;
case __MASKSMALLINT(LONGLONGARRAY):
case __MASKSMALLINT(SLONGLONGARRAY):
#ifdef __NEED_LONGLONG_ALIGN
if ((INT)pFirst & (__LONGLONG_ALIGN-1)) {
int delta = __LONGLONG_ALIGN - ((INT)pFirst & (__LONGLONG_ALIGN-1));
pFirst += delta;
nIndex -= delta;
}
#endif
if ((unsigned)indx < (unsigned)nIndex) {
RETURN ( __MKSMALLINT( (INT)(pFirst[indx])) );
}
break;
}
}
}
%}.
"/ index not integer or index out of range
"/ or non-byte indexable receiver
^ self primitiveFailed
"
Point new byteAt:1
(ByteArray with:1 with:2) byteAt:2
(WordArray with:1) byteAt:1
(FloatArray with:1.0) byteAt:2
'hello' byteAt:1
"
!
byteAt:index put:byteValue
"set the byte at index.
This is only allowed for non-pointer indexed objects
(i.e. byteArrays, wordArrays, floatArrays etc.).
The receivers indexed instvars are treated as an uninterpreted
collection of bytes.
Only useful with binary storage."
%{ /* NOCONTEXT */
REGISTER int indx;
int val, nIndex;
REGISTER OBJ slf;
REGISTER OBJ cls;
if (__bothSmallInteger(index, byteValue)) {
val = __intVal(byteValue);
if ((unsigned)(val) <= 0xFF /* i.e. (val >= 0) && (val <= 255) */) {
slf = self;
if (__isNonNilObject(slf)) {
cls = __qClass(slf);
indx = __intVal(index) - 1;
switch ((INT)(__ClassInstPtr(cls)->c_flags) & __MASKSMALLINT(ARRAYMASK)) {
case __MASKSMALLINT(BYTEARRAY):
case __MASKSMALLINT(WORDARRAY):
case __MASKSMALLINT(LONGARRAY):
case __MASKSMALLINT(SWORDARRAY):
case __MASKSMALLINT(SLONGARRAY):
case __MASKSMALLINT(LONGLONGARRAY):
case __MASKSMALLINT(SLONGLONGARRAY):
case __MASKSMALLINT(FLOATARRAY):
case __MASKSMALLINT(DOUBLEARRAY):
indx += __OBJS2BYTES__(__intVal(__ClassInstPtr(cls)->c_ninstvars));
nIndex = __byteArraySize(slf);
if ((unsigned)indx < (unsigned)nIndex) {
__ByteArrayInstPtr(slf)->ba_element[indx] = val;
RETURN ( byteValue );
}
break;
}
}
}
}
%}.
"/ index not integer or index out of range
"/ or non-byte indexable receiver
^ self primitiveFailed
"
(ByteArray with:1 with:2) byteAt:2 put:3; yourself
'hello' copy byteAt:1 put:105; yourself
"
!
instVarAt:index
"return a non-indexed instance variable;
peeking into an object this way is not very object oriented
- use with care (needed for copy, inspector etc.)"
%{ /* NOCONTEXT */
OBJ myClass;
int idx, ninstvars;
if (__isSmallInteger(index)) {
myClass = __Class(self);
idx = __intVal(index) - 1;
/*
* do not allow returning of non-object fields.
* if subclass did not make privisions for that,
* we wont do so here ...
*/
if (((INT)(__ClassInstPtr(myClass)->c_flags) & __MASKSMALLINT(NONOBJECT_INSTS))) {
if (idx == 0) {
RETURN ( nil )
}
}
ninstvars = __intVal(__ClassInstPtr(myClass)->c_ninstvars);
if ((idx >= 0) && (idx < ninstvars)) {
RETURN ( __InstPtr(self)->i_instvars[idx] );
}
}
%}
.
index isInteger ifFalse:[
^ self indexNotInteger
].
^ self subscriptBoundsError:index
!
instVarAt:index put:value
"change a non-indexed instance variable;
peeking into an object this way is not very object oriented
- use with care (needed for copy, inspector etc.)"
%{ /* NOCONTEXT */
OBJ myClass;
int idx, ninstvars;
if (__isSmallInteger(index)) {
myClass = __Class(self);
idx = __intVal(index) - 1;
ninstvars = __intVal(__ClassInstPtr(myClass)->c_ninstvars);
/*
* do not allow setting of non-object fields.
* if subclass did not make privisions for that,
* we wont do so here ...
*/
if (((INT)(__ClassInstPtr(myClass)->c_flags) & __MASKSMALLINT(NONOBJECT_INSTS))) {
if (idx == 0) {
RETURN ( nil )
}
}
if ((idx >= 0) && (idx < ninstvars)) {
__InstPtr(self)->i_instvars[idx] = value;
__STORE(self, value);
RETURN ( value );
}
}
%}
.
index isInteger ifFalse:[
^ self indexNotInteger
].
^ self subscriptBoundsError:index
!
instVarNamed:name
"return a non-indexed instance variables value by name;
peeking into an object this way is not very object oriented
- use with care if at all (provided for inspectors and memory usage monitor).
Notice, this access is very slow (because the classes instVar-description has to be
parsed ad runtime)"
^ self instVarAt:(self class instVarOffsetOf:name)
"
|p|
p := Point x:10 y:20.
p instVarNamed:'x'
"
"Modified: 19.4.1996 / 11:12:39 / cg"
!
instVarNamed:name ifAbsent:exceptionBlock
"return a non-indexed instance variables value by name,
or the value of exceptionBlock, if there is no such instance variable.
peeking into an object this way is not very object oriented
- use with care if at all (provided for inspectors and memory usage monitor).
Notice, this access is very slow (because the classes instVar-description has to be
parsed ad runtime)"
|idx|
idx := self class instVarOffsetOf:name.
idx isNil ifTrue:[^ exceptionBlock value].
^ self instVarAt:idx
"
|p|
p := Point x:10 y:20.
p instVarNamed:'x'
"
"Created: 6.7.1996 / 23:02:49 / cg"
"Modified: 6.7.1996 / 23:03:41 / cg"
!
instVarNamed:name put:value
"set a non-indexed instance variable by name;
peeking into an object this way is not very object oriented
- if at all, use with care (provided for protocol completeness).
Notice, this access is very slow (because the classes instVar-description has to be
parsed ad runtime)"
^ self instVarAt:(self class instVarOffsetOf:name) put:value
"
|p|
p := Point x:10 y:20.
p instVarNamed:'x' put:30.
p
"
"Modified: 19.4.1996 / 11:12:49 / cg"
! !
!Object methodsFor:'attributes access'!
objectAttributeAt:attributeKey
"return the attribute for a given key or nil if not found"
| attrs |
attrs := self objectAttributes.
(attrs notNil and:[attrs size > 0]) ifTrue:[
^ attrs at:attributeKey ifAbsent:[]
].
^ nil
"Created: / 22.1.1998 / 21:29:17 / av"
"Modified: / 3.2.1998 / 18:55:55 / cg"
!
objectAttributeAt:attributeKey put:anObject
"store the attribute anObject referenced by key into the receiver"
"/ must do this save from interrupts, since the attributes collection
"/ is possibly accessed from multiple threads ...
[
| attrs |
attrs := self objectAttributes.
(attrs isNil or:[attrs size == 0]) ifTrue:[
attrs := WeakIdentityDictionary new.
attrs at:attributeKey put:anObject.
self objectAttributes:attrs.
] ifFalse:[
attrs at:attributeKey put:anObject.
].
] valueUninterruptably
"Attaching additional attributes (slots) to an arbitrary object:
|p|
p := Point new.
p objectAttributeAt:#color put:#green.
p objectAttributeAt:#color
"
"Created: / 22.1.1998 / 21:29:25 / av"
"Modified: / 3.2.1998 / 18:57:58 / cg"
!
objectAttributes
"return a Collection of attributes - nil if there is none.
The default implementation here uses a global WeakDictionary to store
attributes
This may be too slow for high frequency slot access,
therefore, some classes may redefine this for better performance.
Notice the mentioning of a WeakDictionary - read the classes documentation."
^ ObjectAttributes at:self ifAbsent:[nil]
"Created: / 22.1.1998 / 21:29:30 / av"
"Modified: / 18.2.2000 / 11:34:16 / cg"
!
objectAttributes:aCollection
"set the collection of attributes.
The default implementation here uses a global Dictionary to store
attributes which may be too slow for high frequency change&update.
Therefore, some classes may redefine this for better performance."
"/ must do this save from interrupts, since the attributes collection
"/ is possibly accessed from multiple threads.
(OperatingSystem blockInterrupts) ifTrue:[
"/ the common case - already blocked
(aCollection isNil or:[aCollection isEmpty]) ifTrue:[
ObjectAttributes removeKey:self ifAbsent:nil
] ifFalse:[
ObjectAttributes at:self put:aCollection
].
^ self
].
[
(aCollection isNil or:[aCollection isEmpty]) ifTrue:[
ObjectAttributes removeKey:self ifAbsent:nil
] ifFalse:[
ObjectAttributes at:self put:aCollection
].
] ensure:[
OperatingSystem unblockInterrupts
]
"Created: / 22.1.1998 / 21:29:35 / av"
"Modified: / 3.2.1998 / 18:58:10 / cg"
!
removeObjectAttribute:attributeKey
"make the argument, anObject be no attribute of the receiver"
"/ must do this save from interrupts, since the attributes collection
"/ is possibly accessed from multiple threads.
[
|attrs n a|
attrs := self objectAttributes.
attrs size == 0 ifTrue:[
self objectAttributes:nil
] ifFalse:[
attrs removeKey:attributeKey ifAbsent:nil.
attrs size == 0 ifTrue:[
self objectAttributes:nil
]
]
] valueUninterruptably
"Created: / 22.1.1998 / 21:29:39 / av"
"Modified: / 18.2.2000 / 11:32:19 / cg"
! !
!Object methodsFor:'binary storage'!
binaryStoreBytes
^ ByteArray streamContents:[:s | self storeBinaryOn:s].
"
#('hello' 1 1.234) binaryStoreBytes
"
!
hasSpecialBinaryRepresentation
"return true, if the receiver has a special binary representation;
default here is false, but can be redefined in class which provide
their own storeBinary/readBinary methods.
Normal user classes should not use this, it is meant as a hook for
special classes such as True, False, UndefinedObject or SmallInteger.
If your instances should be stored in a special way, see
#representBinaryOn: and #readBinaryContentsFromdata:manager:."
^ false
!
readBinaryContentsFrom:stream manager:manager
"reconstruct the receivers instance variables by reading a binary
binary representation from stream.
This is a general implementation, walking over instances
and loading each recursively using manager.
Redefined by some classes to read a more compact representations
(see String, SmallInteger etc).
Notice, that the object is already recreated as an empty corps
with instance variables all nil and bit-instances (bytes, words etc.)
already read and restored.
Also notice: this method is not called for if a private representation
has been stored (see representBinaryOn:).
In that case, #readBinaryContentsFromData:manager: is called, which
has to be reimplemented in the objects class."
|size "{ Class: SmallInteger }"
instvarArray|
stream next == 1 ifTrue:[
"/
"/ special representation ...
"/
instvarArray := Array new:(size := stream nextNumber:3).
1 to:size do:[:i |
instvarArray basicAt:i put:(manager nextObject)
].
self readBinaryContentsFromData:instvarArray manager:manager.
^ self
].
"/
"/ standard representation
"/
size := self basicSize.
size ~~ 0 ifTrue:[
self class isPointers ifTrue:[
1 to:size do:[:i |
self basicAt:i put:(manager nextObject)
]
]
].
size := self class instSize.
1 to:size do:[:i |
self instVarAt:i put:(manager nextObject)
].
!
readBinaryContentsFromData:instvarArray manager:manager
"reconstruct the receivers instance variables by filling instance
variables with values from instvarArray. This array contains the instvars
as specified in #representBinaryOn: when the object was stored.
It is the receivers responsibility to set its instance variables in the
same order from that array."
^ self subclassResponsibility:'method must be reimplemented in subclass for binary storage'
"typical implementation (see also comment in #representBinaryOn:)
(for an object with foo, bar and baz as instance variables,
which did not store baz and wants baz to be reinitialized to
some constant string)
foo := instvarArray at:1.
bar := instvarArray at:2.
baz := 'aConstant'.
"
!
representBinaryOn:manager
"this method is called by the storage manager to ask objects
if they wish to provide their own binary representation.
If they want to do so, they should return an array containing all
instance variables (named & indexed pointer) to be stored.
If not redefined, this method returns nil which means that all
instance variables are to be stored.
It should be redefined in objects which do not want all instance variables
to be stored (for example: objects which keep references to a view etc.).
If this is redefined returning non-nil, the corresponding class needs
a redefined instance method named #readBinaryContentsFromData:manager:
which has to fill the receivers named (and optionally indexed pointer)
instance variables with corresponding values from a data array."
^ nil
"typical implementation:
(see also comment in #readBinaryContentsFromData:manager:)
for an object with foo, bar and baz as instance variables,
which does not want to store baz:
representBinaryOn:manager
|data|
data := Array new:2.
data at:1 put:foo.
data at:2 put:bar.
^ data
"
!
storeBinaryDefinitionBodyOn:stream manager:manager
"append a binary representation of the receivers body onto stream.
This is a general implementation walking over instances storing
each recursively as an ID using manager.
Can be redefined in subclasses."
|basicSize "{ Class: SmallInteger }"
instSize "{ Class: SmallInteger }"
specialSize "{ Class: SmallInteger }"
myClass specialRep pointers|
myClass := self class.
instSize := myClass instSize.
(pointers := myClass isPointers) ifTrue:[
"/
"/ inst size not needed - if you uncomment the line below,
"/ also uncomment the corresponding line in
"/ Object>>binaryDefinitionFrom:manager:
"/
"/ stream nextPut:instSize. "mhmh this limits us to 255 named instvars"
myClass isVariable ifTrue:[
stream nextNumber:3 put:(basicSize := self basicSize)
] ifFalse:[
basicSize := 0
].
] ifFalse: [
stream nextNumber:4 put:(basicSize := self basicSize).
myClass isBytes ifTrue:[
1 to:basicSize do:[:i |
stream nextPut:(self basicAt:i)
]
] ifFalse:[
myClass isWords ifTrue:[
1 to:basicSize do:[:i |
stream nextNumber:2 put:(self basicAt: i)
]
] ifFalse:[
myClass isLongs ifTrue:[
1 to:basicSize do:[:i |
stream nextNumber:4 put:(self basicAt: i)
]
] ifFalse:[
myClass isFloats ifTrue:[
"could do it in one big write on machines which use IEEE floats ..."
1 to:basicSize do:[:i |
Float storeBinaryIEEESingle:(self basicAt:i) on:stream
]
] ifFalse:[
myClass isDoubles ifTrue:[
"could do it in one big write on machines which use IEEE doubles ..."
1 to:basicSize do:[:i |
Float storeBinaryIEEEDouble:(self basicAt:i) on:stream
]
] ifFalse:[
"/ should never be reached ...
1 to:basicSize do:[:i |
manager putIdOf:(self basicAt:i) on:stream
]
]
]
]
]
].
].
(pointers or:[instSize ~~ 0]) ifTrue:[
specialRep := self representBinaryOn:manager.
specialRep notNil ifTrue:[
specialSize := specialRep basicSize.
stream nextPut:1. "/ means: private representation follows
stream nextNumber:3 put:specialSize.
1 to:specialSize do:[:i |
manager putIdOf:(specialRep at:i) on:stream
].
] ifFalse:[
stream nextPut:0. "/ means: normal representation follows
"/ index pointers followed by named instanceVars
pointers ifTrue:[
basicSize ~~ 0 ifTrue:[
1 to:basicSize do:[:i |
manager putIdOf:(self basicAt:i) on:stream
].
].
].
instSize ~~ 0 ifTrue:[
1 to:instSize do:[:i |
manager putIdOf:(self instVarAt:i) on:stream
]
].
]
]
"Modified: / 2.11.1997 / 14:43:29 / cg"
!
storeBinaryDefinitionOn:stream manager:manager
"append a binary representation of the receiver onto stream.
This is an internal interface for binary storage mechanism.
This method first stores the class, then the body, which is done
in a separate method to allow redefinition of the bodies format.
Can be redefined in subclasses to write more compact representations
(see String, SmallInteger etc)."
manager putIdOfClass:(self class) on:stream.
self storeBinaryDefinitionBodyOn:stream manager:manager
"Modified: 23.4.1996 / 09:31:12 / cg"
!
storeBinaryOn:aStreamOrFilename
"Writes a description of the receiver onto aStreamOrFilename, in a way that allows
the object's structure to be reconstructed from the stream's contents"
BinaryOutputManager store:self on:aStreamOrFilename
"
|a s1 s2|
s1 := 'hello'.
s2 := 'world'.
a := Array new:5.
a at:1 put:s1.
a at:2 put:s2.
a at:3 put:s1.
a at:4 put:s2.
a storeBinaryOn:'test.boss'
"
"
(BinaryObjectStorage onOld:'test.boss' asFilename readStream)
next
inspect
"
"Modified: / 1.11.1997 / 21:16:24 / cg"
!
storeBinaryOn:stream manager:manager
"append a binary representation of the receiver onto stream."
manager putIdOf:self on:stream
! !
!Object methodsFor:'change & update'!
broadcast:aSelectorSymbol
"send a message with selector aSelectorSymbol to all my dependents"
self dependentsDo:[:dependent |
dependent perform:aSelectorSymbol
]
!
broadcast:aSelectorSymbol with:anArgument
"send a message with selector aSelectorSymbol with an additional
argument anArgument to all my dependents."
self dependentsDo:[:dependent |
dependent perform:aSelectorSymbol with:anArgument
]
!
changeRequest
"the receiver wants to change - check if all dependents
grant the request, and return true if so"
self dependentsDo:[:dependent |
dependent updateRequest ifFalse:[^ false].
].
^ true
!
changeRequest:aParameter
"the receiver wants to change - check if all dependents
grant the request, and return true if so"
self dependentsDo:[:dependent |
(dependent updateRequest:aParameter) ifFalse:[^ false].
].
^ true
!
changeRequest:aParameter from:anObject
"the receiver wants to change - check if all dependents
except anObject grant the request, and return true if so.
The argument anObject is typically going to be the one who is
about to send the change request."
self dependentsDo:[:dependent |
dependent == anObject ifFalse:[
(dependent updateRequest:aParameter) ifFalse:[^ false].
]
].
^ true
!
changeRequestFrom:anObject
"the receiver wants to change - check if all dependents
except anObject grant the request, and return true if so.
The argument anObject is typically going to be the one who is
about to send the change request."
self dependentsDo:[:dependent |
dependent == anObject ifFalse:[
(dependent updateRequest) ifFalse:[^ false].
]
].
^ true
!
changed
"notify all dependents that the receiver has changed.
Each dependent gets a '#update:'-message with the original
receiver as argument."
self changed:nil
!
changed:aParameter
"notify all dependents that the receiver has changed somehow.
Each dependent gets a '#update:'-message with aParameter
as argument."
self changed:aParameter with:nil
!
changed:aParameter with:anArgument
"notify all dependents that the receiver has changed somehow.
Each dependent gets a '#update:with:from:'-message, with aParameter
and anArgument as arguments."
self dependentsDo:[:dependent |
dependent update:aParameter with:anArgument from:self
]
!
update:aParameter
"the message is sent to a dependent, when one of the objects
on whom the receiver depends, has changed. The argument aParameter
is either the changed object or the argument to the #changed: message.
Default behavior here is to do nothing"
^ self
!
update:aParameter with:anArgument
"dependent is notified of some change -
Default is to try update:"
^ self update:aParameter
!
update:aParameter with:anArgument from:sender
"dependent is notified of some change -
Default is to try update:with:"
^ self update:aParameter with:anArgument
!
updateRequest
"return true, if an update request is granted.
Default here is to grant updates - may be used
to lock updates if someone is making other changes
from within an update. Or if someone has locked its
state and does not want others to change things.
However, these dependents must all honor the
changeRequest - ifTrue - change protocol. I.e. they
must first ask all others via changeRequest, and only do the change
it returns true. The others must decide in updateRequest and
return true if they think a change is ok."
^ true
!
updateRequest:aSymbol
"return true, if an update request is granted.
Default here a simple updateRequest"
^ self updateRequest
! !
!Object methodsFor:'cleanup'!
lowSpaceCleanup
"ignored here - redefined in some classes to
cleanup in low-memory situations"
^ self
! !
!Object methodsFor:'comparing'!
= anObject
"return true, if the receiver and the arg have the same structure.
Notice:
This method is partially open coded (inlined) by the compiler(s)
identical objects are always considered equal.
redefining it may not work as expected."
^ self == anObject
!
== anObject
"return true, if the receiver and the arg are the same object.
Never redefine this in any class.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
%{ /* NOCONTEXT */
RETURN ( (self == anObject) ? true : false );
%}
!
deepSameContentsAs:anObject
"return true, if the receiver and the arg have the same contents
in both the named instance vars and any indexed instVars.
This method descends into referenced objects, where #sameContentsAs: does not descend"
|myClass val
sz "{ Class: SmallInteger }" |
myClass := self class.
myClass isVariable ifTrue:[
sz := self basicSize.
"compare the indexed variables"
1 to:sz do:[:i |
val := self basicAt:i.
val isLiteral ifTrue:[
val = (anObject basicAt:i) ifFalse:[^ false].
] ifFalse:[
(val deepSameContentsAs:(anObject basicAt:i)) ifFalse:[^ false].
]
]
].
"compare the instance variables"
sz := myClass instSize.
1 to:sz do:[:i |
val := self instVarAt:i.
val isLiteral ifTrue:[
val = (anObject instVarAt:i) ifFalse:[^ false].
] ifFalse:[
(val deepSameContentsAs:(anObject instVarAt:i)) ifFalse:[^ false].
]
].
^ true
"
#(1 2 3 4) deepSameContentsAs:#[1 2 3 4] asArray
(1@2) deepSameContentsAs:(1->2)
"
!
hash
"return an Integer useful as a hash key for the receiver.
This hash should return same values for objects with same
contents (i.e. use this to hash on structure)"
^ self identityHash
!
identityHash
"return an Integer useful as a hash key for the receiver.
This hash should return same values for the same object (i.e. use
this to hash on identity of objects).
We cannot use the Objects address (as other smalltalks do) since
no object-table exists and the hashval must not change when objects
are moved by the collector. Therefore we assign each object a unique
Id in the object header itself as its hashed upon.
(luckily we have 11 bits spare to do this - unluckily its only 11 bits).
Time will show, if 11 bits are enough; if not, another entry in the
object header will be needed, adding 4 bytes to every object. Alternatively,
hashed-upon objects could add an instvar containing the hash value."
%{ /* NOCONTEXT */
REGISTER unsigned INT hash;
static unsigned nextHash = 0;
if (__isNonNilObject(self)) {
hash = __GET_HASH(self);
if (hash == 0) {
/* has no hash yet */
if (++nextHash > __MAX_HASH__) {
nextHash = 1;
}
hash = nextHash;
__SET_HASH(self, hash);
}
/*
* now, we got 11 bits for hashing;
* make it as large as possible; since most hashers use the returned
* key and take it modulo some prime number, this will allow for
* better distribution (i.e. bigger empty spaces) in hashed collection.
*/
hash = __MAKE_HASH__(hash);
RETURN ( __MKSMALLINT(hash) );
}
%}.
^ 0 "never reached, since redefined in UndefinedObject and SmallInteger"
!
identityHashForBinaryStore
"hash which is usable if the object does not change its class
and does not #become something else, while the hash is used.
This is only used by the binary storage mechanism, during the
object writing phase."
%{ /* NOCONTEXT */
REGISTER unsigned INT hash, hash1, hash2, sz;
OBJ o;
static unsigned INT nextHash = 0;
static unsigned INT nextClassHash = 0;
if (__isNonNilObject(self)) {
/*
* my own identityHash
*/
hash1 = __GET_HASH(self);
if (hash1 == 0) {
/* has no hash yet */
if (++nextHash > __MAX_HASH__) {
nextHash = 1;
}
hash1 = nextHash;
__SET_HASH(self, hash1);
}
/*
* my classes identityHash
*/
o = __qClass(self);
hash2 = __GET_HASH(o);
if (hash2 == 0) {
/* has no hash yet */
if (++nextClassHash > __MAX_HASH__) {
nextClassHash = 1;
}
hash2 = nextClassHash;
__SET_HASH(o, hash2);
}
/*
* some bits of my size
*/
sz = __qSize(self);
/*
* now, we got 11 + 11 + 8 bits for hashing;
* make it as large as possible; since most hashers use the returned
* key and take it modulo some prime number, this will allow for
* better distribution (i.e. bigger empty spaces) in hashed collection.
*/
hash = (hash1 << 11) | hash2; /* 22 bits */
hash = (hash << 8) | (sz & 0xFC); /* 30 bits */
while ((hash & 0x20000000) == 0) {
hash <<= 1;
}
RETURN ( __MKSMALLINT(hash) );
}
%}.
"never reached, since UndefinedObject and SmallInteger are not hashed upon in binary storage"
^ self identityHash
!
sameContentsAs:anObject
"return true, if the receiver and the arg have the same contents
in both the named instance vars and any indexed instVars."
|myClass
sz "{ Class: SmallInteger }" |
myClass := self class.
myClass isVariable ifTrue:[
sz := self basicSize.
"compare the indexed variables"
1 to:sz do:[:i |
(self basicAt:i) == (anObject basicAt:i) ifFalse:[^ false].
]
].
"compare the instance variables"
sz := myClass instSize.
1 to:sz do:[:i |
(self instVarAt:i) == (anObject instVarAt:i) ifFalse:[^ false].
].
^ true
"
#(1 2 3 4) sameContentsAs:#[1 2 3 4] asArray
(1@2) sameContentsAs:(1->2)
"
"Created: / 21.4.1998 / 15:56:40 / cg"
"Modified: / 21.4.1998 / 15:58:15 / cg"
!
~= anObject
"return true, if the receiver and the arg do not have the same structure.
Notice:
This method is partially open coded (inlined) by the compiler(s)
identical objects are never considered unequal.
redefining it may not work as expected."
^ (self = anObject) not
!
~~ anObject
"return true, if the receiver and the arg are not the same object.
Never redefine this in any class.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
%{ /* NOCONTEXT */
RETURN ( (self == anObject) ? false : true );
%}
! !
!Object methodsFor:'converting'!
!! anObject
"return a cons with the receiver as car and the argument as cdr"
^ Cons car:self cdr:anObject
"
(1 !! 2)
(#car !! #cdr)
(1 !! (2 !! (3 !! nil)))
(1 !! 2) !! (2 !! 3)
"
!
-> anObject
"return an association with the receiver as key and
the argument as value"
^ Association key:self value:anObject
!
asCollection
"return myself as a Collection.
Redefined in collection to return themself."
^ Array with:self
!
asSequenceableCollection
"return myself as a SequenceableCollection.
Redefined in SequenceableCollection"
^ Array with:self
!
asValue
"return a valueHolder for for the receiver"
^ ValueHolder with:self
!
collect
"return mySelf"
^ self
!
deepCollect
"return mySelf"
^ self
!
deepSelect
"return mySelf"
^ self
!
select
"return mySelf"
^ self
! !
!Object methodsFor:'copying'!
cloneFrom:anObject
"Helper for copy:
copy all instance variables from anObject into the receiver,
which should be of the same class as the argument."
self cloneFrom:anObject performing:#yourself
"
|x|
x := Array new:3.
x cloneFrom:#(1 2 3).
"
!
cloneFrom:anObject performing:aSymbol
"Helper for copy:
for each instance variables from anObject, send it aSymbol
and store the result into the receiver,
which should be of the same class as the argument."
|myClass sz "{ Class: SmallInteger }" t |
myClass := self class.
myClass isVariable ifTrue:[
sz := self basicSize.
"copy the indexed variables"
1 to:sz do:[:i |
t := anObject basicAt:i.
aSymbol ~~ #yourself ifTrue:[
t := t perform:aSymbol.
].
self basicAt:i put:t.
]
].
"copy the instance variables"
sz := myClass instSize.
1 to:sz do:[:i |
t := anObject instVarAt:i.
aSymbol ~~ #yourself ifTrue:[
t := t perform:aSymbol
].
self instVarAt:i put:t
].
^ self
!
cloneInstanceVariablesFrom:aPrototype
"Shallow copy variables from a prototype into myself.
This copies instVars by name - i.e. same-named variables are
copied, others are not.
The variable slots are copied as available
(i.e. the min of both indexed sizes is used)."
|myInfo otherInfo|
myInfo := self class instanceVariableOffsets.
otherInfo := aPrototype class instanceVariableOffsets.
myInfo keysAndValuesDo:[:name :index | |varIndexAssoc|
varIndexAssoc := otherInfo at:name ifAbsent:[].
varIndexAssoc notNil ifTrue:[
self instVarAt:index put:(aPrototype instVarAt:(varIndexAssoc value))
]
].
self isVariable ifTrue:[
1 to:(self basicSize min:aPrototype basicSize) do:[:index |
self basicAt:index put:(aPrototype basicAt:index)
].
].
"
Class withoutUpdatingChangesDo:[
Point subclass:#Point3D
instanceVariableNames:'z'
classVariableNames:''
poolDictionaries:''
category:'testing'.
(Point3D new cloneInstanceVariablesFrom:1@2) inspect.
]
"
"
Class withoutUpdatingChangesDo:[
Point variableSubclass:#Point3D
instanceVariableNames:'z'
classVariableNames:''
poolDictionaries:''
category:'testing'.
((Point3D new:2) cloneInstanceVariablesFrom:#(1 2 3)) inspect.
]
"
"
|someObject|
Class withoutUpdatingChangesDo:[
Object subclass:#TestClass1
instanceVariableNames:'foo bar'
classVariableNames:''
poolDictionaries:''
category:'testing'.
someObject := TestClass1 new.
someObject instVarAt:1 put:'foo'; instVarAt:2 put:'bar'.
Object subclass:#TestClass2
instanceVariableNames:'bar foo'
classVariableNames:''
poolDictionaries:''
category:'testing'.
(TestClass2 new cloneInstanceVariablesFrom:someObject) inspect.
]
"
"
|top b b1|
top := StandardSystemView new.
top extent:100@100.
b := Button in:top.
b label:'hello'.
b1 := ArrowButton new cloneInstanceVariablesFrom:b.
top open.
b1 inspect
"
!
copy
"return a copy of the receiver - defaults to shallowcopy here.
Notice, that copy does not copy dependents."
^ self shallowCopy postCopy
!
copyToLevel:level
"one more level than a shallowCopy"
| newObject class index |
level == 1 ifTrue:[^ self shallowCopy].
class _ self class.
newObject _ self clone.
newObject == self ifTrue: [^ self].
class isVariable
ifTrue:
[index _ self basicSize.
[index > 0]
whileTrue:
[newObject basicAt: index put: ((self basicAt: index) copyToLevel:(level-1)).
index _ index - 1]].
index _ class instSize.
[index > 0]
whileTrue:
[newObject instVarAt: index put: ((self instVarAt: index) copyToLevel:(level-1)).
index _ index - 1].
^newObject
!
deepCopy
"return a copy of the object with all subobjects also copied.
This method DOES handle cycles/self-refs and preserves object identity;
however the receivers class is not copied (to avoid the 'total' copy).
This deepCopy is a bit slower than the old (unsecure) one, since it
keeps track of already copied objects. If you are sure, that your
copied object does not include duplicates (or you do not care) and
no cycles are involved, you can use the old simpleDeepCopy,
which avoids this overhead (but may run into trouble).
Notice, that deepCopy does not copy dependents."
^ (self deepCopyUsing:(IdentityDictionary new)) postDeepCopyFrom:self
"an example which is not handled by the old deepCopy:
|a|
a := Array new:3.
a at:3 put:a.
a deepCopy inspect
"
"
|a|
a := Color black onDevice:Screen current.
a deepCopy inspect
"
"Modified: 27.3.1996 / 16:31:20 / stefan"
!
deepCopyError
"{ Pragma: +optSpace }"
"raise a signal, that deepCopy is not allowed for this object"
^ DeepCopyErrorSignal raise
!
deepCopyUsing:aDictionary
"a helper for deepCopy; return a copy of the object with
all subobjects also copied. If the to-be-copied object is in the dictionary,
use the value found there. The class of the receiver is not copied.
This method DOES handle cycles/self references."
|myClass aCopy
sz "{ Class: SmallInteger }"
iOrig iCopy|
myClass := self class.
myClass isVariable ifTrue:[
sz := self basicSize.
aCopy := myClass basicNew:sz.
] ifFalse:[
sz := 0.
aCopy := myClass basicNew
].
aCopy setHashFrom:self.
aDictionary at:self put:aCopy.
"
copy indexed instvars - if any
"
sz ~~ 0 ifTrue:[
myClass isBits ifTrue:[
"block-copy indexed instvars"
aCopy replaceFrom:1 to:sz with:self startingAt:1
] ifFalse:[
"individual deep copy the indexed variables"
1 to:sz do:[:i |
iOrig := self basicAt:i.
iOrig notNil ifTrue:[
(aDictionary includesKey:iOrig) ifTrue:[
iCopy := aDictionary at:iOrig
] ifFalse:[
iCopy := (iOrig deepCopyUsing:aDictionary) postDeepCopy
].
aCopy basicAt:i put:iCopy
]
]
]
].
"
copy the instance variables
"
sz := myClass instSize.
1 to:sz do:[:i |
(self skipInstvarIndexInDeepCopy:i) ifFalse:[
iOrig := self instVarAt:i.
iOrig notNil ifTrue:[
(aDictionary includesKey:iOrig) ifTrue:[
iCopy := aDictionary at:iOrig
] ifFalse:[
iCopy := (iOrig deepCopyUsing:aDictionary) postDeepCopy
].
aCopy instVarAt:i put:iCopy
]
]
].
^ aCopy
"
|a b c copyOfC|
a := Array with:'hello' with:'world' with:nil.
b := 99 @ 999.
a at:3 put:b.
c := Array with:a with:b with:a.
Transcript showCR: (c at:1) == (c at:3).
copyOfC := c deepCopy.
Transcript showCR: (copyOfC at:1) == (copyOfC at:3)
"
!
postCopy
"this is for compatibility with ST-80 code, which uses postCopy for
cleanup after copying, while ST/X passes the original in postCopyFrom:
(see there)"
^ self
!
postDeepCopy
"allows for cleanup after deep copying"
^ self postCopy
!
postDeepCopyFrom:aSource
"allows for cleanup after deep copying"
^ self postDeepCopy
!
setHashFrom:anObject
"set my identity-hash key to be the same as anObjects hash key.
This is an ST/X speciality, which is NOT available in other (especially OT based)
Smalltalks, and may not be available in future ST/X versions.
DO NEVER use this for normal application code."
%{ /* NOCONTEXT */
REGISTER unsigned h;
if (__isNonNilObject(self) && __isNonNilObject(anObject)) {
h = __GET_HASH(anObject);
__SET_HASH(self, h);
RETURN (self);
}
%}.
self primitiveFailed "neither receiver not arg may be nil or SmallInteger"
!
shallowCopy
"return a copy of the object with shared subobjects (a shallow copy)
i.e. the copy shares referenced instvars with its original."
%{ /* NOCONTEXT */
int ninsts, spc;
int sz;
OBJ theCopy;
OBJ cls;
int flags;
cls = __qClass(self);
flags = __intVal(__ClassInstPtr(cls)->c_flags);
/*
* bail out for special objects ..
*/
if (((flags & ~ARRAYMASK) == 0)
&& ((flags & ARRAYMASK) != WKPOINTERARRAY)) {
sz = __qSize(self);
__PROTECT__(self);
__qNew(theCopy, sz); /* OBJECT ALLOCATION */
__UNPROTECT__(self);
if (theCopy) {
cls = __qClass(self);
spc = __qSpace(theCopy);
theCopy->o_class = cls; __STORE_SPC(theCopy, cls, spc);
sz = sz - OHDR_SIZE;
if (sz) {
char *src, *dst;
src = (char *)(__InstPtr(self)->i_instvars);
dst = (char *)(__InstPtr(theCopy)->i_instvars);
#ifdef bcopy4
{
/* care for odd-number of longs */
int nW = sz >> 2;
if (sz & 3) {
nW++;
}
bcopy4(src, dst, nW);
}
#else
bcopy(src, dst, sz);
#endif
flags &= ARRAYMASK;
if (flags == POINTERARRAY) {
ninsts = __BYTES2OBJS__(sz);
} else {
ninsts = __intVal(__ClassInstPtr(cls)->c_ninstvars);
}
if (ninsts) {
do {
OBJ el;
el = __InstPtr(theCopy)->i_instvars[ninsts-1];
__STORE_SPC(theCopy, el, spc);
} while (--ninsts);
}
}
RETURN (theCopy);
}
}
%}.
"/ fallBack for special objects & memoryAllocation failure case
^ self slowShallowCopy
!
simpleDeepCopy
"return a copy of the object with all subobjects also copied.
This method does NOT handle cycles - but is included to allow this
slightly faster copy in situations where it is known that
no recursive references occur (LargeIntegers for example).
NOTICE: you will run into trouble, when trying this with recursive
objects (usually recursionInterrupt or memory-alert).
This method corresponds to the 'traditional' deepCopy found in
the Blue book."
|myClass aCopy|
(myClass := self class) isVariable ifTrue:[
aCopy := myClass basicNew:(self basicSize).
] ifFalse:[
aCopy := myClass basicNew
].
"copy the instance variables"
aCopy cloneFrom:self performing:#simpleDeepCopy.
^ aCopy
"a bad example (but ST/X should survive ...)"
"
|a|
a := Array new:3.
a at:3 put:a.
a simpleDeepCopy
"
!
skipInstvarIndexInDeepCopy:index
"a helper for deepCopy; only indices for which this method returns
false are copied in a deep copy.
The default is false here - which means that everything is copied.
Can be redefined in subclasses for partial copies"
^ false
!
slowShallowCopy
"return a copy of the object with shared subobjects (a shallow copy)
i.e. the copy shares referenced instvars with its original.
This method is only invoked as a fallback from #shallowCopy."
|myClass aCopy|
(myClass := self class) isVariable ifTrue:[
aCopy := myClass basicNew:(self basicSize).
] ifFalse:[
aCopy := myClass basicNew
].
"copy the instance variables"
aCopy cloneFrom:self performing:#yourself.
^ aCopy
! !
!Object methodsFor:'debugging'!
basicInspect
"{ Pragma: +optSpace }"
"launch an inspector on the receiver.
this method should NOT be redefined in subclasses."
Inspector isNil ifTrue:[
"
for systems without GUI
"
self warn:'No Inspector defined (Inspector is nil).'
] ifFalse:[
Inspector openOn:self
]
"Modified: 18.5.1996 / 15:43:25 / cg"
!
browse
"open a browser on the receivers class"
self class theNonMetaclass browse
"
10 browse
Collection browse
Collection class browse
"
!
inspect
"{ Pragma: +optSpace }"
"launch an inspector on the receiver.
this method (or better: inspectorClass) can be redefined in subclasses
to start special inspectors."
|cls|
cls := self inspectorClass.
cls isNil ifTrue:[
^ self basicInspect
].
cls openOn:self
"
Object new inspect
(1 @ 2) inspect
Smalltalk inspect
#(1 2 3) asOrderedCollection inspect
(Color red) inspect
(Image fromFile:'bitmaps/garfield.gif') inspect
"
!
inspectorClass
"{ Pragma: +optSpace }"
"return the class to use for inspect.
Can (should) be redefined in classes for which a better inspector is available"
^ Inspector
!
mustBeBoolean
"this message is sent by the VM, if a non-Boolean receiver is encountered
in an if* or while* message.
Caveat: for now, this is only sent by the interpreter;
both the JIT and the stc compiler treat it as undefined."
self error:'Non boolean receiver - proceed for truth' mayProceed:true.
^ true
!
mustBeKindOf:aClass
"for compatibility & debugging support:
check if the receiver isKindOf:aClass and raise an error if not.
Notice:
it is VERY questionable, if it makes sense to add manual
type checks to a dynamically typed language like smalltalk.
It will, at least, slow down performance,
make your code less reusable and clutter your code with stupid sends
of this selector. Also, read the comment in isKindOf:, regarding the
use of isXXX check methods.
You see: The author does not like this at all ..."
(self isKindOf:aClass) ifFalse:[
self error:'argument is not of expected type'
]
!
obsoleteMethodWarning
"{ Pragma: +optSpace }"
"in methods which are going to be obsoleted, a self send to
this method is used to tell programmers that a method is
used which is going to be removed in later ST/X versions.
Find all methods which will be obsolete soon by looking at senders
of this message.
Hopefully, this warning message is annoying enough for you to
change the code ... ;-)"
self obsoleteMethodWarning:nil from:thisContext sender
!
obsoleteMethodWarning:message
"{ Pragma: +optSpace }"
"in methods which are going to be obsoleted, a self send to
this method is used to tell programmers that a method is
used which is going to be removed in later ST/X versions.
Find all methods which will be obsolete soon by looking at senders
of this message.
Hopefully, this warning message is annoying enough for you to
change the code ... ;-)"
self obsoleteMethodWarning:message from:thisContext sender
!
obsoleteMethodWarning:message from:aContext
"{ Pragma: +optSpace }"
"in methods which are going to be obsoleted, a self-send to
this method is used to tell programmers that a method is
used which is going to be removed in later ST/X versions.
Find all methods which will be obsolete soon by looking at senders
of this message.
Hopefully, this warning message is annoying enough for you to
change the code ... ;-).
This message is intended for application developers, so print it as info message."
|spec|
spec := aContext methodPrintString.
('WARNING: the ''' , spec , ''' method is obsolete.') infoPrintCR.
(' And may not be present in future ST/X versions.') infoPrintCR.
(' called from ' , aContext sender printString) infoPrintCR.
message notNil ifTrue:[
'------> ' infoPrint. message infoPrintCR
]
"
Object obsoleteMethodWarning:'foo' from:thisContext sender sender
"
! !
!Object methodsFor:'dependents access'!
addDependent:anObject
"make the argument, anObject be a dependent of the receiver"
|wasBlocked|
"/ must do this save from interrupts, since the dependents collection
"/ is possibly accessed from multiple threads.
"/ Used to use #valueUninterruptably here; inlined that code for slightly
"/ faster execution.
wasBlocked := OperatingSystem blockInterrupts.
[
|deps dep|
deps := self dependents.
"/ to save a fair amount of memory in case of
"/ many dependencies, we store a single dependent in
"/ a WeakArray, and switch to a WeakSet if more dependents are
"/ added.
(deps isNil or:[deps size == 0]) ifTrue:[
self dependents:(WeakArray with:anObject)
] ifFalse:[
deps class == WeakArray ifTrue:[
dep := deps at:1.
dep ~~ anObject ifTrue:[
(dep isNil or:[dep == 0]) ifTrue:[
deps at:1 put:anObject
] ifFalse:[
self dependents:(WeakIdentitySet with:dep with:anObject)
]
]
] ifFalse:[
deps add:anObject
]
]
] ensure:[
wasBlocked ifFalse:[
OperatingSystem unblockInterrupts
]
]
"Modified: / 27.10.1997 / 19:35:52 / cg"
!
breakDependents
"remove all dependencies from the receiver"
self dependents:nil.
self nonWeakDependents:nil
"Modified: / 19.4.1996 / 10:55:36 / cg"
"Created: / 27.2.1998 / 11:26:11 / stefan"
!
dependents
"return a Collection of dependents.
The default implementation here uses a global WeakDictionary to store
dependents
This may be too slow for high frequency change&update,
therefore, some classes (Model) redefine this for better performance.
Notice the mentioning of a WeakDictionary - read the classes documentation."
|deps|
(deps := Dependencies at:self ifAbsent:nil) isNil ifTrue:[
^ #().
].
^ deps
"Modified: / 26.1.1998 / 11:18:15 / cg"
!
dependents:aCollection
"set the collection of dependents.
The default implementation here uses a global Dictionary to store
dependents which may be too slow for high frequency change&update.
Therefore, some classes (Model) redefine this for better performance."
"/ must do this save from interrupts, since the dependents collection
"/ is possibly accessed from multiple threads.
"/ Used to use #valueUninterruptably here; inlined that code for slightly
"/ faster execution (and to avoid creation of garbage blocks).
(OperatingSystem blockInterrupts) ifTrue:[
"/ the common case - already blocked
(aCollection isNil or:[aCollection isEmpty]) ifTrue:[
Dependencies removeKey:self ifAbsent:nil
] ifFalse:[
Dependencies at:self put:aCollection
].
^ self
].
[
(aCollection isNil or:[aCollection isEmpty]) ifTrue:[
Dependencies removeKey:self ifAbsent:nil
] ifFalse:[
Dependencies at:self put:aCollection
].
] ensure:[
OperatingSystem unblockInterrupts
]
"Modified: 30.1.1997 / 21:22:10 / cg"
!
dependentsDo:aBlock
"evaluate aBlock for all of my dependents"
|deps nwDeps|
deps := self dependents.
deps size ~~ 0 ifTrue:[
deps do:[:d |
(d notNil and:[d ~~ 0]) ifTrue:[
aBlock value:d
]
]
].
nwDeps := self nonWeakDependents.
(nwDeps ~~ deps and:[nwDeps size ~~ 0]) ifTrue:[
nwDeps do:aBlock
].
"Modified: / 30.1.1998 / 14:03:40 / cg"
!
myDependents
"same as dependents - ST-80 compatibility"
^ self dependents
!
release
"remove all references to objects that may refer to self.
Subclasses may redefine this method but should do a 'super release'."
self breakDependents
"Modified: / 27.2.1998 / 11:29:35 / stefan"
!
removeDependent:anObject
"make the argument, anObject be independent of the receiver"
|wasBlocked|
"/ must do this save from interrupts, since the dependents collection
"/ is possibly accessed from multiple threads.
"/ Used to use #valueUninterruptably here; inlined that code for slightly
"/ faster execution.
wasBlocked := OperatingSystem blockInterrupts.
[
|deps n d|
deps := self dependents.
deps size ~~ 0 ifTrue:[
"/ to save a fair amount of memory in case of
"/ many dependencies, we store a single dependent in
"/ a WeakArray, and switch to a WeakSet if more dependents are
"/ added. Here we have to do the inverse ...
deps class == WeakArray ifTrue:[
((d := deps at:1) == anObject
or:[d isNil
or:[d == 0]]) ifTrue:[
self dependents:nil
]
] ifFalse:[
deps remove:anObject ifAbsent:[].
(n := deps size) == 0 ifTrue:[
self dependents:nil
] ifFalse:[
n == 1 ifTrue:[
d := deps firstIfEmpty:nil.
d notNil ifTrue:[
deps := WeakArray with:d
] ifFalse:[
deps := nil
].
self dependents:deps.
]
]
]
]
] ensure:[
wasBlocked ifFalse:[
OperatingSystem unblockInterrupts
]
]
"Modified: / 26.1.1998 / 19:51:50 / cg"
! !
!Object methodsFor:'dependents access (nonWeak)'!
addNonWeakDependent:anObject
"make the argument, anObject be a nonWeak dependent of the receiver.
Be careful: this nonWeakDependency will prevent the dependent from being
garbage collected unless the dependency is removed.
This is a private mechanism, for directed dependencies."
|wasBlocked|
"/ must do this save from interrupts, since the dependents collection
"/ is possibly accessed from multiple threads.
"/ Used to use #valueUninterruptably here; inlined that code for slightly
"/ faster execution.
wasBlocked := OperatingSystem blockInterrupts.
[
|deps dep|
deps := self nonWeakDependents.
"/ to save a fair amount of memory in case of
"/ many dependencies, we store a single dependent in
"/ an Array, and switch to a Set if more dependents are
"/ added.
deps size == 0 ifTrue:[
self nonWeakDependents:(Array with:anObject)
] ifFalse:[
deps class == Array ifTrue:[
dep := deps at:1.
dep ~~ anObject ifTrue:[
self nonWeakDependents:(IdentitySet with:dep with:anObject)
]
] ifFalse:[
deps add:anObject
]
]
] ensure:[
wasBlocked ifFalse:[
OperatingSystem unblockInterrupts
]
]
"Created: / 19.4.1996 / 10:54:08 / cg"
"Modified: / 30.1.1998 / 14:03:08 / cg"
!
nonWeakDependents
"return a Collection of nonWeakDependents - empty if there is none.
This is a private mechanism for directed dependencies."
NonWeakDependencies isNil ifTrue:[^ #()].
^ NonWeakDependencies at:self ifAbsent:#()
"Created: / 19.4.1996 / 10:55:06 / cg"
"Modified: / 30.1.1998 / 14:06:47 / cg"
!
nonWeakDependents:aCollection
"set the collection of nonWeak dependents.
This is a private helper for directed dependencies."
[
(aCollection isNil or:[aCollection isEmpty]) ifTrue:[
NonWeakDependencies removeKey:self ifAbsent:nil
] ifFalse:[
NonWeakDependencies at:self put:aCollection
]
] valueUninterruptably
"Created: 19.4.1996 / 11:07:47 / cg"
!
removeNonWeakDependent:anObject
"remove a nonWeak dependency from the receiver to the argument, anObject.
(i.e. make it independent of the receiver)"
|wasBlocked|
"/ must do this save from interrupts, since the dependents collection
"/ is possibly accessed from multiple threads.
"/ Used to use #valueUninterruptably here; inlined that code for slightly
"/ faster execution.
wasBlocked := OperatingSystem blockInterrupts.
[
|deps n|
deps := self nonWeakDependents.
deps size ~~ 0 ifTrue:[
deps class == Array ifTrue:[
(deps at:1) == anObject ifTrue:[
self nonWeakDependents:nil
]
] ifFalse:[
deps remove:anObject ifAbsent:[].
(n := deps size) == 0 ifTrue:[
self nonWeakDependents:nil
] ifFalse:[
n == 1 ifTrue:[
self nonWeakDependents:(Array with:(deps first))
]
]
]
]
] ensure:[
wasBlocked ifFalse:[
OperatingSystem unblockInterrupts
]
]
"Created: / 19.4.1996 / 11:44:44 / cg"
"Modified: / 30.1.1998 / 14:04:01 / cg"
! !
!Object methodsFor:'displaying'!
displayOn:aGCOrStream
"ST-80 Compatibility
display the receiver in a graphicsContext at 0@0
- this method allows for any object to be displayed in some view
(although the fallBack is to display its printString ...)"
"/ what a kludge - Dolphin and Squeak mean: printOn:;
"/ ST/X (and some old ST80's) mean: draw-yourself on.
(aGCOrStream isStream or:[aGCOrStream == Transcript]) ifTrue:[
self printOn:aGCOrStream.
^ self
].
^ self displayOn:aGCOrStream x:0 y:0.
"Created: 29.5.1996 / 16:28:58 / cg"
!
displayOn:aGC at:aPoint
"ST-80 Compatibility
display the receiver in a graphicsContext - this method allows
for any object to be displayed in a ListView - for example."
^ self displayOn:aGC x:(aPoint x) y:(aPoint y).
!
displayOn:aGC x:x y:y
"display the receiver in a graphicsContext - this method allows
for any object to be displayed in a ListView - for example."
self displayOn:aGC x:x y:y opaque:false
"Modified: 29.5.1996 / 16:29:38 / cg"
!
displayOn:aGc x:x y:y opaque:opaque
"display the receiver in a graphicsContext - this method allows
for any object to be displayed in a ListView - for example.
The fallBack here shows the receivers displayString."
|s yBaseline|
s := self displayString.
"/ although correct, this breaks DataSet, and it must be fixed
"/ there first ...
yBaseline := y + aGc font ascent.
yBaseline := y "+ aGc font ascent".
opaque ifTrue:[
aGc displayOpaqueString:s x:x y:yBaseline.
] ifFalse:[
aGc displayString:s x:x y:yBaseline.
].
"Modified: 29.5.1996 / 16:29:38 / cg"
!
displayOpaqueOn:aGC x:x y:y
"display the receiver in a graphicsContext - this method allows
for any object to be displayed in a ListView - for example."
self displayOn:aGC x:x y:y opaque:true
"Modified: / 29.5.1996 / 16:29:38 / cg"
"Created: / 26.10.1997 / 15:01:36 / cg"
!
displayString
"return a string used when displaying the receiver in a view;
for example an Inspector. This is usually the same as printString,
but sometimes redefined for a better look."
^ String streamContents:[:s | self displayOn:s].
"
#(1 2 3) printString
#(1 2 3) displayString
#(1 2 3) storeString
"
!
heightOn:aGC
"return the height of the receiver, if it is to be displayed on aGC"
^ (aGC font onDevice:aGC device) heightOf:(self displayString)
!
widthFrom:startIndex to:endIndex on:aGC
"return the width of the receiver, if it is to be displayed on aGC"
^ (aGC font onDevice:aGC device) widthOf:(self displayString) from:startIndex to:endIndex
!
widthOn:aGC
"return the width of the receiver, if it is to be displayed on aGC"
^ (aGC font onDevice:aGC device) widthOf:(self displayString)
! !
!Object methodsFor:'encoding & decoding'!
decodeAsLiteralArray
^ self
!
encodeOn:anEncoder with:aParameter
"double-dispatch onto an ObjectEncoder.
Subclasses redefine this"
anEncoder encodeObject:self with:aParameter
!
encodingVectorFor:aspect
"answer a collection of associations containing the
objects state to be encoded for aspect.
Association key is the instance variable name or access selector,
association value is the contents of the instance variable.
The default is to return the contents of all instance variables"
|ret|
ret := self perform:aspect ifNotUnderstood:[0].
ret == 0 ifTrue:[
^ self encodingVectorForNonNilInstanceVariables
].
^ ret.
!
encodingVectorForInstanceVariables
"return all instance variables for encoding"
|instVarNames theClass children
instSize "{ Class: SmallInteger }"
varSize "{ Class: SmallInteger }"|
theClass := self class.
instSize := theClass instSize.
varSize := theClass isVariable ifTrue:[self basicSize] ifFalse:[0].
children := OrderedCollection new:(instSize + varSize).
instVarNames := theClass allInstVarNames.
1 to:instSize do:[:i | |var|
var := self instVarAt:i.
children add:((instVarNames at:i) -> var)
].
varSize ~~ 0 ifTrue:[
1 to:varSize do:[:i |
children add:(i -> (self basicAt:i))
]
].
^ children.
"
#(1 2 3 nil true symbol) encodingVectorForInstanceVariables
Dictionary new encodingVectorForInstanceVariables
(5 @ nil) encodingVectorForInstanceVariables
"
!
encodingVectorForNonNilInstanceVariables
"return all instance variables for encoding"
|instVarNames theClass children
instSize "{ Class: SmallInteger }"
varSize "{ Class: SmallInteger }"|
theClass := self class.
instSize := theClass instSize.
varSize := theClass isVariable ifTrue:[self basicSize] ifFalse:[0].
children := OrderedCollection new:(instSize + varSize)*2.
instVarNames := theClass allInstVarNames.
1 to:instSize do:[:i | |var|
var := self instVarAt:i.
var notNil ifTrue:[
children add:((instVarNames at:i) -> var).
]
].
varSize ~~ 0 ifTrue:[
1 to:varSize do:[:i |
"even code nil -- position matters"
children add:(i -> (self basicAt:i))
]
].
^ children.
"
#(1 2 3 nil true symbol) encodingVectorForNonNilInstanceVariables
(5 @ nil) encodingVectorForNonNilInstanceVariables
"
!
fromLiteralArrayEncoding:aSpecArray
"read my attributes from aSpecArray
"
|sel val
stop "{ Class:SmallInteger }" |
stop := aSpecArray size.
2 to:stop by:2 do:[:i|
sel := aSpecArray at:i.
val := aSpecArray at:i + 1.
(self respondsTo:sel) ifTrue:[
self perform:sel with:(val decodeAsLiteralArray)
] ifFalse:[
Transcript show:self class name; show:': unhandled literalArrayEncoding attribute: '.
Transcript showCR:sel.
]
]
!
literalArrayEncoding
"generate a literalArrayEncoding array for myself.
This uses #literalArrayEncodingSlotOrder which defines the slots and
order and #skippedInLiteralEncoding which defines slots to skip.
For most subclasses, there is no need to redefine those."
|names encoding cls skipped|
self isLiteral ifTrue:[
^ self
].
skipped := self skippedInLiteralEncoding.
cls := self class.
names := cls allInstVarNames.
encoding := OrderedCollection with:(cls name).
(self literalArrayEncodingSlotOrder) do:[:instSlot |
|value nm|
nm := names at:instSlot.
(skipped includes:nm) ifFalse:[
(value := self instVarAt:instSlot) notNil ifTrue:[
encoding add:(nm , ':') asSymbol.
encoding add:value literalArrayEncoding
]
]
].
^ encoding asArray
!
literalArrayEncodingSlotOrder
"define the order in which inst-slots are saved when generating
a literalArrayEncoding
"
^ 1 to:self class instSize
!
skippedInLiteralEncoding
"return a Collection with it's elements are slots for skipping
"
^ #()
! !
!Object methodsFor:'error handling'!
appropriateDebugger:aSelector
"{ Pragma: +optSpace }"
"return an appropriate debugger to use.
If there is already a debugger active on the stack, and it is
the DebugView, return MiniDebugger (as a last chance) otherwise abort."
|context|
"DebugView cannot run without system processes"
(Processor isNil
or:[Processor activeProcessIsSystemProcess
or:[Smalltalk isInitialized not]]) ifTrue:[
^ MiniDebugger
].
(Screen isNil or:[Screen default isNil or:[Screen default isOpen not]]) ifTrue:[
Debugger isNil ifTrue:[^ nil].
^ MiniDebugger
].
context := thisContext.
context := context findNextContextWithSelector:aSelector or:nil or:nil.
[context notNil] whileTrue:[
((context receiver class == Debugger)
and:[context selector == aSelector]) ifTrue:[
"we are already in some Debugger"
(Debugger == MiniDebugger) ifTrue:[
"we are already in the MiniDebugger"
ErrorRecursion ifFalse:[
Smalltalk fatalAbort:'recursive error ...'
]
].
MiniDebugger isNil ifTrue:[
Smalltalk fatalAbort:'no debugger'
].
"ok, an error occured while in the graphical debugger;
lets try MiniDebugger"
^ MiniDebugger
].
context := context findNextContextWithSelector:aSelector or:nil or:nil.
].
"not within Debugger - no problem"
^ Debugger
"Modified: / 23.9.1996 / 12:14:52 / stefan"
"Modified: / 19.5.1999 / 18:05:00 / cg"
!
breakPoint:something
"{ Pragma: +optSpace }"
"Like halt, but disabled by default.
User may enable it.
Code with breakpoints may be even checked into the source repository"
"Example: nil breakPoint:#stefan"
"/ something = OperatingSystem getLoginName ifTrue:[
"/ ^ HaltSignal raiseRequestWith:something errorString:'Breakpoint encountered: ',
"/ something printString
"/ ].
!
cannotSendMessage:aMessage to:someReceiver
"this message is sent by the runtime system (VM),
when a message is sent to some object, whose class is not
a valid behavior (see documentation in Behavior)."
^ InternalErrorSignal
raiseWith:someReceiver
errorString:('bad class in send of #' , aMessage selector)
"Modified: 23.1.1997 / 00:05:39 / cg"
!
doesNotUnderstand:aMessage
"this message is sent by the runtime system (VM) when
a message is not understood by some object (i.e. there
is no method for that selector). The original message has
been packed into aMessage (i.e. the receiver, selector and
any arguments) and the original receiver is then sent the
#doesNotUnderstand: message.
Here, we raise another signal which usually enters the debugger.
You can of course redefine #doesNotUnderstand: in your classes
to implement message delegation,
or handle the MessageNotUnderstoodSignal gracefully."
<context: #return>
|sel selStr errorString cls|
sel := aMessage selector.
selStr := sel printString.
"/ Although sel should always be a symbol,
"/ always use printStrings in the code below.
"/ Non-symbol selector may happen when things go mad in a primitive,
"/ or a method has been called by valueWithReceiver: with a wrong arg.
"/ handle the case of an error during early startup
"/ (output streams not yet initialized)
Stdout isNil ifTrue:[
Smalltalk fatalAbort:'error during init: ' , selStr , ' not understood'.
].
"/
"/ extract the class that should have implemented the message.
"/ (in case of a super-send, this is not the receivers class)
"/
cls := thisContext sender searchClass.
cls isNil ifTrue:[
"it was NOT a super or directed send ..."
cls := self class
].
cls notNil ifTrue:[
"/
"/ displayString is better than 'cls name',
"/ since it appends (obsolete) for outdated classes.
"/ (this happens if you send messages to old instances
"/ after changing a classes definition)
"/
errorString := cls displayString.
] ifFalse:[
errorString := '(** nil-class **)'
].
sel class ~~ Symbol ifTrue:[
errorString := errorString , ' nonSymbol selector: ' , selStr , ' not understood'.
] ifFalse:[
errorString := errorString , ' does not understand: ' , selStr.
].
"/
"/ this only happens, when YOU play around with my classvars ...
"/ (or an error occurs during very early startup, when signals are not yet set)
"/
MessageNotUnderstood isNil ifTrue:[
^ MiniDebugger
enterWithMessage:'oops - MessageNotUnderstoodSignal is gone (nil)'
mayProceed:true.
].
"/
"/ thats where we end up normally - raise a signal which (if unhandled) opens a debugger
"/
^ MessageNotUnderstood
raiseRequestWith:aMessage
errorString:errorString
"Modified: / 9.6.1999 / 17:46:17 / cg"
!
elementBoundsError
"{ Pragma: +optSpace }"
"report an error that badElement is out of bounds
(i.e. cannot be put into that collection).
The error is reported by raising the ElementOutOfBoundsSignal exception."
^ ElementOutOfBoundsSignal raise
"Modified: 8.5.1996 / 09:12:45 / cg"
!
elementNotCharacter
"{ Pragma: +optSpace }"
"report an error that object to be stored is no Character.
(usually when storing into Strings).
The error is reported by raising the ElementOutOfBoundsSignal exception."
^ ElementOutOfBoundsSignal raise
"Modified: 8.5.1996 / 09:12:49 / cg"
!
elementNotInteger
"{ Pragma: +optSpace }"
"report an error that object to be stored is not Integer.
(in collections that store integers only).
The error is reported by raising the ElementOutOfBoundsSignal exception."
^ ElementOutOfBoundsSignal raise
"Modified: 8.5.1996 / 09:12:51 / cg"
!
error
"{ Pragma: +optSpace }"
<context: #return>
"report error that an error occured.
The error is reported by raising the Error exception,
which is non-proceedable.
If no handler has been setup, a debugger is entered."
Error raiseWith:#error:
"
nil error
"
"Modified: / 8.5.1996 / 09:13:01 / cg"
"Modified: / 2.8.1999 / 17:00:19 / stefan"
!
error:aString
"{ Pragma: +optSpace }"
<context: #return>
"Raise an error with error message aString.
The error is reported by raising the Error exception,
which is non-proceedable.
If no handler has been setup, a debugger is entered."
Error raiseWith:#error: errorString:aString
"
nil error:' bad bad bad'
"
"Modified: 8.5.1996 / 09:13:04 / cg"
!
error:aString mayProceed:mayProceed
"{ Pragma: +optSpace }"
"enter debugger with error-message aString.
The error is reported by raising either the
non-proceedable Error exception,
or the ProceedableError exception."
mayProceed ifTrue:[
^ ProceedableError raiseRequestWith:#error: errorString:aString
].
Error raiseWith:#error: errorString:aString
"Modified: 8.5.1996 / 09:13:04 / cg"
!
errorInvalidFormat
"{ Pragma: +optSpace }"
<context: #return>
"report an error that some conversion to/from string representation failed
typically when converting numbers, date, time etc."
^ ConversionError raiseErrorString:'invalid format'
!
errorKeyNotFound:aKey
"{ Pragma: +optSpace }"
"report an error that a key was not found in a collection.
The error is reported by raising the KeyNotFoundSignal exception."
^ KeyNotFoundSignal raiseRequestWith:aKey
"
#(1 2) at:3
"
!
errorNotFound
"{ Pragma: +optSpace }"
"report an error that no element was found in a collection.
The error is reported by raising the NotFoundSignal exception."
^ NotFoundSignal raiseRequestWith:nil
"Modified: / 8.5.1996 / 09:13:11 / cg"
"Modified: / 26.7.1999 / 10:51:50 / stefan"
!
errorNotFound:errorString
"{ Pragma: +optSpace }"
"report an error that no element was found in a collection.
The error is reported by raising the NotFoundSignal exception."
^ NotFoundError raiseErrorString:errorString
!
errorSignal
^ self class errorSignal
"Created: / 19.6.1998 / 02:32:32 / cg"
!
halt
"{ Pragma: +optSpace }"
"enter debugger with halt-message.
The error is reported by raising the HaltSignal exception."
(Smalltalk at:#IgnoreHalt ifAbsent:false) == true ifTrue:[^ self].
^ HaltInterrupt raiseRequestWith:#halt
"Modified: / 2.8.1999 / 17:00:29 / stefan"
"Modified: / 17.11.2001 / 22:47:44 / cg"
!
halt:aString
"{ Pragma: +optSpace }"
"enter debugger with halt-message.
The error is reported by raising the HaltSignal exception."
(Smalltalk at:#IgnoreHalt ifAbsent:false) == true ifTrue:[^ self].
^ HaltSignal raiseRequestWith:#halt: errorString:aString
"Modified: 8.5.1996 / 09:13:23 / cg"
!
implementedBySubclass
"{ Pragma: +optSpace }"
"this is sent by ST/V code - its the same as #subclassResponsibility"
^ self subclassResponsibility:'method must be reimplemented in ST/V subclass'
!
indexNotInteger
"{ Pragma: +optSpace }"
"report an error that index is not an Integer.
(when accessing collections indexed by an integer key).
The error is reported by raising the NonIntegerIndexSignal exception."
^ NonIntegerIndexSignal raiseRequestWith:nil
"Modified: / 8.5.1996 / 09:13:37 / cg"
"Modified: / 26.7.1999 / 10:57:43 / stefan"
!
indexNotInteger:anIndex
"{ Pragma: +optSpace }"
"report an error that index is not an Integer.
(when accessing collections indexed by an integer key).
The error is reported by raising the NonIntegerIndexSignal exception."
^ NonIntegerIndexSignal raiseRequestWith:anIndex
"Created: / 16.5.1998 / 19:39:41 / cg"
!
integerCheckError
"{ Pragma: +optSpace }"
"generated when a variable declared with an integer type gets a bad
value assigned"
^ self error:'bad assign of ' , self printString ,
' (' , self class name , ') to integer-typed variable'
!
invalidCodeObject
"{ Pragma: +optSpace }"
self error:'not an executable code object'
"Created: 1.8.1997 / 00:16:44 / cg"
!
invalidMessage
"{ Pragma: +optSpace }"
"this is sent by ST/V code - its the same as #shouldNotImplement"
^ self shouldNotImplement
!
mustBeRectangle
"{ Pragma: +optSpace }"
"report an argument-not-rectangle-error"
^ self error:'argument must be a Rectangle'
!
mustBeString
"{ Pragma: +optSpace }"
"report an argument-not-string-error"
^ self error:'argument must be a String'
!
notIndexed
"{ Pragma: +optSpace }"
<context: #return>
"report an error that receiver has no indexed instance variables.
The error is reported by raising the SubscriptOutOfBoundsSignal exception."
^ SubscriptOutOfBoundsSignal
raiseErrorString:'receiver has no indexed variables'
"Modified: 26.7.1996 / 16:43:13 / cg"
!
openDebuggerOnException:ex
"{ Pragma: +optSpace }"
"enter the debugger on some unhandled exception"
|msgString debugger answer|
msgString := ex errorString.
"
if there is no debugger,
ask for ignore or exit. Exit will terminate the applciation.
ignore will raise an abortSignal.
"
Debugger isNil ifTrue:[
msgString := 'Error: ' , msgString.
Smalltalk isStandAloneApp ifTrue:[
Dialog notNil ifTrue:[
AbortSignal isHandled ifTrue:[
answer := OptionBox
request:msgString
label:msgString
buttonLabels:#('Ignore' 'Abort' 'Exit')
values:#(#ignore #abort #exit)
default:#exit.
] ifFalse:[
answer := OptionBox
request:msgString
label:msgString
buttonLabels:#('Ignore' 'Exit')
values:#(#ignore #exit)
default:#exit.
].
answer == #abort ifTrue:[
^ AbortSignal raise
].
answer == #ignore ifTrue:[
^ nil
].
].
"/ dont output the message, if its a CTRL-C (userInterrupt)
ex signal == NoHandlerError ifTrue:[
ex parameter signal == UserInterrupt ifTrue:[
OperatingSystem exit:130
].
].
msgString errorPrintCR.
OperatingSystem exit:1
].
msgString errorPrintCR.
Smalltalk fatalAbort:'no Debugger defined'
].
"
find an appropriate debugger to use
"
debugger := self appropriateDebugger:(thisContext selector).
debugger isNil ifTrue:[
^ AbortSignal raise
].
^ debugger
enter:ex suspendedContext
withMessage:msgString
mayProceed:(ex mayProceed).
"Modified: 24.7.1997 / 10:09:20 / cg"
!
primitiveFailed
"{ Pragma: +optSpace }"
"report an error that some primitive code failed.
The error is reported by raising the PrimitiveFailureSignal exception."
^ PrimitiveFailureSignal raiseRequestWith:nil
"
1234 primitiveFailed
"
"Modified: / 8.5.1996 / 09:14:07 / cg"
"Modified: / 26.7.1999 / 10:58:08 / stefan"
!
primitiveFailed:messageString
"{ Pragma: +optSpace }"
"report an error that some primitive code failed.
The error is reported by raising the PrimitiveFailureSignal exception."
^ PrimitiveFailureSignal raiseRequestWith:nil errorString:messageString
"
1234 primitiveFailed:'this is a test'
"
!
shouldImplement
"{ Pragma: +optSpace }"
"report an error that this message should be implemented.
This is send by automatically generated method bodies"
^ self error:'method not yet implemented by class'
!
shouldNotImplement
"{ Pragma: +optSpace }"
"report an error that this message should not be implemented"
^ self error:'method not appropriate for this class'
"Modified: 8.5.1996 / 09:09:44 / cg"
!
subclassResponsibility
"{ Pragma: +optSpace }"
"report an error that this message should have been reimplemented in a
subclass"
^ self class subclassResponsibilitySignal
raiseRequestErrorString:'method must be reimplemented in subclass'
!
subclassResponsibility:msg
"{ Pragma: +optSpace }"
"report an error that this message should have been reimplemented in a subclass"
^ Object subclassResponsibilitySignal
raiseRequestErrorString:msg
!
subscriptBoundsError
"{ Pragma: +optSpace }"
"report an error that some index is out of bounds.
(when accessing indexable collections).
The error is reported by raising the SubscriptOutOfBoundsSignal exception."
^ SubscriptOutOfBoundsSignal raiseRequestWith:nil
"Modified: / 26.7.1996 / 16:45:42 / cg"
"Modified: / 26.7.1999 / 10:58:27 / stefan"
!
subscriptBoundsError:anIndex
"{ Pragma: +optSpace }"
"report an error that anIndex is out of bounds.
(when accessing indexable collections).
The error is reported by raising the SubscriptOutOfBoundsSignal exception."
^ SubscriptOutOfBoundsError
raiseRequestWith:anIndex
errorString:('subscript (' , anIndex printString , ') out of bounds')
"Modified: / 17.11.2001 / 22:49:56 / cg"
!
typeCheckError
"{ Pragma: +optSpace }"
"generated when a variable declared with a type hint gets a bad
value assigned"
^ self error:'bad assign of ' , self printString ,
' (' , self class name , ') to typed variable'
! !
!Object methodsFor:'evaluation'!
value
"return the receiver itself.
This allows every object to be used where blocks or valueHolders
are typically used, and allows for valueHolders and blocks to be
used interchangably in some situations.
Time will show, if this is a good idea or leads to sloppy programming
style ... (the idea was borrowed from the Self language).
WARNING: dont 'optimize' away ifXXX: blocks
(i.e. do NOT replace
foo ifTrue:[var1] ifFalse:[var2]
by:
foo ifTrue:var1 ifFalse:var2
)
- the compilers will only generate inline code for the if,
iff the argument(s) are blocks - otherwise, a true send is
generated.
This 'oprimization' will work semantically correct,
but execute SLOWER instead."
^ self
"
#(1 2 3 4) indexOf:5 ifAbsent:0
#(1 2 3 4) indexOf:5 ifAbsent:[0]
1 > 2 ifTrue:['yes'] ifFalse:['no']
1 > 2 ifTrue:'yes' ifFalse:'no'
"
"DO NOT DO THIS (its slower)
(1 > 4) ifTrue:'oops' ifFalse:'ok'
USE (the compiler optimizes blocks in if/while):
(1 > 4) ifTrue:['oops'] ifFalse:['ok']
"
"Modified: 3.5.1996 / 11:57:08 / cg"
! !
!Object methodsFor:'finalization'!
disposed
"OBSOLETE INTERFACE: use #finalize
this is invoked for objects which have been registered
in a Registry, when the original object dies.
Subclasses may redefine this method"
<resource: #obsolete>
^ self
!
executor
"Return the object which does the finalization for me.
This interface is also VW & Sqeak compatible,"
"for now, send #shallowCopyForFinalization, to be compatible with
classes designed for old ST/X versions"
^ self shallowCopyForFinalization
!
finalizationLobby
"answer a Registry used for finalization.
Use a generic Registry for any object.
Subclasses using their own Registry should redefine this"
^ FinalizationLobby
!
finalize
"this is invoked for executor objects which have been registered
in a Registry, when the original object dies.
Subclasses may redefine this method
This interface is also VW-compatible"
"send #disposed for compatibility with existing classes that still
implement the obsolete #disposed message"
^ self disposed
!
reRegisterForFinalization
"re-register mySelf for later finalization.
This will create a new executor, which will receive a #finalize message when
the receiver is garbage collected."
self finalizationLobby registerChange:self
!
registerForFinalization
"register mySelf for later finalization.
Once registered, the executor of the receiver will receive a #finalize message when
the receiver is garbage collected."
self finalizationLobby register:self
!
shallowCopyForFinalization
"OBSOLETE INTERFACE: use #executor.
This is used to aquire a copy to be used for finalization -
(the copy will be sent a #finalize message; see the documentation in the Registry class)
This method can be redefined for more efficient copying - especially for large objects."
<resource: #obsolete>
^ self shallowCopy
!
unregisterForFinalization
"unregister mySelf from later finalization"
self finalizationLobby unregister:self
! !
!Object methodsFor:'initialization'!
initialize
"just to ignore initialize to objects which do not need it"
^ self
! !
!Object methodsFor:'interest'!
addInterest:anInterest
"install an interest forwarder.
Here, we use the nonWeakDependencies."
self addNonWeakDependent:anInterest
"Created: 14.10.1996 / 22:27:34 / stefan"
!
expressInterestIn:aspect for:anObject sendBack:aSelector
"arrange for aSelector to be sent to anObject whenever the receiver
changes aspect."
"/ for now, use an interestConverter, which is somewhat less efficient.
"/ In the future, a more intelligent DependencyCollection class is planned for
self addInterest:(InterestConverter
destination:anObject
selector:aSelector
aspect:aspect)
"
|p b|
b := [Transcript showCR:' -> the point changed'].
p := Point new.
Transcript showCR:'interest in #foo:'.
p expressInterestIn:#foo for:b sendBack:#value.
p x:1.
Transcript showCR:'now changing #bar ... (expect no notification)'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'now changing #foo ... (expect notification)'.
p changed:#foo.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interest in #foo:'.
p retractInterestIn:#foo for:b.
Transcript showCR:'now changing #foo ... (expect no notification)'.
p changed:#foo.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest in #bar now:'.
p expressInterestIn:#bar for:b sendBack:#value.
Transcript showCR:'now changing #foo ... (expect no notification)'.
p changed:#foo.
Transcript showCR:'now changing #bar ... (expect notification)'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest in #foo now:'.
p expressInterestIn:#foo for:b sendBack:#value.
Transcript showCR:'now changing #foo ... (expect notification)'.
p changed:#foo.
Transcript showCR:'now changing #bar ... (expect notification)'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interests:'.
p retractInterestsFor:b.
Transcript showCR:'now changing #foo ... (expect no notification)'.
p changed:#foo.
Transcript showCR:'now changing #bar... (expect no notification)'.
p changed:#bar.
Transcript cr.
p release.
"
"Created: 19.4.1996 / 10:26:22 / cg"
"Modified: 19.4.1996 / 12:34:08 / cg"
"Modified: 14.10.1996 / 22:28:20 / stefan"
!
interests
"return a Collection of interests - empty if there is none.
Here, we use the nonWeakDependents for interests."
^ self nonWeakDependents
"Created: / 14.10.1996 / 22:20:51 / stefan"
"Modified: / 30.1.1998 / 14:07:35 / cg"
!
interestsFor:someOne
"return a collection of interests of someOne - empty if there is none."
|coll deps|
deps := self interests.
deps size == 0 ifTrue:[^ #()].
coll := IdentitySet new.
deps do:[:dep |
(dep isMemberOf:InterestConverter) ifTrue:[
dep destination == someOne ifTrue:[
coll add:dep.
]
]
].
^ coll
"Created: / 30.1.1998 / 14:02:26 / cg"
"Modified: / 30.1.1998 / 14:08:24 / cg"
!
onChangeEvaluate:aBlock
"arrange for aBlock to be evaluated whenever the receiver changes."
^ self onChangeSend:#value to:aBlock
"Created: / 29.1.1999 / 16:01:22 / cg"
!
onChangeSend:aSelector to:anObject
"arrange for aSelector to be sent to anObject whenever the receiver
changes."
"/ for now, use an interestConverter, which is somewhat less efficient.
"/ In the future, a more intelligent DependencyCollection class is planned for
self addInterest:(InterestConverter
destination:anObject
selector:aSelector)
"
|p b|
b := [Transcript showCR:'the point changed'].
p := Point new.
p onChangeSend:#value to:b.
p x:1.
Transcript showCR:'now changing'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'now changing'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interest'.
p retractInterestsFor:b.
Transcript showCR:'now changing again'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest again'.
p onChangeSend:#value to:b.
Transcript showCR:'now changing again'.
p changed.
Transcript cr.
"
"Created: 19.4.1996 / 10:26:38 / cg"
"Modified: 19.4.1996 / 12:34:26 / cg"
"Modified: 14.10.1996 / 22:28:27 / stefan"
!
removeInterest:anInterest
"remove an interest forwarder.
Here, we use the nonWeakDependencies."
self removeNonWeakDependent:anInterest
"Created: 14.10.1996 / 22:21:59 / stefan"
!
retractInterestIn:aspect for:someOne
"remove the interest of someOne in the receiver changing aspect
(as installed with #expressInterestIn:for:sendBack:)."
"/ for now, remove the interestConverter.
"/ In the future, a more intelligent DependencyCollection class is planned for
"/ cannot removeDependent within the loop - the collection rehashes
|deps coll|
deps := self interests.
deps size ~~ 0 ifTrue:[
coll := IdentitySet new.
deps do:[:dep |
(dep isMemberOf:InterestConverter) ifTrue:[
dep destination == someOne ifTrue:[
dep aspect == aspect ifTrue:[
self removeInterest:dep.
^ self
]
]
]
].
coll do:[:dep |
self removeInterest:dep.
].
].
"
|p b|
b := [Transcript showCR:'the point changed'].
p := Point new.
Transcript showCR:'interest in #foo'.
p expressInterestIn:#foo for:b sendBack:#value.
p x:1.
Transcript showCR:'now changing #bar'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'now changing #foo'.
p changed:#foo.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interest in #foo'.
p retractInterestIn:#foo for:b.
Transcript showCR:'now changing #foo'.
p changed:#foo.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest in #bar now'.
p expressInterestIn:#bar for:b sendBack:#value.
Transcript showCR:'now changing #foo'.
p changed:#foo.
Transcript showCR:'now changing #bar'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest in #foo now'.
p expressInterestIn:#foo for:b sendBack:#value.
Transcript showCR:'now changing #foo'.
p changed:#foo.
Transcript showCR:'now changing #bar'.
p changed:#bar.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interests'.
p retractInterestsFor:b.
Transcript showCR:'now changing #foo'.
p changed:#foo.
Transcript showCR:'now changing #bar'.
p changed:#bar.
Transcript cr.
"
"Created: / 19.4.1996 / 10:27:11 / cg"
"Modified: / 14.10.1996 / 22:21:19 / stefan"
"Modified: / 30.1.1998 / 14:05:34 / cg"
!
retractInterestsFor:someOne
"remove the interest of someOne in the receiver
(as installed with #onChangeSend:to:)."
"/ for now, remove the interestConverter.
"/ In the future, a more intelligent DependencyCollection class is planned for
|coll deps|
"/ cannot removeDependent within the loop - the collection rehashes
deps := self interests.
deps size ~~ 0 ifTrue:[
coll := IdentitySet new.
deps do:[:dep |
(dep isMemberOf:InterestConverter) ifTrue:[
dep destination == someOne ifTrue:[
coll add:dep.
]
]
].
coll do:[:dep |
self removeInterest:dep.
].
].
"
|p b|
b := [Transcript showCR:'the point changed'].
p := Point new.
p onChangeSend:#value to:b.
p x:1.
Transcript showCR:'now changing'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'now changing'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'no more interest'.
p retractInterestsFor:b.
Transcript showCR:'now changing again'.
p changed.
Transcript cr.
Delay waitForSeconds:1.
Transcript showCR:'interest again'.
p onChangeSend:#value to:b.
Transcript showCR:'now changing again'.
p changed.
Transcript cr.
"
"Created: / 19.4.1996 / 10:23:46 / cg"
"Modified: / 14.10.1996 / 22:21:25 / stefan"
"Modified: / 30.1.1998 / 14:04:52 / cg"
! !
!Object methodsFor:'interrupt handling'!
childSignalInterrupt
"death of a child process (unix process) - do nothing"
^ self
!
customInterrupt
"{ Pragma: +optSpace }"
"a custom interrupt - but no handler has defined"
self error:'custom interrupt' mayProceed:true
!
errorInterrupt:errorID with:aParameter
"subsystem error. The arguments errorID and aParameter are the values passed
to the 'errorInterruptWithIDAndParameter(id, param)' function,
which can be called from C subsystems to raise an (asynchronous)
error exception.
Currently, this is used to map XErrors to smalltalk errors, but can be
used from other C subsystems too, to upcast errors.
Especially, for subsystems which call errorHandler functions asynchronously.
IDs (currently) used:
#DisplayError ..... x-error interrupt
#XtError ..... xt-error interrupt (Xt interface is not yet published)
"
|handlers handler|
handlers := ObjectMemory registeredErrorInterruptHandlers.
handlers notNil ifTrue:[
handler := handlers at:errorID ifAbsent:nil.
handler notNil ifTrue:[
"/
"/ handler found; let it do whatever it wants ...
"/
handler errorInterrupt:errorID with:aParameter.
^ self
].
].
"/
"/ no handler - raise errorSignal passing the errorId as parameter
"/
^ ErrorSignal
raiseRequestWith:errorID
errorString:('Subsystem error. ErrorID = ' , errorID printString)
!
exceptionInterrupt
"{ Pragma: +optSpace }"
"exception interrupt - enter debugger"
self error:'exception Interrupt' mayProceed:true
!
fpExceptionInterrupt
"{ Pragma: +optSpace }"
"a floating point exception occured - this one
has to be handled differently since it comes asynchronous
on some machines (for example, on machines with a separate FPU
or superscalar architectures. Also, errors from within primitive code
(or library functions such as GL) are sent via the Unix-signal
mechanism this way."
|where rec|
where := thisContext sender.
rec := where receiver.
rec isNumber ifTrue:[
^ rec class
raise:#domainErrorSignal
receiver:rec
selector:where selector
arguments:(where args asArray)
errorString:'floating point exception'
].
"/ could be in some C-library ...
^ Float domainErrorSignal raise
!
internalError:msg
"{ Pragma: +optSpace }"
"this is triggered, when VM hits some bad error,
such as corrupted class, corrupted method/selector array
etc. The argument string gives some more information on what happened.
(for example, if you set an objects class to a non-behavior, nil etc.).
Its not guaranteed, that the system is in a working condition once
this error occurred ...."
InternalErrorSignal raiseWith:self errorString:msg
!
ioInterrupt
"{ Pragma: +optSpace }"
"I/O (SIGIO/SIGPOLL) interrupt (supposed to be sent to Processor).
If we arrive here, there is either no handler (ObjMem>>ioInterruptHandler)
or it does not understand the ioInterrupt message.
In any case, this is a sign of some big trouble. Enter debugger."
self error:'I/O Interrupt - but no handler' mayProceed:true
!
memoryInterrupt
"{ Pragma: +optSpace }"
"out-of-memory interrupt and no handler - enter debugger"
self error:'almost out of memory' mayProceed:true
!
recursionInterrupt
"{ Pragma: +optSpace }"
"recursion limit (actually: stack overflow) interrupt.
This interrupt is triggered, when a process stack grows above
its stackLimit - usually, this leads into the debugger, but
could be caught.
Under Unix, the stackLimit may be increased in the handler,
and the exception can be resumed.
Sorry, but under win32, the stack cannot grow, and the exception
is not proceedable.
At the time we arrive here, the system has still some stack
as a reserve so we can continue to do some useful work, or cleanup,
or debug for a while.
If the signal is ignored, and the stack continues to grow, there
will be a few more chances (and more interrupts) before the VM
terminates the process."
|con remaining|
(con := thisContext) isRecursive ifFalse:[
"/ Processor activeProcess usedStackSize < Processor activeProcess maximumStackSize ifTrue:[
"/ "/ mhmh - it hit me, but I am not responsible ...
"/ 'Stray recursionInterrupt ...' infoPrintCR.
"/ ^ self
"/ ].
ObjectMemory infoPrinting ifTrue:[
'Object [info]: recursionInterrupt from:' printCR.
con := con sender.
remaining := 50.
[con notNil and:[remaining > 0]] whileTrue:[
'| ' print. con fullPrint.
con := con sender.
remaining := remaining - 1
].
].
^ RecursionInterruptSignal raiseSignal
]
"Modified: / 10.11.2001 / 15:15:56 / cg"
!
schedulerInterrupt
"{ Pragma: +optSpace }"
"scheduler interrupt (supposed to be sent to Processor).
If we arrive here, either the Processor does not understand it,
or it has been set to nil. In any case, this is a sign of some
big trouble. Enter debugger."
self error:'schedulerInterrupt - but no Processor' mayProceed:true
!
signalInterrupt:signalNumber
"{ Pragma: +optSpace }"
"unix signal occured - some signals are handled as Smalltalk Exceptions
(SIGPIPE), others (SIGBUS) are rather fatal ...
In any case, IF a smalltalk-signal has been connected to the OS signal,
that one is raised.
Otherwise, a dialog is shown, asking the user on how to handle the
signal.
TODO: add another argument, giving more detailed signal info (PC, VADDR,
exact cause etc.). This helps if segvs occur in primitive code.
Currently (temporary kludge), these are passed as global variables."
|name here sig fatal titles actions badContext msg pc addr
action title screen|
"if there has been an ST-signal installed, use it ..."
sig := OperatingSystem operatingSystemSignal:signalNumber.
sig notNil ifTrue:[
sig raise.
^ self.
].
"/ if handled, raise OSSignalInterruptSignal
OSSignalInterruptSignal isHandled ifTrue:[
OSSignalInterruptSignal raiseRequestWith:signalNumber.
^ self.
].
"
special case - SIGPWR/SIGHUP: write a crash image
"
(signalNumber == 30 "OperatingSystem sigPWR"
or:[signalNumber == 1 "OperatingSystem sigHUP"]) ifTrue:[
ObjectMemory snapShotOn:'crash.img'.
^ self.
].
name := OperatingSystem nameForSignal:signalNumber.
here := thisContext.
badContext := here sender. "the context, in which the signal occurred"
"if there is no screen at all, bring up a mini debugger"
(Screen isNil
or:[(screen := Screen current) isNil
or:[(screen := Screen default) isNil
or:[screen isOpen not]]]) ifTrue:[
^ self startMiniDebuggerOrExit:'Signal (' , name, ')'.
].
"ungrab - in case it happened in a box/popupview
otherwise display stays locked"
screen ungrabPointer; ungrabKeyboard.
"there is a screen. use it to bring up a box asking for what to do ..."
Screen currentScreenQuerySignal answer:screen do:[
"
SIGBUS, SIGSEGV and SIGILL do not make sense to ignore (i.e. continue)
since the system will retry the faulty instruction, which leads to
another signal - to avoid frustration, better not offer this option.
"
fatal := OperatingSystem isFatalSignal:signalNumber.
fatal ifTrue:[
(Debugger isNil or:[here isRecursive]) ifTrue:[
'Object [hard error]: signal ' errorPrint. signalNumber errorPrintCR.
^ self startMiniDebuggerOrExit:'Signal (' , name, ')'.
].
"
a hard signal - go into debugger immediately
"
msg := 'OS-signal: ', name.
"/ the IRQ-PC is passed as low-hi, to avoid the need
"/ to allocate a LargeInteger in the VM during signal
"/ time. I know, this is ugly.
InterruptPcLow notNil ifTrue:[
pc := InterruptPcLow + (InterruptPcHi bitShift:(SmallInteger maxBits + 1 // 2)).
pc ~~ 0 ifTrue:[
msg := msg , ' PC=' , (pc printStringRadix:16)
].
].
InterruptAddrLow notNil ifTrue:[
addr := InterruptAddrLow + (InterruptAddrHi bitShift:(SmallInteger maxBits + 1 // 2)).
addr ~~ 0 ifTrue:[
msg := msg , ' ADDR=' , (addr printStringRadix:16)
].
].
Debugger enter:here withMessage:msg mayProceed:false.
"unreachable"
^ nil.
].
"if possible, open an option box asking the user what do.
Otherwise, start a debugger"
Dialog notNil ifTrue:[
titles := #('save crash image' 'dump core' 'exit ST/X' 'debug').
actions := #(save core exit debug).
action := nil.
title := 'OS Signal caught (' , name, ')'.
title := (title , '\[in ST-process: ' , Processor activeProcess nameOrId ,']') withCRs.
"/ if cought while in the scheduler or event dispatcher,
"/ a modal dialog is not possible ...
"/ (therefore, abort & return does not makes sense)
Processor activeProcess isSystemProcess ifFalse:[
titles := #('abort') , titles.
actions := #(abort), actions.
badContext canReturn ifTrue:[
titles := #('return') , titles.
actions := #(return), actions.
].
].
fatal ifFalse:[
titles := titles, #('ignore').
actions := actions , #(ignore).
].
action := Dialog choose:title
labels:titles
values:actions
default:(fatal ifTrue:[nil] ifFalse:[#ignore]).
"Dialog may fail (if system process), default action is debug"
action size == 0 ifTrue:[action := #debug].
] ifFalse:[
action := #debug.
].
action == #save ifTrue:[
ObjectMemory snapShotOn:'crash.img'
].
action == #core ifTrue:[
Smalltalk fatalAbort
].
action == #exit ifTrue:[
Smalltalk exit
].
action == #return ifTrue:[
badContext return
].
action == #abort ifTrue:[
AbortSignal raise.
].
action == #debug ifTrue:[
Debugger isNil ifTrue:[
^ self startMiniDebuggerOrExit:'Signal (' , name, ')'.
].
Debugger enter:here withMessage:('Signal ', name) mayProceed:true.
].
"action == #ignore"
].
!
spyInterrupt
"{ Pragma: +optSpace }"
"spy interrupt and no handler - enter debugger"
self error:'spy Interrupt - but no handler' mayProceed:true
!
startMiniDebuggerOrExit:text
"some critical condition happened.
Start a mini debugger or exit if none is present"
MiniDebugger isNil ifTrue:[
"a system without debugging facilities (i.e. a standalone system)
output a message and exit."
('Object [error]: exit due to ', text, ' - and no debugger.') errorPrintCR.
OperatingSystem exit:99.
].
MiniDebugger enterWithMessage:text mayProceed:true.
!
timerInterrupt
"{ Pragma: +optSpace }"
"timer interrupt and no handler - enter debugger"
self error:'timer Interrupt - but no handler' mayProceed:true
!
userInterrupt
"{ Pragma: +optSpace }"
"user (^c) interrupt.
This is typically sent by the VM, when a ctrl-C is typed at the
controlling tty (i.e. in the xterm)."
UserInterruptSignal raiseRequest
!
userInterruptIn:aContext
"{ Pragma: +optSpace }"
"user (^c) interrupt - enter debugger, but show aContext
as top-context.
This is used to hide any intermediate scheduler contexts,
in case of an interrupted process. Typically, this is sent by
the WindowGroup, when a keyboardEvent for the ctrl-C key is
processed."
<context: #return>
UserInterruptSignal raiseRequestWith:nil errorString:nil in:aContext
"Created: / 18.10.1996 / 20:46:04 / cg"
"Modified: / 20.10.1996 / 13:06:38 / cg"
"Modified: / 26.7.1999 / 10:58:49 / stefan"
! !
!Object methodsFor:'message sending'!
perform:aSelector
"send the message aSelector to the receiver"
%{
REGISTER OBJ sel = aSelector;
if (InterruptPending == nil) {
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF0(@line);
static struct inlineCache ilc_1 = __ILCPERF0(@line);
static struct inlineCache ilc_2 = __ILCPERF0(@line);
static struct inlineCache ilc_3 = __ILCPERF0(@line);
static struct inlineCache ilc_4 = __ILCPERF0(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static OBJ last_2 = nil;
static OBJ last_3 = nil;
static OBJ last_4 = nil;
static flip = 0;
if (sel == last_0) {
pIlc = &ilc_0;
} else if (sel == last_1) {
pIlc = &ilc_1;
} else if (sel == last_2) {
pIlc = &ilc_2;
} else if (sel == last_3) {
pIlc = &ilc_3;
} else if (sel == last_4) {
pIlc = &ilc_4;
} else {
if (flip == 0) {
pIlc = &ilc_0;
flip = 1;
last_0 = sel;
} else if (flip == 1) {
pIlc = &ilc_1;
flip = 2;
last_1 = sel;
} else if (flip == 2) {
pIlc = &ilc_2;
flip = 3;
last_2 = sel;
} else if (flip == 3) {
pIlc = &ilc_3;
flip = 4;
last_3 = sel;
} else {
pIlc = &ilc_4;
flip = 0;
last_4 = sel;
}
pIlc->ilc_func = __SEND0ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ( (*(pIlc->ilc_func))(self, sel, nil, pIlc) );
} else {
static struct inlineCache ilc0 = __DUMMYILCSELF0(@line+1);
RETURN (_SEND0(self, aSelector, nil, &ilc0));
}
%}.
^ self perform:aSelector withArguments:#()
!
perform:aSelector inClass:aClass withArguments:argArray
"send the message aSelector with all args taken from argArray
to the receiver as a super-send message.
This is actually more flexible than the normal super-send, since it allows
to execute a method in ANY superclass of the receiver (not just the
immediate superclass).
Thus, it is (theoretically) possible to do
'5 perform:#< inClass:Magnitude withArguments:#(6)'
and evaluate Magnitudes compare method even if there was one in Number.
This method is used by the interpreter to evaluate super sends
and could be used for very special behavior (language extension ?).
WARNING: this is an ST/X feature - probably not found in other smalltalks."
|numberOfArgs a1 a2 a3 a4 a5 a6 a7 a8 a9 a10 a11 a12 a13 a14 a15 myClass|
"
check, if aClass is really a superclass of the receiver
"
myClass := self class.
(myClass == aClass or:[myClass isSubclassOf:aClass]) ifFalse:[
self error:'lookup-class argument is not a superclass of the receiver'.
^ nil
].
%{
REGISTER OBJ *argP;
int nargs, i;
if (__isArray(argArray)) {
nargs = __arraySize(argArray);
argP = __arrayVal(argArray);
} else {
if (__isNonNilObject(argArray)) {
static struct inlineCache ilcSize = __ILC0(@line+1);
numberOfArgs = (*ilcSize.ilc_func)(argArray, @symbol(size), nil, &ilcSize);
if (!__isSmallInteger(numberOfArgs))
goto bad;
nargs = __intVal(numberOfArgs);
argP = (OBJ *)(&a1);
for (i=1; i <= nargs; i++) {
*argP++ = __AT_(argArray, __MKSMALLINT((INT)i));
}
argP = (OBJ *)(&a1);
} else {
nargs = 0;
}
}
switch (nargs) {
case 0:
{
static struct inlineCache ilc0 = __DUMMYILCSELF0(@line+1);
RETURN ( _SEND0(self, aSelector, aClass, &ilc0));
}
case 1:
{
static struct inlineCache ilc1 = __DUMMYILCSELF1(@line+1);
RETURN ( _SEND1(self, aSelector, aClass, &ilc1, argP[0]));
}
case 2:
{
static struct inlineCache ilc2 = __DUMMYILCSELF2(@line+1);
RETURN ( _SEND2(self, aSelector, aClass, &ilc2, argP[0], argP[1]));
}
case 3:
{
static struct inlineCache ilc3 = __DUMMYILCSELF3(@line+1);
RETURN ( _SEND3(self, aSelector, aClass, &ilc3,
argP[0], argP[1], argP[2]));
}
case 4:
{
static struct inlineCache ilc4 = __DUMMYILCSELF4(@line+1);
RETURN ( _SEND4(self, aSelector, aClass, &ilc4,
argP[0], argP[1], argP[2], argP[3]));
}
case 5:
{
static struct inlineCache ilc5 = __DUMMYILCSELF5(@line+1);
RETURN ( _SEND5(self, aSelector, aClass, &ilc5,
argP[0], argP[1], argP[2], argP[3], argP[4]));
}
case 6:
{
static struct inlineCache ilc6 = __DUMMYILCSELF6(@line+1);
RETURN ( _SEND6(self, aSelector, aClass, &ilc6,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5]));
}
case 7:
{
static struct inlineCache ilc7 = __DUMMYILCSELF7(@line+1);
RETURN ( _SEND7(self, aSelector, aClass, &ilc7,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6]));
}
case 8:
{
static struct inlineCache ilc8 = __DUMMYILCSELF8(@line+1);
RETURN ( _SEND8(self, aSelector, aClass, &ilc8,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7]));
}
case 9:
{
static struct inlineCache ilc9 = __DUMMYILCSELF9(@line+1);
RETURN ( _SEND9(self, aSelector, aClass, &ilc9,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8]));
}
case 10:
{
static struct inlineCache ilc10 = __DUMMYILCSELF10(@line+1);
RETURN ( _SEND10(self, aSelector, aClass, &ilc10,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9]));
}
case 11:
{
static struct inlineCache ilc11 = __DUMMYILCSELF11(@line+1);
RETURN ( _SEND11(self, aSelector, aClass, &ilc11,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10]));
}
case 12:
{
static struct inlineCache ilc12 = __DUMMYILCSELF12(@line+1);
RETURN ( _SEND12(self, aSelector, aClass, &ilc12,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11]));
}
case 13:
{
static struct inlineCache ilc13 = __DUMMYILCSELF13(@line+1);
RETURN ( _SEND13(self, aSelector, aClass, &ilc13,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11], argP[12]));
}
case 14:
{
static struct inlineCache ilc14 = __DUMMYILCSELF14(@line+1);
RETURN ( _SEND14(self, aSelector, aClass, &ilc14,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11], argP[12], argP[13]));
}
case 15:
{
static struct inlineCache ilc15 = __DUMMYILCSELF15(@line+1);
RETURN ( _SEND15(self, aSelector, aClass, &ilc15,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11], argP[12], argP[13], argP[14]));
}
#ifdef _SEND16
case 16:
{
static struct inlineCache ilc16 = __DUMMYILCSELF16(@line+1);
RETURN ( _SEND16(self, aSelector, aClass, &ilc15,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11], argP[12], argP[13], argP[14], argP[15]));
}
#endif
#ifdef _SEND17
case 17:
{
static struct inlineCache ilc17 = __DUMMYILCSELF17(@line+1);
RETURN ( _SEND17(self, aSelector, aClass, &ilc15,
argP[0], argP[1], argP[2], argP[3], argP[4], argP[5],
argP[6], argP[7], argP[8], argP[9], argP[10],
argP[11], argP[12], argP[13], argP[14], argP[15], argP[16]));
}
#endif
}
bad:;
%}.
"/ arrive here, if bad number of arguments (too many)
"/ ST/X (currently) only allows up to 15 method arguments
^ self primitiveFailed
!
perform:aSelector with:arg
"send the one-arg-message aSelector to the receiver"
%{
REGISTER OBJ sel = aSelector;
if (InterruptPending == nil) {
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF1(@line);
static struct inlineCache ilc_1 = __ILCPERF1(@line);
static struct inlineCache ilc_2 = __ILCPERF1(@line);
static struct inlineCache ilc_3 = __ILCPERF1(@line);
static struct inlineCache ilc_4 = __ILCPERF1(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static OBJ last_2 = nil;
static OBJ last_3 = nil;
static OBJ last_4 = nil;
static flip = 0;
if (sel == last_0) {
pIlc = &ilc_0;
} else if (sel == last_1) {
pIlc = &ilc_1;
} else if (sel == last_2) {
pIlc = &ilc_2;
} else if (sel == last_3) {
pIlc = &ilc_3;
} else if (sel == last_4) {
pIlc = &ilc_4;
} else {
if (flip == 0) {
pIlc = &ilc_0;
flip = 1;
last_0 = sel;
} else if (flip == 1) {
pIlc = &ilc_1;
flip = 2;
last_1 = sel;
} else if (flip == 2) {
pIlc = &ilc_2;
flip = 3;
last_2 = sel;
} else if (flip == 3) {
pIlc = &ilc_3;
flip = 4;
last_3 = sel;
} else {
pIlc = &ilc_4;
flip = 0;
last_4 = sel;
}
pIlc->ilc_func = __SEND1ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ( (*(pIlc->ilc_func))(self, sel, nil, pIlc, arg) );
} else {
static struct inlineCache ilc1 = __DUMMYILCSELF1(@line+1);
RETURN (_SEND1(self, aSelector, nil, &ilc1, arg));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg)
!
perform:aSelector with:arg1 with:arg2
"send the two-arg-message aSelector to the receiver"
%{
struct inlineCache *pIlc;
if (InterruptPending == nil) {
static struct inlineCache ilc_0 = __ILCPERF2(@line);
static struct inlineCache ilc_1 = __ILCPERF2(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static flip = 0;
if (aSelector == last_0) {
pIlc = &ilc_0;
} else if (aSelector == last_1) {
pIlc = &ilc_1;
} else {
if (flip == 0) {
pIlc = &ilc_0;
flip = 1;
last_0 = aSelector;
} else {
pIlc = &ilc_1;
flip = 0;
last_1 = aSelector;
}
pIlc->ilc_func = __SEND2ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ( (*(pIlc->ilc_func))(self, aSelector, nil, pIlc, arg1, arg2) );
} else {
static struct inlineCache ilc2 = __DUMMYILCSELF2(@line+1);
RETURN (_SEND2(self, aSelector, nil, &ilc2, arg1, arg2));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg1 with:arg2)
!
perform:aSelector with:arg1 with:arg2 with:arg3
"send the three-arg-message aSelector to the receiver"
%{
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF3(@line);
static struct inlineCache ilc_1 = __ILCPERF3(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static flip = 0;
if (InterruptPending == nil) {
if (aSelector != last_0) {
if (aSelector != last_1) {
if (flip) {
pIlc = &ilc_0;
flip = 0;
last_0 = aSelector;
} else {
pIlc = &ilc_1;
flip = 1;
last_1 = aSelector;
}
pIlc->ilc_func = __SEND3ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
} else {
pIlc = &ilc_1;
}
} else {
pIlc = &ilc_0;
}
RETURN ( (*(pIlc->ilc_func))(self, aSelector, nil, pIlc, arg1, arg2, arg3) );
} else {
static struct inlineCache ilc3 = __DUMMYILCSELF3(@line+1);
RETURN (_SEND3(self, aSelector, nil, &ilc3, arg1, arg2, arg3));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg1 with:arg2 with:arg3)
!
perform:aSelector with:arg1 with:arg2 with:arg3 with:arg4
"send the four-arg-message aSelector to the receiver"
%{
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF4(@line);
static struct inlineCache ilc_1 = __ILCPERF4(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static flip = 0;
if (InterruptPending == nil) {
if (aSelector != last_0) {
if (aSelector != last_1) {
if (flip) {
pIlc = &ilc_0;
flip = 0;
last_0 = aSelector;
} else {
pIlc = &ilc_1;
flip = 1;
last_1 = aSelector;
}
pIlc->ilc_func = __SEND4ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
} else {
pIlc = &ilc_1;
}
} else {
pIlc = &ilc_0;
}
RETURN ( (*(pIlc->ilc_func))(self, aSelector, nil, pIlc,
arg1, arg2, arg3, arg4) );
} else {
static struct inlineCache ilc4 = __DUMMYILCSELF4(@line+1);
RETURN (_SEND4(self, aSelector, nil, &ilc4,
arg1, arg2, arg3, arg4));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg1 with:arg2 with:arg3 with:arg4)
!
perform:aSelector with:arg1 with:arg2 with:arg3 with:arg4 with:arg5
"send the five-arg-message aSelector to the receiver"
%{
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF5(@line);
static struct inlineCache ilc_1 = __ILCPERF5(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static flip = 0;
if (InterruptPending == nil) {
if (aSelector != last_0) {
if (aSelector != last_1) {
if (flip) {
pIlc = &ilc_0;
flip = 0;
last_0 = aSelector;
} else {
pIlc = &ilc_1;
flip = 1;
last_1 = aSelector;
}
pIlc->ilc_func = __SEND5ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
} else {
pIlc = &ilc_1;
}
} else {
pIlc = &ilc_0;
}
RETURN ( (*(pIlc->ilc_func))(self, aSelector, nil, pIlc,
arg1, arg2, arg3, arg4, arg5) );
} else {
static struct inlineCache ilc5 = __DUMMYILCSELF5(@line+1);
RETURN (_SEND5(self, aSelector, nil, &ilc5,
arg1, arg2, arg3, arg4, arg5));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg1 with:arg2 with:arg3 with:arg4
with:arg5)
!
perform:aSelector with:arg1 with:arg2 with:arg3 with:arg4 with:arg5 with:arg6
"send the six-arg-message aSelector to the receiver"
%{
struct inlineCache *pIlc;
static struct inlineCache ilc_0 = __ILCPERF6(@line);
static struct inlineCache ilc_1 = __ILCPERF6(@line);
static OBJ last_0 = nil;
static OBJ last_1 = nil;
static flip = 0;
if (InterruptPending == nil) {
if (aSelector != last_0) {
if (aSelector != last_1) {
if (flip) {
pIlc = &ilc_0;
flip = 0;
last_0 = aSelector;
} else {
pIlc = &ilc_1;
flip = 1;
last_1 = aSelector;
}
pIlc->ilc_func = __SEND6ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
} else {
pIlc = &ilc_1;
}
} else {
pIlc = &ilc_0;
}
RETURN ( (*(pIlc->ilc_func))(self, aSelector, nil, pIlc,
arg1, arg2, arg3, arg4, arg5, arg6) );
} else {
static struct inlineCache ilc6 = __DUMMYILCSELF6(@line+1);
RETURN (_SEND6(self, aSelector, nil, &ilc6,
arg1, arg2, arg3, arg4, arg5, arg6));
}
%}.
^ self perform:aSelector withArguments:(Array with:arg1 with:arg2 with:arg3 with:arg4
with:arg5 with:arg6)
!
perform:aSelector withArguments:argArray
"send the message aSelector with all args taken from argArray
to the receiver."
|numberOfArgs a1 a2 a3 a4 a5 a6 a7 a8 a9 a10 a11 a12 a13 a14 a15|
%{
REGISTER OBJ *argP;
int nargs;
OBJ l;
if (__isArray(argArray)) {
nargs = __arraySize(argArray);
argP = __arrayVal(argArray);
} else {
if (__isNonNilObject(argArray)) {
static struct inlineCache ilcSize = __ILC0(@line);
int i;
numberOfArgs = (*ilcSize.ilc_func)(argArray, @symbol(size), nil, &ilcSize);
if (!__isSmallInteger(numberOfArgs))
goto bad;
nargs = __intVal(numberOfArgs);
argP = (OBJ *)(&a1);
for (i=1; i <= nargs; i++) {
*argP++ = __AT_(argArray, __MKSMALLINT((INT)i));
}
argP = (OBJ *)(&a1);
} else {
nargs = 0;
}
}
switch (nargs) {
case 0:
if (InterruptPending == nil) {
static OBJ last0_0 = nil; static struct inlineCache ilc0_0 = __ILCPERF0(@line);
static OBJ last0_1 = nil; static struct inlineCache ilc0_1 = __ILCPERF0(@line);
static OBJ last0_2 = nil; static struct inlineCache ilc0_2 = __ILCPERF0(@line);
static OBJ last0_3 = nil; static struct inlineCache ilc0_3 = __ILCPERF0(@line);
static int flip0 = 0;
struct inlineCache *pIlc;
if (aSelector == last0_0) {
pIlc = &ilc0_0;
} else if (aSelector == last0_1) {
pIlc = &ilc0_1;
} else if (aSelector == last0_2) {
pIlc = &ilc0_2;
} else if (aSelector == last0_3) {
pIlc = &ilc0_3;
} else {
if (flip0 == 0) {
pIlc = &ilc0_0;
flip0 = 1;
last0_0 = aSelector;
} else if (flip0 == 1) {
pIlc = &ilc0_1;
flip0 = 2;
last0_1 = aSelector;
} else if (flip0 == 2) {
pIlc = &ilc0_2;
flip0 = 3;
last0_2 = aSelector;
} else {
pIlc = &ilc0_3;
flip0 = 0;
last0_3 = aSelector;
}
pIlc->ilc_func = __SEND0ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ((*pIlc->ilc_func)(self, aSelector, nil, pIlc));
} else {
static struct inlineCache ilc0 = __DUMMYILCSELF0(@line+1);
RETURN (_SEND0(self, aSelector, nil, &ilc0));
}
case 1:
if (InterruptPending == nil) {
static OBJ last1_0 = nil; static struct inlineCache ilc1_0 = __ILCPERF1(@line);
static OBJ last1_1 = nil; static struct inlineCache ilc1_1 = __ILCPERF1(@line);
static OBJ last1_2 = nil; static struct inlineCache ilc1_2 = __ILCPERF1(@line);
static OBJ last1_3 = nil; static struct inlineCache ilc1_3 = __ILCPERF1(@line);
static int flip1 = 0;
struct inlineCache *pIlc;
if (aSelector == last1_0) {
pIlc = &ilc1_0;
} else if (aSelector == last1_1) {
pIlc = &ilc1_1;
} else if (aSelector == last1_2) {
pIlc = &ilc1_2;
} else if (aSelector == last1_3) {
pIlc = &ilc1_3;
} else {
if (flip1 == 0) {
pIlc = &ilc1_0;
flip1 = 1;
last1_0 = aSelector;
} else if (flip1 == 1) {
pIlc = &ilc1_1;
flip1 = 2;
last1_1 = aSelector;
} else if (flip1 == 2) {
pIlc = &ilc1_2;
flip1 = 3;
last1_2 = aSelector;
} else {
pIlc = &ilc1_3;
flip1 = 0;
last1_3 = aSelector;
}
pIlc->ilc_func = __SEND1ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ((*pIlc->ilc_func)(self, aSelector, nil, pIlc, argP[0]));
} else {
static struct inlineCache ilc1 = __DUMMYILCSELF1(@line+1);
RETURN (_SEND1(self, aSelector, nil, &ilc1, argP[0]));
}
case 2:
if (InterruptPending == nil) {
static OBJ last2_0 = nil; static struct inlineCache ilc2_0 = __ILCPERF2(@line);
static OBJ last2_1 = nil; static struct inlineCache ilc2_1 = __ILCPERF2(@line);
static int flip2 = 0;
struct inlineCache *pIlc;
if (aSelector == last2_0) {
pIlc = &ilc2_0;
} else if (aSelector == last2_1) {
pIlc = &ilc2_1;
} else {
if (flip2 == 0) {
pIlc = &ilc2_0;
flip2 = 1;
last2_0 = aSelector;
} else {
pIlc = &ilc2_1;
flip2 = 0;
last2_1 = aSelector;
}
pIlc->ilc_func = __SEND2ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ((*pIlc->ilc_func)(self, aSelector, nil, pIlc, argP[0], argP[1]));
} else {
static struct inlineCache ilc2 = __DUMMYILCSELF2(@line+1);
RETURN (_SEND2(self, aSelector, nil, &ilc2, argP[0], argP[1]));
}
case 3:
if (InterruptPending == nil) {
static OBJ last3_0 = nil; static struct inlineCache ilc3_0 = __ILCPERF3(@line);
static OBJ last3_1 = nil; static struct inlineCache ilc3_1 = __ILCPERF3(@line);
static int flip3 = 0;
struct inlineCache *pIlc;
if (aSelector == last3_0) {
pIlc = &ilc3_0;
} else if (aSelector == last3_1) {
pIlc = &ilc3_1;
} else {
if (flip3 == 0) {
pIlc = &ilc3_0;
flip3 = 1;
last3_0 = aSelector;
} else {
pIlc = &ilc3_1;
flip3 = 0;
last3_1 = aSelector;
}
pIlc->ilc_func = __SEND3ADDR__;
if (pIlc->ilc_poly) {
__flushPolyCache(pIlc->ilc_poly);
pIlc->ilc_poly = 0;
}
}
RETURN ((*pIlc->ilc_func)(self, aSelector, nil, pIlc, argP[0], argP[1], argP[2]));
} else {
static struct inlineCache ilc3 = __DUMMYILCSELF3(@line+1);
RETURN (_SEND3(self, aSelector, nil, &ilc3, argP[0], argP[1], argP[2]));
}
case 4:
{
static OBJ last4 = nil; static struct inlineCache ilc4 = __ILCPERF4(@line);
if ((InterruptPending != nil) || (aSelector != last4)) {
ilc4.ilc_func = __SEND4ADDR__;
if (ilc4.ilc_poly) {
__flushPolyCache(ilc4.ilc_poly);
ilc4.ilc_poly = 0;
}
last4 = aSelector;
}
RETURN ( (*ilc4.ilc_func)(self, aSelector, nil, &ilc4,
argP[0], argP[1], argP[2], argP[3]));
}
case 5:
{
static OBJ last5 = nil; static struct inlineCache ilc5 = __ILCPERF5(@line);
if ((InterruptPending != nil) || (aSelector != last5)) {
ilc5.ilc_func = __SEND5ADDR__;
if (ilc5.ilc_poly) {
__flushPolyCache(ilc5.ilc_poly);
ilc5.ilc_poly = 0;
}
last5 = aSelector;
}
RETURN ( (*ilc5.ilc_func)(self, aSelector, nil, &ilc5,
argP[0], argP[1], argP[2], argP[3], argP[4]));
}
case 6:
{
static OBJ last6 = nil; static struct inlineCache ilc6 = __ILCPERF6(@line);
if ((InterruptPending != nil) || (aSelector != last6)) {
ilc6.ilc_func = __SEND6ADDR__;
if (ilc6.ilc_poly) {
__flushPolyCache(ilc6.ilc_poly);
ilc6.ilc_poly = 0;
}
last6 = aSelector;
}
RETURN ( (*ilc6.ilc_func)(self, aSelector, nil, &ilc6,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5]));
}
case 7:
{
static OBJ last7 = nil; static struct inlineCache ilc7 = __ILCPERF7(@line);
if ((InterruptPending != nil) || (aSelector != last7)) {
ilc7.ilc_func = __SEND7ADDR__;
if (ilc7.ilc_poly) {
__flushPolyCache(ilc7.ilc_poly);
ilc7.ilc_poly = 0;
}
last7 = aSelector;
}
RETURN ( (*ilc7.ilc_func)(self, aSelector, nil, &ilc7,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6]));
}
case 8:
{
static OBJ last8 = nil; static struct inlineCache ilc8 = __ILCPERF8(@line);
if ((InterruptPending != nil) || (aSelector != last8)) {
ilc8.ilc_func = __SEND8ADDR__;
if (ilc8.ilc_poly) {
__flushPolyCache(ilc8.ilc_poly);
ilc8.ilc_poly = 0;
}
last8 = aSelector;
}
RETURN ( (*ilc8.ilc_func)(self, aSelector, nil, &ilc8,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7]));
}
case 9:
{
static OBJ last9 = nil; static struct inlineCache ilc9 = __ILCPERF9(@line);
if ((InterruptPending != nil) || (aSelector != last9)) {
ilc9.ilc_func = __SEND9ADDR__;
if (ilc9.ilc_poly) {
__flushPolyCache(ilc9.ilc_poly);
ilc9.ilc_poly = 0;
}
last9 = aSelector;
}
RETURN ( (*ilc9.ilc_func)(self, aSelector, nil, &ilc9,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8]));
}
case 10:
{
static OBJ last10 = nil; static struct inlineCache ilc10 = __ILCPERF10(@line);
if ((InterruptPending != nil) || (aSelector != last10)) {
ilc10.ilc_func = __SEND10ADDR__;
if (ilc10.ilc_poly) {
__flushPolyCache(ilc10.ilc_poly);
ilc10.ilc_poly = 0;
}
last10 = aSelector;
}
RETURN ( (*ilc10.ilc_func)(self, aSelector, nil, &ilc10,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9]));
}
case 11:
{
static OBJ last11 = nil; static struct inlineCache ilc11 = __ILCPERF11(@line);
if ((InterruptPending != nil) || (aSelector != last11)) {
ilc11.ilc_func = __SEND11ADDR__;
if (ilc11.ilc_poly) {
__flushPolyCache(ilc11.ilc_poly);
ilc11.ilc_poly = 0;
}
last11 = aSelector;
}
RETURN ( (*ilc11.ilc_func)(self, aSelector, nil, &ilc11,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9],
argP[10]));
}
case 12:
{
static OBJ last12 = nil; static struct inlineCache ilc12 = __ILCPERF12(@line);
if ((InterruptPending != nil) || (aSelector != last12)) {
ilc12.ilc_func = __SEND12ADDR__;
if (ilc12.ilc_poly) {
__flushPolyCache(ilc12.ilc_poly);
ilc12.ilc_poly = 0;
}
last12 = aSelector;
}
RETURN ( (*ilc12.ilc_func)(self, aSelector, nil, &ilc12,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9],
argP[10], argP[11]));
}
case 13:
{
static OBJ last13 = nil; static struct inlineCache ilc13 = __ILCPERF13(@line);
if ((InterruptPending != nil) || (aSelector != last13)) {
ilc13.ilc_func = __SEND13ADDR__;
if (ilc13.ilc_poly) {
__flushPolyCache(ilc13.ilc_poly);
ilc13.ilc_poly = 0;
}
last13 = aSelector;
}
RETURN ( (*ilc13.ilc_func)(self, aSelector, nil, &ilc13,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9],
argP[10], argP[11], argP[12]));
}
case 14:
{
static OBJ last14 = nil; static struct inlineCache ilc14 = __ILCPERF14(@line);
if ((InterruptPending != nil) || (aSelector != last14)) {
ilc14.ilc_func = __SEND14ADDR__;
if (ilc14.ilc_poly) {
__flushPolyCache(ilc14.ilc_poly);
ilc14.ilc_poly = 0;
}
last14 = aSelector;
}
RETURN ( (*ilc14.ilc_func)(self, aSelector, nil, &ilc14,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9],
argP[10], argP[11], argP[12], argP[13]));
}
case 15:
{
static OBJ last15 = nil; static struct inlineCache ilc15 = __ILCPERF15(@line);
if ((InterruptPending != nil) || (aSelector != last15)) {
ilc15.ilc_func = __SEND15ADDR__;
if (ilc15.ilc_poly) {
__flushPolyCache(ilc15.ilc_poly);
ilc15.ilc_poly = 0;
}
last15 = aSelector;
}
RETURN ( (*ilc15.ilc_func)(self, aSelector, nil, &ilc15,
argP[0], argP[1], argP[2], argP[3], argP[4],
argP[5], argP[6], argP[7], argP[8], argP[9],
argP[10], argP[11], argP[12], argP[13],
argP[14]));
}
}
bad:;
%}.
"/ arrive here, if bad number of arguments (too many)
"/ ST/X (currently) only allows up to 15 method arguments
^ self primitiveFailed
!
perform:aSelector withOptionalArgument:arg
"send aSelector-message to the receiver.
If the message expects an argument, pass arg."
aSelector numArgs == 1 ifTrue:[
^ self perform:aSelector with:arg
].
^ self perform:aSelector
"
|rec sel|
rec := -1.
sel := #abs.
rec perform:sel withOptionalArgument:2.
sel := #max:.
rec perform:sel withOptionalArgument:2.
"
!
perform:aSelector withOptionalArgument:optionalArg1 and:optionalArg2
"send aSelector-message to the receiver.
Depending on the number of arguments the message expects,
pass either none, 1, or 2 arguments."
|numArgs|
numArgs := aSelector numArgs.
numArgs == 0 ifTrue:[
^ self perform:aSelector
].
numArgs == 1 ifTrue:[
^ self perform:aSelector with:optionalArg1
].
^ self perform:aSelector with:optionalArg1 with:optionalArg2.
"
|rec sel|
rec := -1.
sel := #abs.
rec perform:sel withOptionalArgument:2.
sel := #max:.
rec perform:sel withOptionalArgument:2.
"
!
perform:aSelector withOptionalArgument:optionalArg1 and:optionalArg2 and:optionalArg3
"send aSelector-message to the receiver.
Depending on the number of arguments the message expects,
pass either none, 1, 2 or 3 arguments."
|numArgs|
numArgs := aSelector numArgs.
numArgs == 0 ifTrue:[
^ self perform:aSelector
].
numArgs == 1 ifTrue:[
^ self perform:aSelector with:optionalArg1
].
numArgs == 2 ifTrue:[
^ self perform:aSelector with:optionalArg1 with:optionalArg2
].
^ self perform:aSelector with:optionalArg1 with:optionalArg2 with:optionalArg3.
"
|rec sel|
rec := -1.
sel := #abs.
rec perform:sel withOptionalArgument:2.
sel := #max:.
rec perform:sel withOptionalArgument:2.
"
!
perform:aSelector withOptionalArgument:optionalArg1 and:optionalArg2 and:optionalArg3 and:optionalArg4
"send aSelector-message to the receiver.
Depending on the number of arguments the message expects,
pass either none, 1, 2, 3 or 4 arguments."
|numArgs|
numArgs := aSelector numArgs.
numArgs == 0 ifTrue:[
^ self perform:aSelector
].
numArgs == 1 ifTrue:[
^ self perform:aSelector with:optionalArg1
].
numArgs == 2 ifTrue:[
^ self perform:aSelector with:optionalArg1 with:optionalArg2
].
numArgs == 3 ifTrue:[
^ self perform:aSelector with:optionalArg1 with:optionalArg2 with:optionalArg3
].
^ self perform:aSelector with:optionalArg1 with:optionalArg2 with:optionalArg3 with:optionalArg4.
"
|rec sel|
rec := -1.
sel := #abs.
rec perform:sel withOptionalArgument:2.
sel := #max:.
rec perform:sel withOptionalArgument:2.
"
!
performMethod:aMethod
"invoke aMethod on the receiver.
The method should be a zero-argument method.
This is a non-object-oriented entry, applying a method
in a functional way on a receiver.
Warning:
Take care for the method to be appropriate for the
receiver - no checking is done by the VM."
^ aMethod valueWithReceiver:self arguments:#()
"
|mthd|
mthd := SmallInteger compiledMethodAt:#negated.
Transcript showCR:(1 performMethod:mthd)
"
"BAD USE example:
|mthd|
mthd := Point compiledMethodAt:#x.
Transcript showCR:((1->2) performMethod:mthd)
"
"Modified: 31.7.1997 / 17:41:50 / cg"
!
performMethod:aMethod arguments:argumentArray
"invoke aMethod on the receiver, passing an argumentArray.
The size of the argumentArray should match the number of args
expected by the method.
This is a non-object-oriented entry, applying a method
in a functional way on a receiver.
Warning:
Take care for the method to be appropriate for the
receiver - no checking is done by the VM."
^ aMethod valueWithReceiver:self arguments:argumentArray
"
|mthd|
mthd := SmallInteger compiledMethodAt:#+.
Transcript showCR:(1 performMethod:mthd arguments:#(2))
"
"Created: 31.7.1997 / 17:46:31 / cg"
!
performMethod:aMethod with:arg
"invoke aMethod on the receiver, passing an argument.
The method should be a one-argument method.
This is a non-object-oriented entry, applying a method
in a functional way on a receiver.
Warning:
Take care for the method to be appropriate for the
receiver - no checking is done by the VM."
^ aMethod valueWithReceiver:self arguments:(Array with:arg)
"
|mthd|
mthd := SmallInteger compiledMethodAt:#+.
Transcript showCR:(1 performMethod:mthd with:2)
"
"Modified: 31.7.1997 / 17:42:32 / cg"
!
performMethod:aMethod with:arg1 with:arg2
"invoke aMethod on the receiver, passing two arguments.
The method should be a two-argument method.
This is a non-object-oriented entry, applying a method
in a functional way on a receiver.
Warning:
Take care for the method to be appropriate for the
receiver - no checking is done by the VM."
^ aMethod valueWithReceiver:self arguments:(Array with:arg1 with:arg2)
"
|mthd arr|
arr := Array new:1.
mthd := Array compiledMethodAt:#basicAt:put:.
arr performMethod:mthd with:1 with:'foo'.
Transcript showCR:arr
"
"Modified: 31.7.1997 / 17:44:54 / cg"
!
performMethod:aMethod with:arg1 with:arg2 with:arg3
"invoke aMethod on the receiver, passing three arguments.
The method should be a three-argument method.
This is a non-object-oriented entry, applying a method
in a functional way on a receiver.
Warning:
Take care for the method to be appropriate for the
receiver - no checking is done by the VM."
^ aMethod valueWithReceiver:self arguments:(Array with:arg1 with:arg2 with:arg3)
"Created: 31.7.1997 / 17:45:20 / cg"
! !
!Object methodsFor:'printing & storing'!
basicPrintOn:aStream
"append the receivers className with an articel to the argument, aStream"
aStream nextPutAll:self classNameWithArticle
!
className
"return the classname of the receivers class"
^ self class name
"
1 className
1 class className 'this may change ...'
$a className
$a class className 'this may change ...'
"
!
classNameWithArticle
"return a string consisting of classname preceeded by an article.
(dont expect me to write national variants for this ... :-)
If you have special preferences, redefine it ..."
| cls|
(cls := self class) == self ifTrue:[
^ 'a funny object'
].
^ cls nameWithArticle
"
1 classNameWithArticle
(1->2) classNameWithArticle
XWorkstation basicNew classNameWithArticle
XWorkstation classNameWithArticle
"
"Modified: 13.5.1996 / 12:16:14 / cg"
!
errorPrint
"print the receiver on the standard error stream."
Stream streamErrorSignal catch:[
self printOn:Stderr
]
"Modified: 7.3.1996 / 19:11:29 / cg"
!
errorPrintCR
"{ Pragma: +optSpace }"
"print the receiver followed by a cr on the standard error stream."
Stream streamErrorSignal catch:[
self printOn:Stderr.
Stderr cr
]
"Modified: 7.3.1996 / 19:13:01 / cg"
"Created: 20.5.1996 / 10:20:41 / cg"
!
errorPrintNL
"{ Pragma: +optSpace }"
<resource:#obsolete>
"print the receiver followed by a cr on the standard error stream.
Please use #errorPrintCR - this method exists for backward compatibility."
^ self errorPrintCR
"Modified: 20.5.1996 / 10:24:45 / cg"
!
errorPrintNewline
"{ Pragma: +optSpace }"
<resource:#obsolete>
"print the receiver followed by a cr on the standard error stream.
Please use #errorPrintCR - this method exists for backward compatibility."
self errorPrintCR.
"Modified: 20.5.1996 / 10:24:38 / cg"
!
infoPrint
"{ Pragma: +optSpace }"
"print the receiver on the standard error stream.
This is meant for information messages which are not warnings
or fatal messages.
These messages can be turned on/off by 'Object infoPrinting:true/false'"
InfoPrinting == true ifTrue:[
self errorPrint
]
!
infoPrintCR
"{ Pragma: +optSpace }"
"print the receiver followed by a cr on the standard error stream.
This is meant for information messages which are not warnings
or fatal messages.
These messages can be turned on/off by 'Object infoPrinting:true/false'"
InfoPrinting == true ifTrue:[
self errorPrintCR
]
"Created: 20.5.1996 / 10:21:28 / cg"
!
infoPrintNL
"{ Pragma: +optSpace }"
<resource:#obsolete>
"print the receiver followed by a cr on the standard error stream.
Please use #infoPrintCR - this method exists for backward compatibility."
^ self infoPrintCR
!
print
"print the receiver on the standard output stream (which is not the Transcript)"
"/ the following allows printCR to be used during
"/ the early init-phase, when no Stdout has been set up.
"/ (depends on string to respond to #print)
Stdout isNil ifTrue:[
self printString print.
^ self
].
self printOn:Stdout
"Modified: 4.11.1996 / 23:36:58 / cg"
!
printCR
"print the receiver followed by a cr on the standard output stream (which is not the Transcript)"
"/ the following allows printCR to be used during
"/ the early init-phase, when no Stdout has been set up.
"/ (depends on string to respond to #printCR)
Stdout isNil ifTrue:[
self printString printCR.
^ self
].
self printOn:Stdout.
Stdout cr
"Created: 20.5.1996 / 10:21:37 / cg"
"Modified: 4.11.1996 / 23:37:06 / cg"
!
printNL
"print the receiver followed by a cr on the standard output stream
This exists for GNU Smalltalk compatibility - please use #printCR."
<resource:#obsolete>
^ self printCR
"Modified: 20.5.1996 / 10:25:31 / cg"
!
printNewline
"print the receiver followed by a cr on the standard output stream.
This exists for backward compatibility - please use #printCR."
<resource:#obsolete>
self printCR
"Modified: 20.5.1996 / 10:25:46 / cg"
!
printOn:aStream
"append a user printed representation of the receiver to aStream.
The format is suitable for a human - not meant to be read back.
The default here is to output the receivers class name.
BUT: this method is heavily redefined for objects which
can print prettier."
self basicPrintOn:aStream.
"
(1@2) printOn:Transcript
(1@2) basicPrintOn:Transcript
"
!
printOn:aStream leftPaddedTo:size
"print the receiver on aStream, padding with spaces up to size.
padding is done on the left."
self printOn:aStream leftPaddedTo:size with:(Character space)
"
123 printOn:Transcript leftPaddedTo:10. Transcript cr
123 printOn:Transcript leftPaddedTo:2. Transcript cr
"
!
printOn:aStream leftPaddedTo:size with:padCharacter
"print the receiver on aStream, padding with padCharacters up to size.
padding is done on the left."
aStream nextPutAll:(self printStringLeftPaddedTo:size with:padCharacter)
"
123 printOn:Transcript leftPaddedTo:10 with:$_ . Transcript cr
123 printOn:Transcript leftPaddedTo:10 with:$. . Transcript cr
"
!
printOn:aStream paddedTo:size
"print the receiver on aStream, padding with spaces up to size."
self printOn:aStream paddedTo:size with:(Character space)
"
123.0 printOn:Transcript paddedTo:10. Transcript nextPut:$|. Transcript cr
"
!
printOn:aStream paddedTo:size with:padCharacter
"print the receiver on aStream, padding with padCharacter up to size"
aStream nextPutAll:(self printStringPaddedTo:size with:padCharacter).
"
123 printOn:Transcript paddedTo:10 with:$_ . Transcript cr
123 printOn:Transcript paddedTo:10 with:$. . Transcript cr
"
!
printOn:aStream zeroPaddedTo:size
"print the receiver on aStream, padding with zeros up to size.
Usually used with float numbers."
self printOn:aStream paddedTo:size with:$0.
"
123.0 printOn:Transcript zeroPaddedTo:10
"
!
printRightAdjustLen:size
"obsolete - just a name confusion.
This method will go away ..."
(self printStringLeftPaddedTo:size) printOn:Stdout
!
printString
"return a string for printing the receiver.
Since we now use printOn: as the basic print mechanism,
we have to create a stream and print into it."
|s|
s := WriteStream on:(String new:30).
self printOn:s.
^ s contents
!
printStringLeftPaddedTo:size
"return my printString as a right-adjusted string of length size;
characters on the left are filled with spaces.
If the printString is longer than size,
it is returned unchanged (i.e. not truncated)"
^ self printStringLeftPaddedTo:size with:(Character space)
"
10 printStringLeftPaddedTo:10
1 printStringLeftPaddedTo:10
"
!
printStringLeftPaddedTo:size ifLarger:alternative
"return my printString as a right-adjusted string of length size;
characters on the left are filled with spaces.
If the printString is larger than size,
return the result from evaluating alternative."
^ self printStringLeftPaddedTo:size with:(Character space) ifLarger:alternative
"
12 printStringLeftPaddedTo:3 ifLarger:['***']
123 printStringLeftPaddedTo:3 ifLarger:['***']
1234 printStringLeftPaddedTo:3 ifLarger:['***']
"
!
printStringLeftPaddedTo:size with:padCharacter
"return my printString as a right-adjusted string of length size;
characters on the left are filled with padCharacter.
If the printString is longer than size,
it is returned unchanged (i.e. not truncated)"
^ (self printString) leftPaddedTo:size with:padCharacter
"
123 printStringLeftPaddedTo:10 with:$.
1 printStringLeftPaddedTo:10 with:$.
(Float pi) printStringLeftPaddedTo:20 with:$*
"
!
printStringLeftPaddedTo:size with:padCharacter ifLarger:alternative
"return my printString as a right-adjusted string of length size;
characters on the left are filled with padCharacter.
If the printString is larger than size,
return the result from evaluating alternative."
|s|
s := self printString.
s size > size ifTrue:[^ alternative value].
^ s leftPaddedTo:size with:padCharacter
"
12 printStringLeftPaddedTo:3 with:$. ifLarger:['***']
123 printStringLeftPaddedTo:3 with:$. ifLarger:['***']
1234 printStringLeftPaddedTo:3 with:$. ifLarger:['***']
"
!
printStringOnError:exceptionBlock
"return a string for printing the receiver; if any error occurs, return the result from
evaluating exceptionBlock. Useful to print something in an exceptionHandler or other
cleanup code."
|rslt|
Error handle:[:ex |
rslt := exceptionBlock value
] do:[
rslt := self printString
].
^ rslt
!
printStringPaddedTo:size
"return a printed representation of the receiver,
padded with spaces (at the right) up to size.
If the printString is longer than size,
it is returned unchanged (i.e. not truncated)"
^ self printStringPaddedTo:size with:(Character space)
"
123 printStringPaddedTo:10
1234567890123456 printStringPaddedTo:10
'hello' printStringPaddedTo:10
"
!
printStringPaddedTo:size ifLarger:alternative
"return a printed representation of the receiver,
padded with spaces (at the right) up to size.
If the resulting printString is too large,
return the result from evaluating alternative."
^ self printStringPaddedTo:size with:(Character space) ifLarger:alternative
"
12 printStringPaddedTo:3 ifLarger:['***']
123 printStringPaddedTo:3 ifLarger:['***']
1234 printStringPaddedTo:3 ifLarger:['***']
"
!
printStringPaddedTo:size with:padCharacter
"return a printed representation of the receiver,
padded with padCharacter (at the right) up to size.
If the printString is longer than size,
it is returned unchanged (i.e. not truncated)"
^ (self printString) paddedTo:size with:padCharacter
"
123 printStringPaddedTo:10 with:$.
123 printStringPaddedTo:10 with:$*
123 printStringPaddedTo:3 with:$*
1234 printStringPaddedTo:3 with:$*
"
!
printStringPaddedTo:size with:padCharacter ifLarger:alternative
"return a printed representation of the receiver,
padded with padCharacter (at the right) up to size.
If the resulting printString is too large,
return the result from evaluating alternative."
|s|
s := self printString.
s size > size ifTrue:[^ alternative value].
^ s paddedTo:size with:padCharacter
"
123 printStringPaddedTo:3 with:$. ifLarger:['***']
12345 printStringPaddedTo:3 with:$. ifLarger:['***']
"
!
printStringRightAdjustLen:size
"obsolete - just a name confusion.
This method will go away ..."
^ self printStringLeftPaddedTo:size
!
printStringZeroPaddedTo:size
"return a printed representation of the receiver,
padded with zero (at the right) characters up to size.
Usually used with float numbers."
^ self printStringPaddedTo:size with:$0
"
123.0 printStringZeroPaddedTo:10
"
!
store
"store the receiver on standard output.
this method is useless, but included for compatibility."
self storeOn:Stdout
!
storeCR
"store the receiver on standard output; append a carriage return."
self store.
Character cr print
"Created: 20.5.1996 / 10:26:01 / cg"
"Modified: 20.5.1996 / 10:26:57 / cg"
!
storeNl
"store the receiver on standard output; append a newline.
This method is included for backward compatibility- use #storeCR."
<resource:#obsolete>
self storeCR.
"Modified: 20.5.1996 / 10:26:49 / cg"
!
storeOn:aStream
"store the receiver on aStream; i.e. print an expression which will
reconstruct the receiver.
Notice, that no self referencing or cyclic objects can be represented
in this format.
Use storeBinaryOn:, which handles these cases correctly."
|myClass hasSemi sz "{ Class: SmallInteger }" |
thisContext isRecursive ifTrue:[
Object recursiveStoreStringSignal raiseRequestWith:self.
('Object [error]: storeString of self referencing object.') errorPrintCR.
aStream nextPutAll:'#("recursive")'.
^ self
].
myClass := self class.
aStream nextPut:$(.
aStream nextPutAll:self class name.
hasSemi := false.
myClass isVariable ifTrue:[
aStream nextPutAll:' basicNew:'.
self basicSize printOn:aStream
] ifFalse:[
aStream nextPutAll:' basicNew'
].
sz := myClass instSize.
1 to:sz do:[:i |
aStream nextPutAll:' instVarAt:'.
i printOn:aStream.
aStream nextPutAll:' put:'.
(self instVarAt:i) storeOn:aStream.
aStream nextPut:$;.
hasSemi := true
].
myClass isVariable ifTrue:[
sz := self basicSize.
1 to:sz do:[:i |
aStream nextPutAll:' basicAt:'.
i printOn:aStream.
aStream nextPutAll:' put:'.
(self basicAt:i) storeOn:aStream.
aStream nextPut:$;.
hasSemi := true
]
].
hasSemi ifTrue:[
aStream nextPutAll:' yourself'
].
aStream nextPut:$).
"
|s|
s := WriteStream on:(String new).
('hello' -> 'world') storeOn:s.
s := ReadStream on:(s contents).
(Object readFrom:s) inspect
"
"
|s|
s := 'data' asFilename writeStream.
('hello' -> 'world') storeOn:s.
s close.
s := 'data' asFilename readStream.
(Object readFrom:s) inspect
"
"does not work example:"
"
|s a|
a := Array new:2.
a at:1 put:a.
s := 'data' asFilename writeStream.
a storeOn:s.
s close.
s := 'data' asFilename readStream.
(Object readFrom:s) inspect
"
"Modified: 28.1.1997 / 00:36:12 / cg"
!
storeString
"return a string representing an expression to reconstruct the receiver.
Notice, that no self referencing or cyclic objects can be represented
in this format.
Use storeBinaryOn:, which handles these cases correctly."
|s|
s := WriteStream on:(String new:50).
self storeOn:s.
^ s contents
! !
!Object methodsFor:'private'!
isHierarchicalItem
"used to decide if the parent is a hierarchical item
or the model
"
^ false
! !
!Object methodsFor:'queries'!
basicSize
"return the number of the receivers indexed instance variables,
0 if it has none.
This method should NOT be redefined in any subclass (except with great care, for tuning)"
%{ /* NOCONTEXT */
REGISTER int nbytes;
REGISTER OBJ myClass;
int nInstBytes;
/*
* notice the missing test for self being a nonNilObject -
* this can be done since basicSize is defined both in UndefinedObject
* and SmallInteger
*/
myClass = __qClass(self);
nbytes = __qSize(self);
nInstBytes = OHDR_SIZE + __OBJS2BYTES__( __intVal(__ClassInstPtr(myClass)->c_ninstvars) );
switch ((INT)(__ClassInstPtr(myClass)->c_flags) & __MASKSMALLINT(ARRAYMASK)) {
case __MASKSMALLINT(POINTERARRAY):
case __MASKSMALLINT(WKPOINTERARRAY):
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(__BYTES2OBJS__(nbytes)) );
case __MASKSMALLINT(BYTEARRAY):
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes / sizeof(char)) );
case __MASKSMALLINT(FLOATARRAY):
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes / sizeof(float)) );
case __MASKSMALLINT(DOUBLEARRAY):
#ifdef __NEED_DOUBLE_ALIGN
nInstBytes = (nInstBytes-1+__DOUBLE_ALIGN) &~ (__DOUBLE_ALIGN-1);
#endif
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes / sizeof(double)) );
case __MASKSMALLINT(WORDARRAY):
case __MASKSMALLINT(SWORDARRAY):
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes>>1) ); /* notice the hardcoded 2 here - not sizeof(short) */
case __MASKSMALLINT(LONGARRAY):
case __MASKSMALLINT(SLONGARRAY):
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes>>2) ); /* notice the hardcoded 4 here - not sizeof(int) */
case __MASKSMALLINT(LONGLONGARRAY):
case __MASKSMALLINT(SLONGLONGARRAY):
#ifdef __NEED_LONGLONG_ALIGN
nInstBytes = (nInstBytes-1+__LONGLONG_ALIGN) &~ (__LONGLONG_ALIGN-1);
#endif
nbytes -= nInstBytes;
RETURN ( __MKSMALLINT(nbytes>>3) ); /* notice the hardcoded 8 here - not sizeof(long long) */
}
%}.
^ 0
!
byteSize
"return the number of bytes in the receivers indexed instance variables,
0 if it has none. This only returns non-zero for non-pointer indexed
instvars i.e. byteArrays, wordArrays etc.
Notice: for Strings the returned size may look strange.
Only useful with binary storage."
|myClass|
myClass := self class.
myClass isVariable ifTrue:[
myClass isPointers ifFalse:[
myClass isBytes ifTrue:[
^ self basicSize.
].
myClass isWords ifTrue:[
^ self basicSize * 2.
].
myClass isSignedWords ifTrue:[
^ self basicSize * 2.
].
myClass isLongs ifTrue:[
^ self basicSize * 4.
].
myClass isSignedLongs ifTrue:[
^ self basicSize * 4.
].
myClass isLongLongs ifTrue:[
^ self basicSize * 8.
].
myClass isSignedLongLongs ifTrue:[
^ self basicSize * 8.
].
myClass isFloats ifTrue:[
^ self basicSize * (ExternalBytes sizeofFloat)
].
myClass isDoubles ifTrue:[
^ self basicSize * (ExternalBytes sizeofDouble)
].
self halt:'oops'.
]
].
^ 0
"
Point new byteSize
'hello' byteSize
(ByteArray with:1 with:2) byteSize
(FloatArray with:1.5) byteSize
(DoubleArray with:1.5) byteSize
(WordArray with:1 with:2) byteSize
"
!
class
"return the receivers class"
%{ /* NOCONTEXT */
RETURN ( __Class(self) );
%}
!
respondsTo:aSelector
"return true, if the receiver implements a method with selector equal
to aSelector; i.e. if there is a method for aSelector in either the
receivers class or one of its superclasses.
Notice, that this does not imply, that such a message can be sent without
an error being raised. For example, an implementation could send
#shouldNotImplement or #subclassResponsibility."
"
should we go via the cache, or search (by class) ?
The first is faster, most of the time; while the 2nd fills
the cache with useless data if this is sent in a loop over all objects.
For now, use the cache ...
"
%{ /* NOCONTEXT */
if (__lookup(__Class(self), aSelector) == nil) {
RETURN ( false );
}
RETURN ( true );
%}
.
^ self class canUnderstand:aSelector
"'aString' respondsTo:#+"
"'aString' respondsTo:#,"
"'aString' respondsTo:#collect:"
!
respondsToArithmetic
"return true, if the receiver responds to arithmetic messages.
false is returned here - the method is redefined in ArithmeticValue."
^ false
!
size
"return the number of the receivers indexed instance variables;
this method may be redefined in subclasses"
^ self basicSize
!
species
"return a class which is similar to (or the same as) the receivers class.
This is used to create an appropriate object when creating derived
copies in the collection classes (sometimes redefined)."
^ self class
!
yourself
"return the receiver - used for cascades to return self at the end"
^ self
! !
!Object methodsFor:'secure message sending'!
askFor:aSelector
"try to send the receiver the message, aSelector.
If it does not understand it, return false.
Otherwise the real value returned.
Useful to send messages such as: #isColor to unknown
receivers."
^ self perform:aSelector ifNotUnderstood:[false]
"
1 askFor:#isColor
Color red askFor:#isColor
1 askFor:#isFoo
Color red askFor:#isFoo
"
!
perform:aSelector ifNotUnderstood:exceptionBlock
"try to send message aSelector to the receiver.
If its understood, return the methods returned value,
otherwise return the value of the exceptionBlock"
|val ok|
MessageNotUnderstood handle:[:ex |
"/ reject, if the bad message is not the one
"/ we have sent originally
ex parameter selector == aSelector ifFalse:[
ex reject
].
ex receiver == self ifFalse:[
ex reject
]
] do:[
val := self perform:aSelector.
ok := true.
].
ok isNil ifTrue:[
^ exceptionBlock value
].
^ val
"
1.2345 perform:#foo ifNotUnderstood:['sorry']
1.2345 perform:#sqrt ifNotUnderstood:['sorry']
12345 perform:#sqrt ifNotUnderstood:['sorry']
"
!
perform:aSelector with:argument ifNotUnderstood:exceptionBlock
"try to send message aSelector to the receiver.
If its understood, return the methods returned value,
otherwise return the value of the exceptionBlock"
|val ok|
MessageNotUnderstoodSignal handle:[:ex |
"/ reject, if the bad message is not the one
"/ we have sent originally
ex parameter selector == aSelector ifFalse:[
ex reject
].
ex receiver == self ifFalse:[
ex reject
]
] do:[
val := self perform:aSelector with:argument.
ok := true.
].
ok isNil ifTrue:[
^ exceptionBlock value
].
^ val
"
|unknown|
unknown := 1.
(unknown perform:#+ with:2 ifNotUnderstood:['sorry']) printNewline.
unknown := 'high there'.
(unknown perform:#+ with:2 ifNotUnderstood:['sorry']) printNewline.
"
!
perform:aSelector with:arg1 with:arg2 ifNotUnderstood:exceptionBlock
"try to send message aSelector to the receiver.
If its understood, return the methods returned value,
otherwise return the value of the exceptionBlock"
|val ok|
MessageNotUnderstoodSignal handle:[:ex |
"/ reject, if the bad message is not the one
"/ we have sent originally
ex parameter selector == aSelector ifFalse:[
ex reject
].
ex receiver == self ifFalse:[
ex reject
]
] do:[
val := self perform:aSelector with:arg1 with:arg2.
ok := true.
].
ok isNil ifTrue:[
^ exceptionBlock value
].
^ val
"
|unknown|
unknown := 1.
(unknown perform:#+ with:2 ifNotUnderstood:['sorry']) printNewline.
unknown := 'high there'.
(unknown perform:#+ with:2 ifNotUnderstood:['sorry']) printNewline.
"
!
perform:aSelector withArguments:argumentArray ifNotUnderstood:exceptionBlock
"try to send message aSelector to the receiver.
If its understood, return the methods returned value,
otherwise return the value of the exceptionBlock"
|val ok|
MessageNotUnderstoodSignal handle:[:ex |
"/ reject, if the bad message is not the one
"/ we have sent originally
ex parameter selector == aSelector ifFalse:[
ex reject
].
ex receiver == self ifFalse:[
ex reject
]
] do:[
val := self perform:aSelector withArguments:argumentArray.
ok := true.
].
ok isNil ifTrue:[
^ exceptionBlock value
].
^ val
"
|unknown|
unknown := 1.
(unknown perform:#+ withArguments:#(2) ifNotUnderstood:['sorry']) printNewline.
unknown := 'high there'.
(unknown perform:#+ withArguments:#(2) ifNotUnderstood:['sorry']) printNewline.
"
"Modified: 27.3.1997 / 14:13:16 / cg"
! !
!Object methodsFor:'signal constants'!
messageNotUnderstoodSignal
^ MessageNotUnderstood
"Created: 6.3.1997 / 15:46:52 / cg"
! !
!Object methodsFor:'special queries'!
allOwners
"return a collection of all objects referencing the receiver"
^ ObjectMemory whoReferences:self
!
references:anObject
"return true, if the receiver refers to the argument, anObject.
- for debugging only"
^ self referencesObject:anObject
"
|v|
v := View new initialize.
v references:Display.
"
!
referencesAny:aCollection
"return true, if the receiver refers to any object from
the argument, aCollection.
- for debugging only"
%{
OBJ cls, flags;
int nInsts, inst;
if (! __isNonNilObject(self)) {
RETURN (false);
}
if (__isArray(aCollection)) {
int nObjs = __arraySize(aCollection);
char *minAddr = 0, *maxAddr = 0;
if (nObjs == 0) {
RETURN (false);
}
/*
* a little optimization: use the fact that all old objects
* refering to a new object are on the remSet; if I am not,
* a trivial reject is possible, if all objects are newbees.
* as a side effect, gather min/max addresses
*/
if ((__qSpace(self) <= OLDSPACE) && !__isRemembered(self)) {
int allNewBees = 1;
int i;
minAddr = (char *)(__ArrayInstPtr(aCollection)->a_element[0]);
maxAddr = minAddr;
for (i=0; i<nObjs; i++) {
OBJ anObject;
anObject = __ArrayInstPtr(aCollection)->a_element[i];
if (__isNonNilObject(anObject)) {
int spc;
if (((spc = __qSpace(anObject)) != NEWSPACE) && (spc != SURVSPACE)) {
allNewBees = 0;
}
}
if ((char *)anObject < minAddr) {
minAddr = (char *)anObject;
} else if ((char *)anObject > maxAddr) {
maxAddr = (char *)anObject;
}
}
if (allNewBees) {
RETURN (false);
}
}
/*
* fetch min/max in searchList (if not already done)
*/
if (minAddr == 0) {
int i;
for (i=0; i<nObjs; i++) {
OBJ anObject;
anObject = __ArrayInstPtr(aCollection)->a_element[i];
if ((char *)anObject < minAddr) {
minAddr = (char *)anObject;
} else if ((char *)anObject > maxAddr) {
maxAddr = (char *)anObject;
}
}
}
cls = __qClass(self);
if (((char *)cls >= minAddr) && ((char *)cls <= maxAddr)) {
#if defined(memsrch4)
if (memsrch4(__arrayVal(aCollection), (INT)cls, nObjs)) {
RETURN (true);
}
#else
int i;
for (i=0; i<nObjs; i++) {
OBJ anObject;
anObject = __ArrayInstPtr(aCollection)->a_element[i];
if (cls == anObject) {
RETURN (true);
}
}
#endif /* memsrch4 */
}
flags = __ClassInstPtr(cls)->c_flags;
if (((INT)flags & __MASKSMALLINT(ARRAYMASK)) == __MASKSMALLINT(POINTERARRAY)) {
nInsts = __BYTES2OBJS__(__qSize(self) - OHDR_SIZE);
} else {
nInsts = __intVal(__ClassInstPtr(cls)->c_ninstvars);
}
if (! nInsts) {
RETURN (false);
}
if (nObjs == 1) {
/* better reverse the loop */
OBJ anObject;
anObject = __ArrayInstPtr(aCollection)->a_element[0];
#if defined(memsrch4)
if (memsrch4(__InstPtr(self)->i_instvars, (INT)anObject, nInsts)) {
RETURN (true);
}
#else
for (inst=0; inst<nInsts; inst++) {
if ((__InstPtr(self)->i_instvars[inst]) == anObject) {
RETURN (true);
}
}
#endif
RETURN (false);
}
for (inst=0; inst<nInsts; inst++) {
OBJ instVar = __InstPtr(self)->i_instvars[inst];
int i;
if (((char *)instVar >= minAddr) && ((char *)instVar <= maxAddr)) {
#if defined(memsrch4)
if (memsrch4(__arrayVal(aCollection), (INT)instVar, nObjs)) {
RETURN (true);
}
#else
for (i=0; i<nObjs; i++) {
OBJ anObject;
anObject = __ArrayInstPtr(aCollection)->a_element[i];
if (instVar == anObject) {
RETURN (true);
}
}
#endif /* memsrch4 */
}
}
RETURN (false);
}
%}.
aCollection do:[:el |
(self references:el) ifTrue:[^ true].
].
^ false
!
referencesDerivedInstanceOf:aClass
"return true, if the receiver refers to an instance of
the argument, aClass or its subclass. This method exists
to support searching for users of a class."
|myClass
numInst "{ Class: SmallInteger }" |
"check the class"
(self isKindOf:aClass) ifTrue:[^ true].
myClass := self class.
"check the instance variables"
numInst := myClass instSize.
1 to:numInst do:[:i |
((self instVarAt:i) isKindOf:aClass) ifTrue:[^ true]
].
"check the indexed variables"
myClass isVariable ifTrue:[
myClass isPointers ifFalse:[
"no need to search in non pointer fields"
((aClass == Number) or:[aClass isSubclassOf:Number]) ifFalse:[^ false].
].
numInst := self basicSize.
1 to:numInst do:[:i |
((self basicAt:i) isKindOf:aClass) ifTrue:[^ true]
]
].
^ false
"
(1 @ 3.4) referencesDerivedInstanceOf:Number
(1 @ 3.4) referencesDerivedInstanceOf:Array
View new initialize referencesDerivedInstanceOf:DeviceWorkstation
"
!
referencesInstanceOf:aClass
"return true, if the receiver refers to an instance of
the argument, aClass.This method exists
to support searching for users of a class."
|myClass
numInst "{ Class: SmallInteger }" |
myClass := self class.
"check the class"
(myClass isMemberOf:aClass) ifTrue:[^ true].
"check the instance variables"
numInst := myClass instSize.
1 to:numInst do:[:i |
((self instVarAt:i) isMemberOf:aClass) ifTrue:[^ true]
].
"check the indexed variables"
myClass isVariable ifTrue:[
myClass isPointers ifFalse:[
"no need to search in non-pointer indexed fields"
myClass isLongs ifTrue:[
(aClass == SmallInteger or:[aClass == LargeInteger]) ifFalse:[^ false].
] ifFalse:[
myClass isFloatsOrDoubles ifTrue:[^ aClass == Float].
^ aClass == SmallInteger
]
].
numInst := self basicSize.
1 to:numInst do:[:i |
((self basicAt:i) isMemberOf:aClass) ifTrue:[^ true]
]
].
^ false
"
(1 @ 3.4) referencesInstanceOf:Float
(1 @ 3.4) referencesInstanceOf:Fraction
View new initialize referencesInstanceOf:(Display class)
"
!
referencesObject:anObject
"return true, if the receiver refers to the argument, anObject.
- for debugging only"
%{ /* NOCONTEXT */
OBJ cls, flags;
int nInsts, i;
if (! __isNonNilObject(self)) {
RETURN (false);
}
/*
* a little optimization: use the fact that all old objects
* refering to a new object are on the remSet; if I am not,
* a trivial reject is possible, if anObject is a newbee
*/
if (__isNonNilObject(anObject)) {
if ((__qSpace(self) <= OLDSPACE) && !__isRemembered(self)) {
int spc;
if (((spc = __qSpace(anObject)) == NEWSPACE) || (spc == SURVSPACE)) {
RETURN (false);
}
}
}
cls = __qClass(self);
if (cls == anObject) {
RETURN (true);
}
flags = __ClassInstPtr(cls)->c_flags;
if (((INT)flags & __MASKSMALLINT(ARRAYMASK)) == __MASKSMALLINT(POINTERARRAY)) {
nInsts = __BYTES2OBJS__(__qSize(self) - OHDR_SIZE);
} else {
nInsts = __intVal(__ClassInstPtr(cls)->c_ninstvars);
}
if (! nInsts) {
RETURN (false);
}
#if defined(memsrch4)
if (memsrch4(__InstPtr(self)->i_instvars, (INT)anObject, nInsts)) {
RETURN (true);
}
#else
for (i=0; i<nInsts; i++) {
if (__InstPtr(self)->i_instvars[i] == anObject) {
RETURN (true);
}
}
#endif /* memsrch4 */
%}.
"/ |myClass
"/ numInst "{ Class: SmallInteger }" |
"/
"/ myClass := self class.
"/
"/ "check the class"
"/ (myClass == anObject) ifTrue:[^ true].
"/
"/ "check the instance variables"
"/ numInst := myClass instSize.
"/ 1 to:numInst do:[:i |
"/ ((self instVarAt:i) == anObject) ifTrue:[^ true]
"/ ].
"/
"/ "check the indexed variables"
"/ myClass isVariable ifTrue:[
"/ myClass isPointers ifFalse:[
"/ "/
"/ "/ we could argue about the following unconditional return:
"/ "/ it says that a non pointer array never has a reference to the
"/ "/ corresponding object - not mimicing a reference to a copy of the
"/ "/ integer. However, it avoids useless searches in huge byteArray
"/ "/ like objects when searching for owners. If in doubt, remove it.
"/ "/ A consequence of the return below is that #[1 2 3] will say that it
"/ "/ does not refer to the number 2 (think of keeping a copy instead)
"/
"/ ^ false.
"/
"/ "/ alternative:
"/ "/ anObject isNumber ifFalse:[^ false].
"/ ].
"/
"/ "/
"/ "/ because arrays are so common, and those have a highly tuned
"/ "/ idenitytIndex method, use it
"/ "/
"/ myClass == Array ifTrue:[
"/ ^ (self identityIndexOf:anObject) ~~ 0
"/ ].
"/
"/ "/
"/ "/ otherwise, do it the slow way
"/ "/
"/ numInst := self basicSize.
"/ 1 to:numInst do:[:i |
"/ ((self basicAt:i) == anObject) ifTrue:[^ true]
"/ ]
"/ ].
^ false
"
|v|
v := View new initialize.
v references:Display.
"
! !
!Object methodsFor:'synchronized evaluation'!
freeSynchronizationSemaphore
"free synchronizationSemaphore. May be used, to save memory when
an object is no longer used synchronized."
|sema|
sema := self synchronizationSemaphore.
sema notNil ifTrue:[
sema wait. "/ get lock
self synchronizationSemaphore:nil.
].
"
self synchronized:[].
self synchronizationSemaphore.
self freeSynchronizationSemaphore.
"
"Created: 28.1.1997 / 19:31:20 / stefan"
"Modified: 28.1.1997 / 19:47:55 / stefan"
!
synchronizationSemaphore
"return the synchronization semaphore for myself.
subclasses may redefine"
^ SynchronizationSemaphores at:self ifAbsent:[].
"
self synchronizationSemaphore
"
"Modified: 28.1.1997 / 19:47:09 / stefan"
!
synchronizationSemaphore:aSemaphore
"set the synchronisationSemaphore for myself.
subclasses may redefine this method"
aSemaphore isNil ifTrue:[
"/ remove Semaphore
SynchronizationSemaphores removeKey:self ifAbsent:nil.
] ifFalse:[
SynchronizationSemaphores at:self put:aSemaphore.
].
"Modified: 28.1.1997 / 19:37:48 / stefan"
!
synchronized:aBlock
"evaluate aBlock synchronized, i.e. use a monitor for this object"
|sema wasBlocked|
wasBlocked := OperatingSystem blockInterrupts.
sema := self synchronizationSemaphore.
sema isNil ifTrue:[
"get a locked semaphore (with count = 0)"
sema := Semaphore new:0.
self synchronizationSemaphore:sema.
] ifFalse:[
sema wait.
].
wasBlocked ifFalse:[OperatingSystem unblockInterrupts].
^ aBlock ensure:[sema signal].
"
[Object synchronized:[Delay waitForSeconds:2. Transcript showCR:'1']] fork.
[Object synchronized:[Delay waitForSeconds:2. Transcript showCR:'2']] fork.
"
"Created: 28.1.1997 / 17:52:56 / stefan"
"Modified: 30.1.1997 / 13:38:54 / cg"
"Modified: 20.2.1997 / 09:43:35 / stefan"
! !
!Object methodsFor:'system primitives'!
asOop
"ST-80 compatibility:
ST-80 returns an OOP-identity based number here (I guess: its address
or index); since ST/X has no such thing, and the objects address cannot
be used (since its changing over time), we return the objects identityHash
key, which provides (at least) some identity indication.
However, notice that (in contrast to ST-80's #asOop), the identityHash
key of two non-identical objects may be the same.
You'd better not use it - especially do not misuse it."
^ self identityHash
"Created: 9.11.1996 / 19:09:56 / cg"
"Modified: 9.11.1996 / 19:16:04 / cg"
!
become:anotherObject
"make all references to the receiver become references to anotherObject
and vice-versa. Notice the vice-versa; see #becomeSameAs: for a one-way become.
This can be a very dangerous operation - be warned.
In general, using #become: should be avoided if possible, since it may
produce many strange effects (think of hashing in Sets, Dictionaries etc.).
This may also be an expensive (i.e. slow) operation,
since in the worst case, the whole memory has to be searched for
references to the two objects (although the primitive tries hard to
limit the search, for acceptable performance in most cases).
This method fails, if the receiver or the argument is a SmallInteger
or nil, or is a context of a living method (i.e. one that has not already
returned).
(notice that #become: is not used heavily by the system
- the Collection-classes have been rewritten to not use it.)"
%{
if (__primBecome(self, anotherObject)) {
RETURN ( self );
}
%}.
self primitiveFailed
!
becomeNil
"make all references to the receiver become nil - effectively getting
rid of the receiver.
This can be a very dangerous operation - be warned.
This may be an expensive (i.e. slow) operation.
The receiver may not be a SmallInteger or a context of a living method."
%{
if (__primBecomeNil(self)) {
RETURN ( nil );
}
%}.
self primitiveFailed
!
becomeSameAs:anotherObject
"make all references to the receiver become references to anotherObject
but NOT vice versa (as done in #become:).
This can be a very dangerous operation - be warned.
In general, using #become: should be avoided if possible, since it may
produce many strange effects (think of hashing in Sets, Dictionaries etc.).
This may also be an expensive (i.e. slow) operation,
since in the worst case, the whole memory has to be searched for
references to the two objects (although the primitive tries hard to
limit the search, for acceptable performance in most cases).
This method fails, if the receiver or the argument is a SmallInteger
or nil, or is a context of a living method (i.e. one that has not already returned)."
%{
if (__primBecomeSameAs(self, anotherObject)) {
RETURN ( self );
}
%}.
self primitiveFailed
!
changeClassTo:otherClass
"changes the class of the receiver to the argument, otherClass.
This is only allowed (possible), if the receivers class and the argument
have the same structure (i.e. number of named instance variables and
type of indexed instance variables).
If the structures do not match, or any of the original class or new class
is UndefinedObject or a Smallinteger, a primitive error is triggered."
|myClass ok|
"check for UndefinedObject/SmallInteger receiver or newClass"
%{
{
OBJ other = otherClass;
if (__isNonNilObject(self)
&& __isNonNilObject(other)
&& (other != UndefinedObject)
&& (other != SmallInteger)) {
ok = true;
} else {
ok = false;
}
}
%}.
ok ifTrue:[
ok := false.
myClass := self class.
myClass flags == otherClass flags ifTrue:[
myClass instSize == otherClass instSize ifTrue:[
"same instance layout and types: its ok to do it"
ok := true.
] ifFalse:[
myClass isPointers ifTrue:[
myClass isVariable ifTrue:[
ok := true
]
]
]
] ifFalse:[
myClass isPointers ifTrue:[
"if newClass is a variable class, with instSize <= my instsize,
we can do it (effectively mapping additional instvars into the
variable part) - usefulness is questionable, though"
otherClass isPointers ifTrue:[
otherClass isVariable ifTrue:[
otherClass instSize <= (myClass instSize + self basicSize)
ifTrue:[
ok := true
]
] ifFalse:[
otherClass instSize == (myClass instSize + self basicSize)
ifTrue:[
ok := true
]
]
] ifFalse:[
"it does not make sense to convert pointers to bytes ..."
]
] ifFalse:[
"does it make sense, to convert bits ?"
"could allow byteArray->wordArray->longArray->floatArray->doubleArray here ..."
(myClass isBitsExtended and:[otherClass isBitsExtended]) ifTrue:[
ok := true
]
]
]
].
ok ifTrue:[
"now, change the receivers class ..."
%{
{
OBJ me = self;
__qClass(me) = otherClass;
__STORE(me, otherClass);
RETURN (me);
}
%}.
].
otherClass isLoaded ifFalse:[
^ self changeClassTo:(otherClass autoload).
].
"
the receiver cannot be represented as a instance of
the desired class.
For example, you cannot change a bitInstance (byteArray etc.)
into a pointer object and vice versa.
"
self primitiveFailed
!
changeClassToThatOf:anObject
"changes the class of the receiver to that of the argument, anObject.
This is only allowed (possible), if the receivers class and the arguments
class have the same structure (i.e. number of named instance variables and
type of indexed instance variables). If the structures do not match, or any
of the objects is nil or a Smallinteger, a primitive error is triggered."
self changeClassTo:(anObject class)
!
replaceReferencesTo:anObject with:newRef
"if the receiver refers to the argument, anObject, replace this reference with newRef.
Return true, if any reference was changed.
Notice: this does not change the class-reference."
%{ /* NOCONTEXT */
OBJ cls, flags, anyChange;
int nInsts, i;
if (! __isNonNilObject(self)) {
RETURN (false);
}
/*
* a little optimization: use the fact that all old objects
* refering to a new object are on the remSet; if I am not,
* a trivial reject is possible, if anObject is a newbee
*/
if (__isNonNilObject(anObject)) {
if ((__qSpace(self) <= OLDSPACE) && !__isRemembered(self)) {
int spc;
if (((spc = __qSpace(anObject)) == NEWSPACE) || (spc == SURVSPACE)) {
RETURN (false);
}
}
}
cls = __qClass(self);
flags = __ClassInstPtr(cls)->c_flags;
if (((INT)flags & __MASKSMALLINT(ARRAYMASK)) == __MASKSMALLINT(POINTERARRAY)) {
nInsts = __BYTES2OBJS__(__qSize(self) - OHDR_SIZE);
} else {
nInsts = __intVal(__ClassInstPtr(cls)->c_ninstvars);
}
if (! nInsts) {
RETURN (false);
}
anyChange = false;
for (i=0; i<nInsts; i++) {
if (__InstPtr(self)->i_instvars[i] == anObject) {
__InstPtr(self)->i_instvars[i] = newRef;
__STORE(self, newRef);
anyChange = true;
}
}
RETURN (anyChange);
%}.
"
|v|
v := Array with:1234 with:'hello' with:Array.
v replaceReferencesTo:Array with:ByteArray.
v inspect
"
! !
!Object methodsFor:'testing'!
? defaultValue
"a syntactic shugar-piece:
if the receiver is nil, return the defaultValue;
otherwise, return the receiver.
This method is only redefined in UndefinedObject - therefore,
the recevier is retuned here.
Thus, if foo and bar are simple variables or constants,
foo ? bar
is the same as:
(foo isNil ifTrue:[bar] ifFalse:[foo])
if they are message sends, the equivalent code is:
[
|t1 t2|
t1 := foo.
t2 := bar.
t1 isNil ifTrue:[t2] ifFalse:[t1]
] value
Can be used to provide defaultValues to variables,
as in:
foo := arg ? #defaultValue
Note: this method should never be redefined in classes other than UndefinedObject.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ self
"
1 ? #default
nil ? #default
"
"Created: / 4.11.1996 / 20:36:19 / cg"
"Modified: / 19.5.1998 / 17:39:56 / cg"
!
?? defaultValue
"a syntactic shugar-piece:
much like ?, but sends #value to the argument if required.
(i.e. its the same as #ifNil:)
If the receiver is nil, return the defaultValues value;
otherwise, return the receiver.
This method is only redefined in UndefinedObject - therefore,
the recevier is retuned here.
Thus, if foo and bar are simple variables or constants,
foo ?? bar
is the same as:
(foo isNil ifTrue:[bar value] ifFalse:[foo])
if they are message sends, the equivalent code is:
[
|t t2|
t := foo.
t isNil ifTrue:[bar value] ifFalse:[t]
] value
Can be used to provide defaultValues to variables,
as in:
foo := arg ?? [ self computeDefault ]
Note: this method should never be redefined in classes other than UndefinedObject.
"
^ self
"
1 ?? #default
nil ?? #default
1 ?? [ self halt. 1 + 2 ]
nil ?? [ self halt. 1 + 2 ]
1 ?? [Date today]
nil ?? [Date today]
"
"Created: / 4.11.1996 / 20:36:19 / cg"
"Modified: / 19.5.1998 / 17:42:56 / cg"
!
ifNil:aBlockOrValue
"return myself, or the result from evaluating the argument, if I am nil.
This is much like #?, but sends #value to the argument in case of a nil
receiver.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ self
!
ifNil:nilBlockOrValue ifNotNil:notNilBlockOrValue
"return the value of the first arg, if I am nil,
the result from evaluating the 2nd argument, if I am not nil.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ notNilBlockOrValue value
!
ifNotNil:aBlockOrValue
"return myself if nil, or the result from evaluating the argument,
if I am not nil.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ aBlockOrValue value
!
ifNotNil:notNilBlockOrValue ifNil:nilBlockOrValue
"return the value of the 2nd arg, if I am nil,
the result from evaluating the 1st argument, if I am not nil.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ notNilBlockOrValue value
!
isArray
"return true, if the receiver is some kind of array (or weakArray etc);
false is returned here - the method is only redefined in Array."
^ false
!
isAssociation
"return true, if the receiver is some kind of association;
false is returned here - the method is only redefined in Association."
^ false
"Created: 14.5.1996 / 17:03:45 / cg"
!
isBehavior
"return true, if the receiver is some kind of class (i.e. behavior);
false is returned here - the method is only redefined in Behavior."
^ false
!
isBlock
"return true, if the receiver is some kind of block;
false returned here - the method is only redefined in Block."
^ false
!
isBoolean
"return true, if the receiver is a boolean;
false is returned here - the method is only redefined in Boolean."
^ false
!
isByteArray
"return true, if the receiver is some kind of bytearray;
false is returned here - the method is only redefined in ByteArray."
^ false
!
isCharacter
"return true, if the receiver is some kind of character;
false is returned here - the method is only redefined in Character."
^ false
!
isClass
"return true, if the receiver is some kind of class (real class,
not just behavior);
false is returned here - the method is only redefined in Class."
^ false
!
isCollection
"return true, if the receiver is some kind of collection;
false is returned here - the method is only redefined in Collection."
^ false
!
isColor
"return true, if the receiver is some kind of color;
false is returned here - the method is only redefined in Color."
^ false
!
isCons
"return true, if the receiver is a cons (pair);
false is returned here - the method is only redefined in Cons."
^ false
!
isContext
"return true, if the receiver is some kind of context;
false returned here - the method is only redefined in Context."
^ false
!
isEmptyOrNil
"Squeak compatibility:
return true if I am nil or an empty collection - return false here.
Sigh: the same as ST/X isNilOrEmptyCollection - which one should be kept in the long run ?"
^ false
"Created: / 13.11.2001 / 13:17:04 / cg"
"Modified: / 13.11.2001 / 13:28:40 / cg"
!
isException
"answer true, if this ia an Exception, that may be queried about its type"
^ false
"Created: / 17.11.2001 / 18:37:44 / cg"
!
isExceptionCreator
"return true, if the receiver can create exceptions,
this includes #raise, #raiseRequest as well as the behavior of
an exception handler, such as the #accepts: and #handles: messages"
^ false
!
isExceptionHandler
"return true, if the receiver responds to the exception handler protocol,
especially to the #accepts: and #handles: messages"
^ false
!
isExternalStream
"return true, if the receiver is some kind of externalStream;
false is returned here - the method is only redefined in ExternalStream."
^false
!
isFileStream
"return true, if the receiver is some kind of fileStream;
false is returned here - the method is only redefined in FileStream."
^false
!
isFilename
"return true, if the receiver is some kind of filename;
false is returned here - the method is only redefined in Filename."
^false
!
isFixedPoint
"return true, if the receiver is some kind of fixedPoint number;
false is returned here - the method is only redefined in FixedPoint."
^ false
"Created: 5.11.1996 / 19:23:04 / cg"
!
isFixedSize
"return true if the receiver cannot grow easily
(i.e. a grow may be expensive, since it involves a become:)"
^ true
!
isFloat
"return true, if the receiver is some kind of floating point number;
false is returned here.
Same as #isLimitedPrecisionReal, but a better name ;-)"
^ false
"Modified: / 14.11.2001 / 14:57:46 / cg"
!
isForm
"return true, if the receiver is some kind of form;
false is returned here - the method is only redefined in Form."
^ false
!
isFraction
"return true, if the receiver is some kind of fraction;
false is returned here - the method is only redefined in Fraction."
^ false
!
isImage
"return true, if the receiver is some kind of image;
false is returned here - the method is only redefined in Image."
^ false
!
isImageOrForm
"return true, if the receiver is some kind of image or form;
false is returned here - the method is only redefined in Image and Form."
^ false
!
isImmediate
"return true if I am an immediate object
i.e. I am represented in the pointer itself and
no real object header/storage is used me.
(currently, only SmallIntegers, some characters and nil return true)"
^ self class hasImmediateInstances
"Created: 3.6.1997 / 12:00:18 / cg"
!
isInteger
"return true, if the receiver is some kind of integer number;
false is returned here - the method is only redefined in Integer."
^ false
!
isJavaClass
"return true, if this is a javaClass.
false is returned here - the method is only redefined in JavaClass."
^ false
"Created: / 26.3.1997 / 13:34:54 / cg"
"Modified: / 8.5.1998 / 21:25:21 / cg"
!
isJavaClassRef
"return true, if this is a JavaClassRef.
false is returned here - the method is only redefined in JavaClassRef."
^ false
"Modified: / 8.5.1998 / 21:25:46 / cg"
"Created: / 24.12.1999 / 01:46:28 / cg"
!
isJavaContext
"return true, if this is a javaContext.
false is returned here - the method is only redefined in JavaContext."
^ false
"Created: / 8.5.1998 / 21:24:27 / cg"
"Modified: / 8.5.1998 / 21:25:35 / cg"
!
isJavaMethod
"return true, if this is a JavaMethod.
false is returned here - the method is only redefined in JavaMethod."
^ false
"Modified: / 8.5.1998 / 21:25:46 / cg"
"Created: / 25.9.1999 / 23:26:12 / cg"
!
isJavaMethodRef
"return true, if this is a JavaMethodRef.
false is returned here - the method is only redefined in JavaMethodRef."
^ false
"Modified: / 8.5.1998 / 21:25:46 / cg"
"Created: / 23.12.1999 / 19:44:51 / cg"
!
isJavaObject
"return true, if this is a javaObject.
false is returned here - the method is only redefined in JavaObject."
^ false
"Created: / 26.3.1997 / 13:34:48 / cg"
"Modified: / 8.5.1998 / 21:25:46 / cg"
!
isJavaScriptClass
"return true, if this is a javaScriptClass.
false is returned here - the method is only redefined in JavaScriptClass."
^ false
!
isKindOf:aClass
"return true, if the receiver is an instance of aClass or one of its
subclasses, false otherwise.
Advice:
use of this to check objects for certain attributes/protocoll should
be avoided; it limits the reusability of your classes by limiting use
to instances of certain classes and fences you into a specific inheritance
hierarchy.
Use check-methods to check an object for a certain attributes/protocol
(such as #isXXXX, #respondsTo: or #isNumber).
Using #isKindOf: is considered BAD STYLE.
Advice2:
Be aware, that using an #isXXX method is usually much faster than
using #isKindOf:; because isKindOf: has to walk up all the superclass
hierarchy, comparing every class on the way.
Due to caching in the VM, a call to #isXXX is normally reached via
a single function call.
"
%{ /* NOCONTEXT */
register OBJ thisClass;
thisClass = __Class(self);
while (thisClass != nil) {
if (thisClass == aClass) {
RETURN ( true );
}
thisClass = __ClassInstPtr(thisClass)->c_superclass;
}
RETURN ( false );
%}
"/
"/ the above code is equivalent to:
"/
"/ thisClass := self class.
"/ [thisClass notNil] whileTrue:[
"/ thisClass == aClass ifTrue:[^ true].
"/ thisClass := thisClass superclass
"/ ].
"/ ^ false
"/
!
isLayout
"return true, if the receiver is some kind of layout;
false is returned here - the method is only redefined in Layout."
^ false
!
isLazyValue
^ false
!
isLimitedPrecisionReal
"return true, if the receiver is some kind of floating point number;
false is returned here - the method is only redefined in LimitedPrecisionReal."
^ false
!
isList
"return true, if the receiver is some kind of list collection;
false is returned here - the method is only redefined in List."
^ false
"Created: / 11.2.2000 / 01:37:05 / cg"
!
isLiteral
"return true, if the receiver can be represented as a literal constant in ST syntax;
false is returned here - the method is redefined in some classes."
^ false
!
isMemberOf:aClass
"return true, if the receiver is an instance of aClass, false otherwise.
Advice:
use of this to check objects for certain attributes/protocoll should
be avoided; it limits the reusability of your classes by limiting use
to instances of a certain class.
Use check-methods to check an object for a certain attributes/protocol
(such as #isXXX, #respondsTo: or #isNumber);
Using #isMemberOf: is considered BAD STYLE.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ (self class) == aClass
!
isMeta
"return true, if the receiver is some kind of metaclass;
false is returned here - the method is only redefined in Metaclass."
^ false
!
isMethod
"return true, if the receiver is some kind of method;
false returned here - the method is only redefined in Method."
^ false
!
isMorph
"return true, if the receiver is some kind of morph;
false is returned here - the method is only redefined in Morph."
^ false
!
isNameSpace
"return true, if this is a nameSpace.
false is returned here - the method is only redefined in Namespace."
^ false
"Created: / 11.10.1996 / 18:08:56 / cg"
"Modified: / 8.5.1998 / 21:26:05 / cg"
!
isNamespace
"return true, if this is a nameSpace.
false is returned here - the method is only redefined in Namespace."
<resource:#obsolete>
self obsoleteMethodWarning:'use #isNameSpace'.
^ self isNameSpace
!
isNil
"return true, if the receiver is nil.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ false
!
isNilOrEmptyCollection
"return true if I am nil or an empty collection - false here.
Sigh: the same as Squeaks isEmptyOrNil - which one should be kept in the long run ?"
^ false
"Modified: / 13.11.2001 / 13:28:06 / cg"
!
isNumber
"return true, if the receiver is some kind of number;
false is returned here - the method is only redefined in Number."
^ false
!
isOrderedCollection
"return true, if the receiver is some kind of ordered collection (or list etc);
false is returned here - the method is only redefined in OrderedCollection."
^ false
!
isPoint
"return true, if the receiver is some kind of point;
false is returned here - the method is only redefined in Point."
^ false
!
isRectangle
"return true, if the receiver is some kind of rectangle;
false is returned here - the method is only redefined in Rectangle."
^ false
!
isRemoteObject
"return true, if the receiver is some kind of remoteObject,
false if its local - the method is only redefined in RemoteObject."
^ false
"Created: 28.10.1996 / 15:18:45 / cg"
"Modified: 28.10.1996 / 15:20:57 / cg"
!
isSequenceable
"return true, if the receiver is some kind of sequenceable collection;
false is returned here - the method is only redefined in SequenceableCollection."
^ false
!
isSequenceableCollection
"OBSOLETE: use isSequenceable for ST-80 compatibility.
This method is a historic leftover and will be removed soon ...
(although its name is much better than #isSequenceable - sigh)"
<resource:#obsolete>
self obsoleteMethodWarning:'use #isSequenceable'.
^ false
!
isStream
"return true, if the receiver is some kind of stream;
false is returned here - the method is only redefined in Stream."
^ false
!
isString
"return true, if the receiver is some kind of string;
false is returned here - the method is only redefined in CharacterArray."
^ false
!
isStringCollection
"return true, if the receiver is some kind of stringCollection;
false is returned here - the method is only redefined in StringCollection."
^ false
!
isSymbol
"return true, if the receiver is some kind of symbol;
false is returned here - the method is only redefined in Symbol."
^ false
!
isText
"return true, if the receiver is some kind of text object;
false is returned here - the method is only redefined in Text."
^ false
"Created: 12.5.1996 / 10:56:50 / cg"
!
isValueModel
"return true, if the receiver is some kind of valueModel;
false is returned here - the method is only redefined in ValueModel."
^ false
!
isVariable
"return true if the receiver has indexed instance variables,
false otherwise."
^ self class isVariable
!
isVariableBinding
"return true, if this is a binding for a variable.
false is returned here - the method is only redefined in Binding."
^ false
"Created: / 19.6.1997 / 17:38:44 / cg"
"Modified: / 8.5.1998 / 21:26:55 / cg"
!
isView
"return true, if the receiver is some kind of view;
false is returned here - the method is only redefined in View."
^ false
!
notEmptyOrNil
"Squeak compatibility:
return true if I am neither nil nor an empty collection.
Return true here."
^ true
!
notNil
"return true, if the receiver is not nil.
Notice:
This method is open coded (inlined) by the compiler(s)
- redefining it may not work as expected."
^ true
! !
!Object methodsFor:'tracing'!
traceInto:aRequestor level:level from:referrer
"double dispatch into tracer, passing my type implicitely in the selector"
^ aRequestor traceObject:self level:level from:referrer
"Created: / 2.9.1999 / 09:05:17 / stefan"
! !
!Object methodsFor:'user interaction & notifications'!
activityNotification:aString
"this can be sent from deeply nested methods, which are going to perform
some long-time activity.
If there is a handler for the ActivityNotificationSignal signal, that one is raised,
passing the argument. The handler should show this message whereever it likes,
and proceed. If there is no handler, this is simply ignored.
This is very useful to pass busy messages up to some higher level (typically a view)
which likes to display that message in its label or a busy-box.
It could also be put into some logfile or printed on the standard output/error."
ActivityNotificationSignal isHandled ifTrue:[
^ ActivityNotificationSignal raiseRequestWith:self errorString:aString
].
"
nil activityNotification:'hello there'
self activityNotification:'hello there'
"
"
ActivityNotificationSignal handle:[:ex |
ex errorString printNL.
ex proceed.
] do:[
'hello' printNL.
self activityNotification:'doing some long time computation'.
'world' printNL.
]
"
"Modified: 16.12.1995 / 18:23:42 / cg"
!
confirm:aString
"launch a confirmer, which allows user to enter yes or no.
return true for yes, false for no.
If no GUI is present (headless applications), true is returned."
"
on systems without GUI, or during startup, output a message
and return true (as if yes was answered)
Q: should we ask user by reading Stdin ?
"
Smalltalk isInitialized ifFalse:[
'*** confirmation requested during initialization:' errorPrintCR.
aString errorPrintCR.
'*** I''ll continue, assuming <yes> ...' errorPrintCR.
^ true
].
(Dialog isNil
or:[Screen isNil
or:[Screen current isNil
or:[Screen current isOpen not]]]) ifTrue:[
'confirm: ' infoPrint.
aString infoPrintCR.
'continue, assuming <yes>' infoPrintCR.
^ true
].
Dialog autoload. "in case its autoloaded"
^ Dialog confirm:aString
"
nil confirm:'hello'
self confirm:'hello'
"
"Modified: 20.5.1996 / 10:28:40 / cg"
!
confirm:aString orCancel:cancelBlock
"launch a confirmer, which allows user to enter yes, no or cancel.
return true for yes, false for no, or the value from cancelBlock for cancel.
If no GUI is present (headless applications), cancelBlock is returned."
|answer|
answer := self confirmWithCancel:aString.
answer isNil ifTrue:[
^ cancelBlock value
].
^ answer
"
self confirm:'hello' orCancel:[self halt]
"
"Modified: 20.5.1996 / 10:28:40 / cg"
!
confirmWithCancel:aString
"launch a confirmer, which allows user to enter yes, no or cancel.
return true for yes, false for no, nil for cancel.
If no GUI is present (headless applications), nil is returned."
"
on systems without GUI, or during startup, output a message
and return true (as if yes was answered)
Q: should we ask user by reading Stdin ?
"
Smalltalk isInitialized ifFalse:[
'*** confirmation requested during initialization:' errorPrintCR.
aString errorPrintCR.
'*** I''ll continue, assuming <cancel> ...' errorPrintCR.
^ nil
].
(Dialog isNil
or:[Screen isNil
or:[Screen current isNil
or:[Screen current isOpen not]]]) ifTrue:[
'confirm: ' infoPrint.
aString infoPrintCR.
'continue, assuming <cancel>' infoPrintCR.
^ nil
].
Dialog autoload. "in case its autoloaded"
^ Dialog confirmWithCancel:aString
"
nil confirmWithCancel:'hello'
self confirmWithCancel:'hello'
"
"Modified: 20.5.1996 / 10:28:40 / cg"
!
errorNotify:aString
"launch a Notifier, showing top stack, telling user something
and give user a chance to enter debugger."
^ self
errorNotify:aString
from:thisContext sender
allowDebug:true
"
nil errorNotify:'hello there'
self errorNotify:'hello there'
"
"Modified: / 16.11.2001 / 15:36:49 / cg"
!
errorNotify:aString from:aContext
"launch a Notifier, showing top stack (above aContext),
telling user something and give user a chance to enter debugger."
^ self errorNotify:aString from:aContext allowDebug:true
"Modified: / 17.8.1998 / 10:09:27 / cg"
!
errorNotify:aString from:aContext allowDebug:allowDebug
"launch a Notifier, showing top stack (above aContext),
telling user something and optionally give the user a chance to enter debugger."
|currentScreen con sender action boxLabels boxValues default|
Smalltalk isInitialized ifFalse:[
'errorNotification: ' print. aString printCR.
^ self
].
(Dialog isNil
or:[Screen isNil
or:[(currentScreen := Screen current) isNil
or:[currentScreen isOpen not]]]) ifTrue:[
"
on systems without GUI, simply show
the message on the Transcript and abort.
"
Transcript showCR:aString.
AbortSignal raise.
^ self
].
Processor activeProcessIsSystemProcess ifTrue:[
action := #debug.
sender := aContext.
Debugger isNil ifTrue:[
'****************** Cought Error while in SystemProcess ****************' errorPrintCR.
thisContext fullPrintAll.
action := #abort.
].
] ifFalse:[
Dialog autoload. "in case it's autoloaded"
Error handle:[:ex |
"/ a recursive error - quickly enter debugger
"/ this happened, when I corrupted the Dialog class ...
('Object [error]: ' , ex errorString , ' caught in errorNotification') errorPrintCR.
action := #debug.
ex return.
] do:[ |s|
sender := aContext.
sender isNil ifTrue:[
sender := thisContext sender.
].
"/ skip intermediate (signal & exception) contexts
DebugView notNil ifTrue:[
sender := DebugView interestingContextFrom:sender
].
"/ show the first few contexts
s := WriteStream with:aString.
s cr; cr.
con := sender.
1 to:15 do:[:n |
con notNil ifTrue:[
con printOn:s.
s cr.
con := con sender
]
].
(allowDebug and:[Debugger notNil]) ifTrue:[
boxLabels := #('Proceed' 'Abort' 'Copy Trace and Abort' 'Debug').
boxValues := #(#proceed #abort #copy #debug).
default := #debug.
] ifFalse:[
boxLabels := #('Proceed' 'Abort' 'Copy Trace and Abort').
boxValues := #(#proceed #abort #copy).
default := #abort.
].
action := Dialog
choose:s contents
label:('Exception [' , Processor activeProcess nameOrId , ']')
image:WarningBox errorIconBitmap
labels:boxLabels
values:boxValues
default:default
onCancel:nil.
].
].
action == #debug ifTrue:[
Debugger enter:sender withMessage:aString mayProceed:true
] ifFalse:[
action == #proceed ifTrue:[
^ self.
].
action == #copy ifTrue:[ |s|
s := '' writeStream.
sender fullPrintAllOn:s.
currentScreen rootView setTextSelection:s contents.
].
AbortSignal raise
]
"
nil errorNotify:'hello there'
self errorNotify:'hello there'
"
"Created: / 17.8.1998 / 10:09:26 / cg"
"Modified: / 16.11.2001 / 15:40:12 / cg"
!
information:aString
"launch an InfoBox, telling user something.
These info-boxes can be suppressed by handling the
UserNotification- or InformationSignal and proceeding in the handler."
InformationSignal isHandled ifTrue:[
^ InformationSignal raiseRequestWith:self errorString:aString
].
self notify:aString
"
nil information:'hello there'
self information:'hello there'
"
"
InformationSignal handle:[:ex |
'no box popped' printNL.
ex proceed.
] do:[
'hello' printNL.
self information:'some info'.
'world' printNL.
]
"
"Modified: 24.11.1995 / 22:29:49 / cg"
!
notify:aString
"launch a Notifier, telling user something.
Use #information: for ignorable messages."
Smalltalk isInitialized ifFalse:[
"/ thisContext fullPrintAll.
'information: ' print. aString printCR.
^ self
].
(Smalltalk isInitialized not
or:[Dialog isNil
or:[Screen isNil
or:[Screen current isNil
or:[Screen current isOpen not]]]]) ifTrue:[
"
on systems without GUI, simply show
the message on the Transcript and abort.
"
Transcript show:'notification: '; showCR:aString.
^ self
].
Dialog autoload. "in case its autoloaded"
Dialog information:aString
"
nil notify:'hello there'
self notify:'hello there'
"
"Modified: 20.5.1996 / 10:28:48 / cg"
!
warn:aString
"launch a WarningBox, telling user something.
These warn-boxes can be suppressed by handling the
UserNotification- or WarningSignal and proceeding in the handler."
WarningSignal isHandled ifTrue:[
^ WarningSignal raiseRequestWith:self errorString:aString
].
(Smalltalk isInitialized not
or:[Dialog isNil
or:[Screen isNil
or:[Screen current isNil
or:[Screen current isOpen not]]]]) ifTrue:[
"
on systems without GUI, simply show
the message on the Transcript and abort.
"
Transcript show:'warning: '; showCR:aString.
^ self
].
Dialog autoload. "in case its autoloaded"
Dialog warn:aString
"
nil warn:'hello there'
self warn:'hello there'
"
"
WarningSignal handle:[:ex |
ex proceed.
] do:[
'hello' printNL.
self warn:'some info'.
'world' printNL.
]
"
"Modified: 20.5.1996 / 10:28:53 / cg"
! !
!Object class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/libbasic/Object.st,v 1.438 2002-12-10 14:36:05 penk Exp $'
! !
Object initialize!