nextByte should (at least) return integer when reading from a string-stream
(should it check for single-byte string as well ?)
"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
"{ Package: 'stx:libbasic' }"
WriteStream subclass:#ReadWriteStream
instanceVariableNames:''
classVariableNames:''
poolDictionaries:''
category:'Streams'
!
!ReadWriteStream class methodsFor:'documentation'!
copyright
"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
!
documentation
"
ReadWriteStreams allow both read- and write-access to some collection.
To allow this, they reenable some methods blocked in WriteStream.
(being one of the seldom places, where multiple inheritance could be
of good use in smalltalk).
Claus:
I personally find the ReadStream - WriteStream - ReadWriteStream
organization brain-damaged. It would be better to have an attribute
(such as readOnly / writeOnly / readWrite) in an InternalStream subclass
of Stream ...
[author:]
Claus Gittinger
"
!
examples
"
|s|
s := ReadWriteStream with:'abcd'.
s reset.
s nextPut:$A.
s contents
"
! !
!ReadWriteStream methodsFor:'access-reading'!
next
"return the next element; advance read position.
If there are no more elements, nil is returned."
|element|
((position-ZeroPosition+1) > readLimit) ifTrue:[^ self pastEnd].
element := collection at:(position-ZeroPosition+1).
position := position + 1.
^ element
"Modified: 5.2.1996 / 21:57:40 / stefan"
!
nextByte
"return the next element; advance read pointer.
return nil, if there is no next element"
^ self next asInteger
!
peek
"return the element to be read next without advancing read position.
If there are no more elements, nil is returned."
((position-ZeroPosition+1) > readLimit) ifTrue:[^ self pastEnd].
^ collection at:(position-ZeroPosition+1)
"Modified: 5.2.1996 / 21:57:47 / stefan"
! !
!ReadWriteStream methodsFor:'accessing'!
contents
"return the contents as written so far;
redefined to prevent confusion resulting due to
my superclasses optimization. (see WriteStream contents).
ST80 users if RWStream expect the contents array to remain
unchanged."
readLimit := (readLimit ? 0) max:position-ZeroPosition.
^ collection copyFrom:1 to:readLimit
"Created: / 30.10.1997 / 16:25:22 / cg"
"Modified: / 30.10.1997 / 18:37:09 / cg"
!
reset
"set the read position to the beginning of the collection"
self resetPosition
! !
!ReadWriteStream methodsFor:'converting'!
readStream
"return the receiver as a readStream - thats myself"
^ self
"Created: 29.11.1995 / 22:04:23 / stefan"
! !
!ReadWriteStream methodsFor:'initialization'!
on:initialCollection
super on:initialCollection.
readLimit := 0.
!
with:initialCollection
super with:initialCollection.
readLimit := initialCollection size.
position := ZeroPosition.
! !
!ReadWriteStream methodsFor:'queries'!
isReadable
"return true if the receiver supports reading - thats true"
^ true
! !
!ReadWriteStream class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/libbasic/ReadWriteStream.st,v 1.23 2004-03-05 20:00:04 cg Exp $'
! !