"
 COPYRIGHT (c) 1988 by Claus Gittinger
              All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

Boolean subclass:#True
       instanceVariableNames:''
       classVariableNames:''
       poolDictionaries:''
       category:'Kernel-Objects'
!

True comment:'

COPYRIGHT (c) 1988 by Claus Gittinger
              All Rights Reserved

Class True has only one instance, true, representing logical truth.

$Header: /cvs/stx/stx/libbasic/True.st,v 1.5 1994-01-09 21:25:44 claus Exp $
'!

!True methodsFor: 'logical operations'!

& aBoolean
   "return true if both the receiver and the argument are true
    (since the receiver is true, return the argument, aBoolen)"

    ^ aBoolean
!

| aBoolean
   "return true if either the receiver or the argument are true
    (since the receiver is true, return true)"

    ^ true
!

not
   "return true if the receiver is false, false otherwise
    (since the receiver is true, return false)"

    ^ false
!

eqv:aBoolean
   "return true if both the receiver and the argument are the same truth value
    (since the receiver is true, return true if the argument is also)"

    ^ aBoolean
!

xor:aBoolean
   "return true if the receiver and the argument are different truth values
    (since the receiver is true, return true, if the argument is not)"

    ^ aBoolean not
! !

!True methodsFor: 'conditional evaluation'!

and:aBlock
    "evaluate aBlock if the receiver is true.
     since the receiver is known to be true,
     return the value of evaluating the block.
     - open coded by compiler"

    ^ aBlock value
!

or:aBlock
    "evaluate aBlock if the receiver is false.
     since the receiver is known to be true simply return true.
     - open coded by compiler"

    ^ self
!

ifTrue:aBlock
    "return the value of evaluating aBlock (since the receiver is true)
     - open coded by compiler"

    ^ aBlock value
!

ifFalse:aBlock
    "return the true alternative, nil (since the receiver is true)
     - open coded by compiler"

    ^ nil
!

ifTrue:trueBlock ifFalse:falseBlock
    "return the value of evaluating trueBlock (since the receiver is true)
     - open coded by compiler"

    ^ trueBlock value
!

ifFalse:falseBlock ifTrue:trueBlock
    "return the value of evaluating trueBlock (since the receiver is true)
     - open coded by compiler"

    ^ trueBlock value
! !

!True methodsFor: 'printing'!

printString
    "return a Character sequence representing the receiver"

    ^ 'true'
! !

!True methodsFor: 'binary storage'!

storeBinaryOn: stream manager: manager
    "store a binary representation of the receiver on stream;
     redefined, since true is stored with a special type-code"

    stream nextPut: manager codeForTrue
! !