"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
WriteStream subclass:#ReadWriteStream
instanceVariableNames:''
classVariableNames:''
poolDictionaries:''
category:'Streams'
!
!ReadWriteStream class methodsFor:'documentation'!
copyright
"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
!
documentation
"
ReadWriteStreams allow both read- and write-access to some collection.
To allow this, they reenable some methods blocked in WriteStream.
(being one of the seldom places, where multiple inheritance could be
of good use in smalltalk).
Claus:
I personally find the ReadStream - WriteStream - ReadWriteStream
organization brain-damaged. It would be better to have an attribute
(such as readOnly / writeOnly / readWrite) in an InternalStream subclass
of Stream ...
[author:]
Claus Gittinger
"
! !
!ReadWriteStream methodsFor:'access-reading'!
next
"return the next element; advance read position.
If there are no more elements, nil is returned."
|element|
(position > readLimit) ifTrue:[^ self pastEnd].
element := collection at:position.
position := position + 1.
^ element
"Modified: 5.2.1996 / 21:57:40 / stefan"
!
peek
"return the element to be read next without advancing read position.
If there are no more elements, nil is returned."
(position > readLimit) ifTrue:[^ self pastEnd].
^ collection at:position
"Modified: 5.2.1996 / 21:57:47 / stefan"
! !
!ReadWriteStream methodsFor:'accessing'!
contents
"return the contents as written so far;
redefined to prevent confusion resulting due to
my superclasses optimization. (see WriteStream contents).
ST80 users if RWStream expect the contents array to remain
unchanged."
readLimit := readLimit max:position-1.
^ collection copyFrom:1 to:readLimit
"Created: / 30.10.1997 / 16:25:22 / cg"
"Modified: / 30.10.1997 / 18:37:09 / cg"
! !
!ReadWriteStream methodsFor:'converting'!
readStream
"return the receiver as a readStream - thats myself"
^ self
"Created: 29.11.1995 / 22:04:23 / stefan"
! !
!ReadWriteStream methodsFor:'positioning'!
reset
"set the read position to the beginning of the collection.
Re-redefined to prevent the collection from being emptied."
position := "0" 1
"Created: / 30.10.1997 / 16:17:45 / cg"
! !
!ReadWriteStream methodsFor:'queries'!
isReadable
"return true if the receiver supports reading - thats true"
^ true
! !
!ReadWriteStream class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/libbasic/ReadWriteStream.st,v 1.19 1997-11-02 17:52:46 cg Exp $'
! !