"
 COPYRIGHT (c) 1994 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

Magnitude subclass:#LookupKey
	instanceVariableNames:'key'
	classVariableNames:''
	poolDictionaries:''
	category:'Collections-Support'
!

!LookupKey class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1994 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    LookupKey has been extracted from Association for ST-80 compatibility.
    This class is currently not used directly.

    [Instance variables:]

        key             <Object>        the key

    [author:]
        Claus Gittinger
"
! !

!LookupKey class methodsFor:'instance creation'!

key:aKey
    "return a new instance."

    ^ self basicNew key:aKey
! !

!LookupKey methodsFor:'accessing'!

key
    "return the key of the receiver"

    ^ key
!

key:anObject
    "set the key of the receiver to be anObject.
     Return the receiver"

    key := anObject
! !

!LookupKey methodsFor:'comparing'!

< aKey
    "return true, if the receivers KEY is less 
     than the arguments key. The argument must be a kind of lookupKey"

    ^ key < aKey key
!

= aLookupKey
    "return true if the receiver equals the argument.
     Notice, that in contrast to the less/greater compares,
     this compares both key AND value."

    ^ (self species == aLookupKey species) and:[key = aLookupKey key]
!

> aKey
    "return true, if the receivers KEY is greater 
     than the arguments key. The argument must be a kind of lookupKey"

    ^ key > aKey key
!

hash
    "return an integer useful for hashing on the receiver;
     redefined since = is redefined here."

    ^ key hash
! !

!LookupKey methodsFor:'printing & storing'!

displayString
    "return a string containing a printable representation
     of the receiver for displaying - redefined to use display string on
     the components for nicer look"

    ^ self class name , '(' , key displayString , ')'
!

printOn:aStream
    "return a string containing a printable representation
     of the receiver"

    key printOn:aStream.
! !

!LookupKey class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libbasic/LookupKey.st,v 1.8 1996-10-15 22:07:04 cg Exp $'
! !