"
 COPYRIGHT (c) 1988 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
"{ Package: 'stx:libbasic' }"

Object subclass:#MiniDebugger
	instanceVariableNames:'tracing stepping traceBlock command commandArg commandCount
		enteringContext dot nesting'
	classVariableNames:'NotFirstTimeEntered'
	poolDictionaries:''
	category:'System-Debugging-Support'
!

!MiniDebugger class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1988 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    a primitive (non graphical) debugger for use on systems without
    graphics or when the real debugger dies (i.e. an error occurs in
    the graphical debugger or the UI/event handler is broken).
    Also, if an interrupt occurs within the debuger, this one is called for.
    Needs a console.

    MiniDebugger enter

    [author:]
	Claus Gittinger
"
! !

!MiniDebugger class methodsFor:'instance creation'!

enter
    "enter a miniDebugger"

    ^ self
	enter:thisContext sender
	withMessage:'MiniDebugger'
	mayProceed:true
!

enter:aContext withMessage:aString mayProceed:mayProceed
    "enter a miniDebugger"

    |active con sender|

    StepInterruptPending := nil.

    Error handle:[:ex |
	ex return
    ] do:[
	thisContext isRecursive ifTrue:[
	    "/ 'recursive error in debugger ignored' errorPrintCR.
	    ^ self
	].

	aString errorPrintCR.
	Processor notNil ifTrue:[
	    active := Processor activeProcess.
	    'process: id=' errorPrint. active id errorPrint.
	    ' name=' errorPrint. active name errorPrintCR.

	    'context: ' errorPrint. aContext printString errorPrintCR.
	    (con := aContext) notNil ifTrue:[
		con := con sender.
		' ......: ' errorPrint. con printString errorPrintCR.
		[con notNil] whileTrue:[
		    sender := con sender.
		    (sender notNil and:[sender selector == con selector]) ifTrue:[
			' ......: ' errorPrint. sender printString errorPrintCR.
			' ......:  [** intermediate recursive contexts skipped **]' errorPrintCR.
			[sender notNil
			 and:[sender selector == con selector
			 and:[sender method == con method]]] whileTrue:[
			    con := sender.
			    sender := con sender.
			].
		    ].
		    con := sender.
		    ' ......: ' errorPrint. con printString errorPrintCR.
		]
	    ]
	].
	NotFirstTimeEntered ~~ true ifTrue:[
	    NotFirstTimeEntered := true.
	    'Type "c" to proceed, "?" for help' errorPrintCR.
	].
    ].

    OperatingSystem hasConsole ifFalse:[
	Error handle:[:ex |
	    ex return
	] do:[
	    self warn:('Unexpected error:\' , aString , '\\No MiniDebugger functionality available') withCRs .
	].

	Error handle:[:ex |
	    'cannot raise Abort - exiting ...' errorPrintCR.
	    OperatingSystem exit:10.
	] do:[
	    AbortOperationRequest raise.
	]
    ] ifTrue:[
	self new enter:aContext mayProceed:mayProceed.
    ].
    mayProceed ifFalse:[
	AbortOperationRequest raise
    ].
    ^ nil

    "Modified: / 19.5.1999 / 18:14:33 / cg"
!

enterException:ex
    "enter a debugger; if this is a recursive invocation, enter
     a MiniDebugger instead.
     This is the standard way of entering the debugger;
     sent from error- and halt messages."

    ^ self
	enter:ex returnableSuspendedContext
	withMessage:(ex creator name,': ',ex descriptionForDebugger)
	mayProceed:(ex mayProceed).
!

enterWithMessage:aString mayProceed:mayProceed
    "enter a miniDebugger"

    ^ self
	enter:thisContext sender
	withMessage:aString
	mayProceed:mayProceed

    "Modified: / 19.5.1999 / 18:14:33 / cg"
!

new
    "redefined to make certain that there is only one miniDebugger
     in the system"

    ^ self basicNew initialize.

"/    TheOneAndOnlyDebugger isNil ifTrue:[
"/        TheOneAndOnlyDebugger := self basicNew initialize
"/    ].
"/    ^ TheOneAndOnlyDebugger

    "
     TheOneAndOnlyDebugger := nil
    "

    "Modified: / 31.7.1998 / 17:08:07 / cg"
!

openOn:aProcess
    "enter a miniDebugger"

    ^ self
	enter:thisContext sender
	withMessage:'MiniDebugger [info]: Attention - process debugging not possible.'
	mayProceed:true

    "Modified: / 19.5.1999 / 18:14:33 / cg"
!

singleStep:aBlock
    |aDebugger|

    aDebugger := self new stepping.
    ObjectMemory stepInterruptHandler:aDebugger.
    ObjectMemory flushInlineCaches.
    StepInterruptPending := 1.
    InterruptPending := 1.
    aBlock value.
    StepInterruptPending := nil.
    ObjectMemory stepInterruptHandler:nil
!

trace:aBlock
    self trace:aBlock with:[:where | where errorPrintCR]

    "Modified: 20.5.1996 / 10:27:37 / cg"
!

trace:aBlock on:aStream
    self trace:aBlock with:[:where | where printString printOn:aStream.
				     aStream cr]
!

trace:aBlock with:aTraceBlock
    |aDebugger|

    aDebugger := self new tracingWith:aTraceBlock.
    ObjectMemory stepInterruptHandler:aDebugger.
    ObjectMemory flushInlineCaches.
    StepInterruptPending := 1.
    InterruptPending := 1.
    aBlock value.
    ObjectMemory stepInterruptHandler:nil.
    StepInterruptPending := nil.
    ^ nil
! !

!MiniDebugger methodsFor:'entering'!

enter:aContext mayProceed:mayProceed
    "regular entry, via unhandled exception"

    |c leaveCmd stillHere yesNo|

    enteringContext := dot := aContext.
    nesting := 0.
    c := aContext.
    [c notNil] whileTrue:[
	c selector == #enter:mayProceed: ifTrue:[
	    nesting := nesting + 1.
	].
	c := c sender.
    ].

    stillHere := true.
    [stillHere] whileTrue:[
	AbortOperationRequest handle:[:ex |
	    '** Abort caught - back in previous debugLevel' errorPrintCR.
	] do:[
	    Error handle:[:ex |
		StreamError handle:[:ex|
		    "You won't see this probably - but you will see it when doing a syscall trace"
		    'Error while processing error in MiniDebugger (Stdout closed?):' errorPrintCR.
		    ex description errorPrintCR.
		    OperatingSystem exit:10.
		] do:[
		    'Error while executing MiniDebugger command: ' errorPrint.
		    ex description errorPrintCR.
		    yesNo := self getCommand:'- (i)gnore / (p)roceed / (d)ebug / b(acktrace) ? '.
		    yesNo == $d ifTrue:[
			MiniDebugger enterWithMessage:'Debugging debugger' mayProceed:true.
			ex proceed
		    ].
		    yesNo == $p ifTrue:[
			ex proceed
		    ].
		    yesNo == $b ifTrue:[
			ex suspendedContext fullPrintAll.
			ex proceed
		    ].
		].
	    ] do:[
		[
		    leaveCmd := self commandLoop.
		] valueUnpreemptively.
	    ].
	].

	(leaveCmd == $s) ifTrue: [
	    self stepping.
	    ObjectMemory flushInlineCaches.
	    ObjectMemory stepInterruptHandler:self.
	    stillHere := false.
	    StepInterruptPending := 1.
	    InterruptPending := 1
	].
	(leaveCmd == $t) ifTrue: [
	    traceBlock := [:where | where fullPrint].
	    ObjectMemory flushInlineCaches.
	    ObjectMemory stepInterruptHandler:self.
	    stillHere := false.
	    StepInterruptPending := 1.
	    InterruptPending := 1
	].
	(leaveCmd == $c) ifTrue: [
	    traceBlock := nil.
	    ObjectMemory flushInlineCaches.
	    ObjectMemory stepInterruptHandler:nil.
	    stillHere := false.
	    stepping := false.
	    tracing := false.
	    StepInterruptPending := nil.
	    InterruptPending := nil
	].
	(leaveCmd == $a) ifTrue: [
	    "abort"
	    traceBlock := nil.
	    ObjectMemory flushInlineCaches.
	    ObjectMemory stepInterruptHandler:nil.
	    stepping := false.
	    tracing := false.
	    StepInterruptPending := nil.
	    InterruptPending := nil.
	    self doAbort.
	    stillHere := true.
	    "failed abort"
	].
    ].
    enteringContext := dot := nil.
    ^ nil

    "Modified (comment): / 29-09-2011 / 09:05:57 / cg"
!

stepInterrupt
    "entry via single stepinterrupt"

    |where|

    where := thisContext.        "where is stepInterrupt context"
    where notNil ifTrue:[
	where := where sender    "where is now interrupted methods context"
    ].
    stepping ifTrue:[
	where notNil ifTrue:[
	    where fullPrint
	] ifFalse:[
	    'stepInterrupt: no context' errorPrintCR
	].
	self enter:where mayProceed:true
    ] ifFalse:[
	where notNil ifTrue:[
	    traceBlock notNil ifTrue:[
		traceBlock value:where
	    ]
	] ifFalse:[
	    'traceInterrupt: no context' errorPrintCR
	].
	ObjectMemory flushInlineCaches.
	StepInterruptPending := 1.
	InterruptPending := 1
    ]

    "Modified: / 20-05-1996 / 10:23:11 / cg"
    "Modified (comment): / 29-09-2011 / 09:06:29 / cg"
! !

!MiniDebugger methodsFor:'initialization'!

initialize
    traceBlock := nil.
    tracing := false.
    stepping := false
! !

!MiniDebugger methodsFor:'private'!

findContext:aSelector
    |con|

    con := thisContext sender.
    [con notNil] whileTrue:[
	(con isBlockContext not and:[con selector == aSelector]) ifTrue:[
	    "got it"
	    ^ con
	].
	con := con sender
    ].
    ^ nil
!

garbageCollectCommand:id
    id == 3 ifTrue:[
	ObjectMemory reclaimSymbols.
	ObjectMemory compressOldSpace.
    ] ifFalse:[
	id == 2 ifTrue:[
	    ObjectMemory reclaimSymbols.
	] ifFalse:[
	    ObjectMemory garbageCollect.
	]
    ]
!

getContext
    |backtrace|

    backtrace := thisContext.
    (backtrace notNil) ifTrue: [
	[backtrace selector ~~ #commandLoop] whileTrue:[
	    backtrace := backtrace sender.
	].
	"remove Debugger commandLoop frame"
	backtrace := backtrace sender.
	"remove Debugger enter frame"
	backtrace := backtrace sender
    ].
    ^ backtrace

    "Modified: / 29-09-2011 / 09:00:14 / cg"
!

moveDotDown
    "/ sigh - must search
    |c|

    c := enteringContext.
    [ c notNil and:[ c sender ~~ dot ] ] whileTrue:[
	c := c sender.
    ].
    c notNil ifTrue:[
	dot := c.
	"/ dot fullPrint.
    ] ifFalse:[
	'** dot is the bottom of the calling chain' errorPrintCR.
    ].
!

moveDotUp
    dot sender notNil ifTrue:[
	dot := dot sender.
	"/ dot fullPrint.
    ] ifFalse:[
	'** dot is the top of the calling chain' errorPrintCR.
    ].
!

printBacktraceFrom:aContext
    |context n|

    aContext isNil ifTrue:[
	'no context' errorPrintCR.
	^ self
    ].

    context := aContext.
    n := commandCount.
    [context notNil] whileTrue: [
	context fullPrint.
	context := context sender.
	n notNil ifTrue:[
	    n := n - 1.
	    n <= 0 ifTrue:[
		^ self
	    ]
	]
    ]
!

printDot
    dot fullPrint.
    '  receiver: ' errorPrint. dot receiver errorPrintCR.
    '  selector: ' errorPrint. dot selector errorPrintCR.
    '  args: ' errorPrintCR.
    dot args keysAndValuesDo:[:idx :eachArg |
	'    ' errorPrint. idx errorPrint. ': ' errorPrint. eachArg errorPrintCR.
    ].
    '  vars: ' errorPrintCR.
    dot vars keysAndValuesDo:[:idx :eachVar |
	'    ' errorPrint. idx errorPrint. ': ' errorPrint. eachVar errorPrintCR.
    ].
!

printDotsMethodSource
    self printDotsMethodSource:false
!

printDotsMethodSource:full
    |home mthd src pcLineNr startLnr stopLnr|

    home := dot methodHome.
    mthd := home method.
    mthd isNil ifTrue:[
	'** no source **' errorPrintCR.
	^ self.
    ].
    src := mthd source.
    src isNil ifTrue:[
	'** no source **' errorPrintCR.
	^ self.
    ].
    pcLineNr := dot lineNumber.

    src := src asCollectionOfLines.
    full ifTrue:[
	startLnr := 1.
	stopLnr := src size.
    ] ifFalse:[
	startLnr := pcLineNr-10 max:1.
	stopLnr := pcLineNr+10 min:src size.
    ].
    startLnr to:stopLnr do:[:lNr |
	lNr == pcLineNr ifTrue:[
	    '>> ' errorPrint.
	] ifFalse:[
	    '   ' errorPrint.
	].
	(lNr printStringLeftPaddedTo:3) errorPrint. ' ' errorPrint.
	(src at:lNr) errorPrintCR.
    ]
!

stepping
    traceBlock := nil.
    tracing := false.
    stepping := true
!

tracingWith:aBlockOrNil
    traceBlock := aBlockOrNil.
    stepping := false.
    tracing := true
! !

!MiniDebugger methodsFor:'user commands'!

commandLoop
    "read-eval commands, until one of the continue, abort or single step commands is entered;
     return the last command character"

    |cmd done|

    done := false.
    [done] whileFalse:[
	cmd := self getCommand:nil.
	cmd isNil ifTrue:[   "/ EOF is treated like continue command
	    cmd := $c
	].
	done := self doCommand:cmd.
    ].
    ^ cmd

    "Modified (comment): / 29-09-2011 / 09:02:24 / cg"
!

doAbort
    |con sig|

    (sig := AbortOperationRequest) isHandled ifTrue:[
	sig raise.
	'abort raise failed' errorPrintCR.
    ].

    "TEMPORARY kludge - find event handler context
     this will be removed, once real debugging is possible
    "
    con := self findContext:#processEvent.
    con isNil ifTrue:[
	con := self findContext:#dispatch.
    ].
    con notNil ifTrue:[
	"got it"
	con return.
	'return failed' errorPrintCR.
    ].

    'found no context to resume' errorPrintCR.

    "Modified: / 16.11.2001 / 17:39:14 / cg"
!

doCommand:cmd
    "a single command;
     return true, if command loop should be finished"

    |id proc bool|

    commandArg notEmptyOrNil ifTrue:[
	id := Number readFrom:commandArg onError:nil.
	id notNil ifTrue:[
	    proc := Process allSubInstances detect:[:p | p id == id] ifNone:nil.
	    proc == Processor activeProcess ifTrue:[
		id := proc := nil
	    ]
	] ifFalse:[
	    commandArg = '-' ifTrue:[
		bool := false
	    ] ifFalse:[
		commandArg = '+' ifTrue:[
		    bool := true
		]
	    ]
	]
    ].

    (cmd == $w) ifTrue:[
	proc notNil ifTrue:[
	    '-------- walkback of process ' errorPrint. id errorPrint. ' -------' errorPrintCR.
	    self printBacktraceFrom:(proc suspendedContext)
	] ifFalse:[
	    id notNil ifTrue:[
		'no process with id: ' errorPrint. id errorPrintCR.
	    ] ifFalse:[
		'-------- walkback of current process -------' errorPrintCR.
		self printBacktraceFrom:(self getContext)
	    ]
	].
	^ false
    ].

    (cmd == $b) ifTrue:[
	proc notNil ifTrue:[
	    '-------- VM walkback of process ' errorPrint. id errorPrint. ' -------' errorPrintCR.
	    ObjectMemory printStackBacktraceFrom:(proc suspendedContext)
	] ifFalse:[
	    id notNil ifTrue:[
		'no process with id: ' errorPrint. id errorPrintCR.
	    ] ifFalse:[
		'-------- VM walkback of current process -------' errorPrintCR.
		ObjectMemory printStackBacktrace
	    ]
	].
	^ false
    ].

    (cmd == $S) ifTrue:[
	'saving "crash.img"...' errorPrint.
	ObjectMemory writeCrashImage.
	'done.' errorPrintCR.
	^ false
    ].
    (cmd == $C) ifTrue:[
	|changesFilename|

	changesFilename := Timestamp now
	     printStringFormat:'changes_%(year)-%(month)-%(day)__%h:%m:%s.chg'.
	OperatingSystem isMSWINDOWSlike ifTrue:[ changesFilename replaceAll:$: with:$_ ].

	ChangeSet current fileOutAs: changesFilename.
	('saved session changes to "',changesFilename,'".') errorPrintCR.
	^ false
    ].

    (cmd == $B) ifTrue:[
	self printAllBacktraces.
	^ false
    ].

    (cmd == $P) ifTrue:[
	self showProcesses:#all.
	^ false
    ].
    (cmd == $p) ifTrue:[
	self showProcesses:#live.
	^ false
    ].

    (cmd == $r) ifTrue:[
	dot receiver errorPrintCR.
	^ false
    ].

    (cmd == $i) ifTrue:[
	(commandArg ? '') withoutSeparators notEmpty ifTrue:[
	    MiniInspector openOn:(Parser evaluate:commandArg).
	] ifFalse:[
	    MiniInspector openOn:(dot receiver).
	].
	^ false
    ].

    (cmd == $I) ifTrue:[
	self interpreterLoopWith:nil.
	^ false
    ].
    (cmd == $E) ifTrue:[
	Parser evaluate:commandArg.
	^ false
    ].
    (cmd == $e) ifTrue:[
	(Parser evaluate:commandArg) errorPrintCR.
	^ false
    ].

    (cmd == $c) ifTrue:[^ true].
    (cmd == $s) ifTrue:[^ true].
    (cmd == $t) ifTrue:[^ true].
    (cmd == $a) ifTrue:[^ true].

    (cmd == $u) ifTrue:[
	stepping := false.
	tracing := false.
	Processor activeProcess vmTrace:false.
	^ false
    ].

    (cmd == $h) ifTrue:[
	(bool notNil) ifTrue:[
	    Smalltalk ignoreHalt:bool not.
	].
	'halts are ' errorPrint. (Smalltalk ignoreHalt ifTrue:['disabled'] ifFalse:['enabled']) errorPrintCR.
	^ false
    ].

    (cmd == $R) ifTrue:[
	proc notNil ifTrue:[
	    proc resume.
	].
	^ false
    ].

    (cmd == $T) ifTrue:[
	proc notNil ifTrue:[
	    proc terminate.
	] ifFalse:[
	    id notNil ifTrue:[
		'no process with id: ' errorPrint. id errorPrintCR.
	    ] ifFalse:[
		Processor terminateActive
	    ]
	].
	^ false
    ].

    (cmd == $W) ifTrue:[
	proc notNil ifTrue:[
	    'stopping process id: ' errorPrint. id errorPrintCR.
	    proc stop.
	] ifFalse:[
	    'invalid process id: ' errorPrint. id errorPrintCR.
	].
	^ false
    ].

    (cmd == $a) ifTrue:[
	"without id-arg, this is handled by caller"
	proc notNil ifTrue:[
	    'aborting process id: ' errorPrint. id errorPrintCR.
	    proc interruptWith:[AbortOperationRequest raise]
	] ifFalse:[
	    'aborting' errorPrintCR.
	].
	^ false
    ].

    (cmd == $Q) ifTrue:[
	proc notNil ifTrue:[
	    proc terminateNoSignal.
	] ifFalse:[
	    id notNil ifTrue:[
		'no process with id: ' errorPrint. id errorPrintCR.
	    ] ifFalse:[
		Processor terminateActiveNoSignal
	    ]
	].
	^ false
    ].

    (cmd == $g) ifTrue:[
	self garbageCollectCommand:id.
	^ false
    ].

    (cmd == $U) ifTrue:[
	MessageTracer unwrapAllMethods.
	^ false
    ].
    (cmd == $D) ifTrue:[
	Breakpoint disableAllBreakpoints.
	^ false
    ].
    (cmd == $X) ifTrue:[
	Smalltalk fatalAbort.
	"/ not reached
	^ false
    ].
    (cmd == $x) ifTrue:[
	OperatingSystem exit.
	"/ not reached
	^ false
    ].

    (cmd == $.) ifTrue:[self printDot. ^ false ].
    (cmd == $l) ifTrue:[self printDotsMethodSource:false. ^ false ].
    (cmd == $L) ifTrue:[self printDotsMethodSource:true. ^ false ].
    (cmd == $-) ifTrue:[self moveDotUp. self printDot. ^ false ].
    (cmd == $+) ifTrue:[self moveDotDown. self printDot. ^ false ].
    (cmd == $?) ifTrue:[
	commandArg notEmpty ifTrue:[
	    self helpOn:commandArg. ^ false
	]
    ].

    "/ avoid usage print if return was typed ...
    ((cmd == Character return)
    or:[cmd == Character linefeed]) ifTrue:[^ false].

    self showValidCommandHelp.
    ^ false.

    "Created: / 29-09-2011 / 08:58:47 / cg"
!

getCommand:prompt
"/    Screen notNil ifTrue:[
"/        Screen allScreens do:[:aScreen |
"/            aScreen ungrabPointer.
"/            aScreen ungrabKeyboard.
"/        ].
"/    ].

    Display notNil ifTrue:[
	Display ungrabPointer.
	Display ungrabKeyboard.
    ].

    (prompt
	? (nesting == 0 ifTrue:[
	    'MiniDebugger> '
	  ] ifFalse:[
	    'MiniDebugger' , nesting printString , '>'
	  ])) errorPrint.

    UserInterrupt handle:[:ex |
	ex restart
    ] do:[
	|c cmd arg cnt|

	cmd := Character fromUser.
	cmd isNil ifTrue:[
	    "
	     mhmh end-of-file;
	     return a 'c' (for continue); hope thats ok.
	    "
	    cmd := $c
	].

	cnt := nil.
	(cmd isDigit) ifTrue:[
	    cnt := 0.
	    [
		cnt := (cnt * 10) + cmd digitValue.
		cmd := Character fromUser
	    ] doWhile:[cmd notNil and:[cmd isDigit]].
	    [cmd notNil and:[cmd == Character space]] whileTrue:[
		cmd := Character fromUser
	    ].
	].

	"
	 collect to end-of-line in arg
	"
	c := cmd.
	arg := ''.
	[c isNil or:[c isEndOfLineCharacter]] whileFalse: [
	    arg := arg copyWith:c.
	    c := Character fromUser.
	].
	commandArg := (arg copyFrom:2) withoutSeparators.
	command := cmd.
	commandCount := cnt.
    ].
    ^ command

    "Modified: / 31.7.1998 / 16:11:01 / cg"
!

helpOn:commandArg
    |args className sym val match showMethod|

    commandArg withoutSeparators isEmpty ifTrue:[
	'usage: H className [methodPattern]' errorPrintCR.
	^self
    ].
    args := commandArg asCollectionOfWords.
    className := args first.

    (sym := className asSymbolIfInterned) isNil ifTrue:[
	'no such class' errorPrintCR.
	^ self.
    ].
    val := Smalltalk at:sym ifAbsent:['no such class' errorPrintCR. ^ self.].
    val isBehavior ifFalse:[
	'not a class: ' errorPrint. className errorPrintCR.
	val := val class.
	'showing help for ' errorPrint. val name errorPrintCR.
    ].
    args size > 1 ifTrue:[
	match := args at:2
    ] ifFalse:[
	match := '*'
    ].

    showMethod :=
	[:sel :cls |
	    |mthd|

	    ((match includesMatchCharacters and:[ sel matches:match caseSensitive:false])
	    or:[ sel asLowercase startsWith:match asLowercase ]) ifTrue:[
		mthd := cls compiledMethodAt:sel.
		mthd category ~= 'documentation' ifTrue:[
		    sel errorPrintCR.
		    (mthd comment ? '') asStringCollection do:[:l |
			'    ' errorPrint. l withoutSeparators errorPrintCR.
		    ].
		    '' errorPrintCR
		].
	    ].
	].

    val theMetaclass selectors copy sort do:[:sel |
	showMethod value:sel value:val theMetaclass
    ].
    val theNonMetaclass selectors copy sort do:[:sel |
	showMethod value:sel value:val theNonMetaclass
    ].
!

interpreterLoopWith:anObject
    'MinDebugger read-eval-print loop; exit with "#exit"; help with "?"' printCR.
    ReadEvalPrintLoop new
	doChunkFormat:false;
	error:Stderr;
	prompt:'mDBG > ';
	readEvalPrintLoop.

"/    |line done rslt|
"/
"/    'read-eval-print loop; exit with empty line' printCR.
"/    '' printCR.
"/
"/    done := false.
"/    [done] whileFalse:[
"/        '> ' print.
"/
"/        line := Stdin nextLine.
"/        (line size == 0) ifTrue:[
"/            done := true
"/        ] ifFalse:[
"/            "/ rslt := Compiler evaluate:line
"/            "/                  receiver:anObject
"/            "/                  notifying:nil.
"/
"/            rslt := Compiler
"/                evaluate:line
"/                in:dot
"/                receiver:dot receiver
"/                notifying:self "/ nil
"/                ifFail:[].
"/            rslt printCR.
"/        ]
"/    ]

    "Modified: / 31.7.1998 / 16:01:47 / cg"
!

printAllBacktraces
    Process allInstancesDo:[:p |
	(p isActive not
	and:[p isDead not]) ifTrue:[
	    '---------------------------------------------------------' errorPrintCR.
	    '  proc id=' errorPrint. p id errorPrint.
	    ' name=''' errorPrint. p name errorPrint.
	    ''' createdBy: ' errorPrint. p creatorId errorPrint.
	    ' state=' errorPrint.  p state errorPrint.
	    ' prio=' errorPrint. p priority errorPrintCR.
	    '' errorPrintCR. '' errorPrintCR.

	    self printBacktraceFrom:(p suspendedContext)
	]
    ]
!

showProcesses
    self showProcesses:#all
!

showProcesses:how
    |active|

    active := Processor activeProcess.
    'current id=' errorPrint. active id errorPrint. ' name=''' errorPrint. active name errorPrint. '''' errorPrintCR.

    (Process allSubInstances sort:[:a :b | (a id ? -1)<(b id ? -1)]) do:[:p |
	|doShow|

	doShow := (how == #all).
	doShow := doShow or:[ (how == #dead) and:[ p isDead ]].
	doShow := doShow or:[ (how ~~ #dead) and:[ p isDead not ]].
	doShow ifTrue:[
	    'proc id=' errorPrint. (p id printStringPaddedTo:6) errorPrint.
	    (p state printStringPaddedTo:10) errorPrint.
	    ' pri=' errorPrint. (p priority printStringPaddedTo:2) errorPrint.
	    ' creator:' errorPrint. (p creatorId printStringPaddedTo:5) errorPrint.
	    ' group:' errorPrint. (p processGroupId printStringPaddedTo:5) errorPrint.
	    ' sys:' errorPrint. (p isSystemProcess ifTrue:'y' ifFalse:'n') errorPrint.
	    ' ui:' errorPrint. (p isGUIProcess ifTrue:'y' ifFalse:'n') errorPrint.
	    ' name=''' errorPrint. p name errorPrint.
	    '''' errorPrintCR.
	]
    ]

    "Modified: / 31.7.1998 / 16:30:19 / cg"
!

showValidCommandHelp
	'valid commands:
   c ........ continue
   s ........ step
   t ........ trace (continue with trace)
   a [id] ... abort (i.e. raise abort signal) in (current) process
   T [id] ... terminate (current) process
   W [id] ... stop (current) process
   R [id] ... resume (current) process
   Q [id] ... quick terminate (current) process - no unwinds or cleanup

   p ........ list processes ("P" for full list)
   w [id] ... walkback (of current/process with id)
   b [id] ... full (VM) backtrace with more detail
   B ........ backtrace of all other processes

   U ........ unwrap all traced/breakpointed methods
   D ........ disable all line breakpoints
   h [-/+] .. disable/enable halts
   g ........ collect all garbage
   g 2 ...... collect all garbage & reclaim symbols
   g 3 ...... collect all garbage, reclaim symbols and compress

   S ........ save snapshot into "crash.img"
   C ........ save session changes to a separate change file
   x ........ exit Smalltalk ("X" to exit with core dump)

   . ........ print dot (the current context)
   - ........ move dot up (sender)
   + ........ move dot down (called context)
   l ........ list dot''s method source around PC ("L" for full list)

   r ........ receiver (in dot) printString
   i [expr] . inspect expression (or receiver in dot)
   I ........ interpreter (expression evaluator)
   e expr ...  evaluate expression & print result ("E" to not print)
   ? c [p] ..  help on class c (selectors matching p)
'  errorPrintCR.

   (XWorkstation notNil and:[ Screen default isKindOf:XWorkstation ]) ifTrue:[
'   To repair a broken X-Connection, enter an interpreter (enter "I") and evaluate:
      Display := XWorkstation new.
      Display initializeFor:''localhost:0''.
      Display startDispatch.
      NewLauncher openOnDevice:Display.
      #exit
    then enter "c" to continue; a NewLauncher should pop up soon.
'  errorPrintCR
    ]

    "Modified: / 03-02-2014 / 10:38:36 / cg"
! !

!MiniDebugger class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libbasic/MiniDebugger.st,v 1.103 2014-06-25 07:43:51 stefan Exp $'
!

version_CVS
    ^ '$Header: /cvs/stx/stx/libbasic/MiniDebugger.st,v 1.103 2014-06-25 07:43:51 stefan Exp $'
! !