"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

AbstractTime subclass:#Time
	instanceVariableNames:'timeEncoding'
	classVariableNames:''
	poolDictionaries:''
	category:'Magnitude-General'
!

!Time class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    Instances of time represent a particular time-of-day.
    Since they only store hours, minutes and seconds within a day,
    they cannot be used to compare times across midnight 
    (i.e. they should not be used as timeStamps).

    Use instances of AbsoluteTime (and read the comment there) to do this.

    Examples:
        |t|

        t := Time now.
        Transcript showCR:t.


        |t1 t2|

        t1 := Time now.
        (Delay forSeconds:10) wait.
        t2 := Time now.
        t2 - t1   

    [author:]
        Claus Gittinger

    [see also:]
        Date AbsoluteTime AbstractTime OperatingSystem
        Filename
"
! !

!Time class methodsFor:'instance creation'!

hour:h minutes:m seconds:s
    "return an instance of Time representing the given time.
     See also Time now / Date today / AbsoluteTime now."

    ^ self basicNew setHour:h minutes:m seconds:s

    "
     Time hour:2 minutes:33 seconds:0 
     Time hour:0 minutes:0 seconds:0 
     Time hour:24 minutes:0 seconds:0 
     Time hour:23 minutes:59 seconds:59 
    "

    "Modified: 19.4.1996 / 15:32:40 / cg"
!

readFrom:aStringOrStream onError:exceptionBlock
    "return a new Time, reading a printed representation from aStream.
     If no pm follows the time, the string is interpreted as either 24 hour format
     or being am."

    ErrorSignal handle:[:ex |
        ^ exceptionBlock value
    ] do:[
        |str hour min sec ex|

        str := aStringOrStream readStream.

        ex := [^ exceptionBlock value].
        hour := Integer readFrom:str onError:ex.
        (hour between:0 and:24) ifFalse:[ex value].

        [str peek isDigit] whileFalse:[str next].
        min := Integer readFrom:str onError:ex.
        (min between:0 and:59) ifFalse:[ex value].

        [str peek isDigit] whileFalse:[str next].
        sec := Integer readFrom:str onError:ex.
        (sec between:0 and:59) ifFalse:[ex value].

        [str peek == Character space] whileTrue:[str next].
        (str peek == $p) ifTrue:[
            "pm"
            hour := hour + 12
        ].
        ^ self basicNew setHour:hour minutes:min seconds:sec
    ]

    "
     Time readFrom:'18:22:00'    
     Time readFrom:'14:00:11'    
     Time readFrom:'7:00:11'     
     Time readFrom:'6:22:00 pm'   
     Time readFrom:'2:00:11 pm'  
     Time readFrom:'7:00:11 am'  
    "

    "Modified: 8.10.1996 / 19:32:11 / cg"
! !

!Time methodsFor:'accessing'!

day
    "catch day access - Time does not know about it"

    ^ self shouldNotImplement
!

hours
    "return the number of hours since midnight (i.e. 0..23)"

    ^ timeEncoding // 3600

    "
     Time now hours
    "
!

minutes
    "return the number of minutes within the hour (i.e. 0..59)"

    ^ (timeEncoding \\ 3600) // 60

    "
     Time now minutes
    "
!

month 
    "catch month access - Time does not know about it"

    ^ self shouldNotImplement
!

seconds
    "return the number of seconds within the minute (i.e. 0..59)"

    ^ (timeEncoding \\ 3600) \\ 60

    "
     Time now seconds
    "
!

year
    "catch year access - Time does not know about it"

    ^ self shouldNotImplement
! !

!Time methodsFor:'comparing'!

< aTime
    "return true if the argument, aTime is before the receiver"

    ^ timeEncoding < aTime timeEncoding
!

= aTime
    "return true if the argument, aTime represents the same timeOfDay"

    aTime class == self class ifTrue:[
	^ timeEncoding == aTime timeEncoding
    ].
    (aTime species == self species) ifFalse:[^ false].
    ^ self asSeconds == aTime asSeconds
!

> aTime
    "return true if the argument, aTime is after the receiver"

    ^ timeEncoding > aTime timeEncoding
!

hash
    "return an integer useful for hashing on times"

    ^ timeEncoding
! !

!Time methodsFor:'converting'!

asAbsoluteTime
    "return an AbsoluteTime object from the receiver.
     The date components are taken from today."

    |today|

    today := Date today.
    ^ AbsoluteTime day:today day month:today month year:today year
		   hour:self hours minutes:self minutes seconds:self seconds
    "
     Time now asAbsoluteTime
    "
!

asSeconds
    "return the number of seconds elapsed since midnight"

    ^ timeEncoding

    "
     Time now asSeconds
    "
!

asTime
    "return a Time object from the receiver - thats the receiver."

    ^ self
! !

!Time methodsFor:'printing & storing'!

print12HourFormatOn:aStream
    "append a printed representation of the receiver to aStream.
     Format is hh:mm:ss am/pm (i.e. 12-hour american format)."

    |h m s ampm|

    h := self hours.
    h > 12 ifTrue:[
	h := h - 12.
    ] ifFalse:[
	h < 1 ifTrue:[
	    h := 12
	]
    ].
    h printOn:aStream.
    aStream nextPut:$:.
    m := self minutes.
    (m < 10) ifTrue:[aStream nextPut:$0].
    m printOn:aStream.
    aStream nextPut:$:.
    s := self seconds.
    (s < 10) ifTrue:[aStream nextPut:$0].
    s printOn:aStream.
    h >= 12 ifTrue:[
	ampm := ' am'
    ] ifFalse:[
	ampm := ' pm'
    ].
    aStream nextPutAll:ampm

    "
     Time now print12HourFormatOn:Transcript. Transcript cr
    "
!

print24HourFormatOn:aStream
    "append a printed representation of the receiver to aStream.
     Format is hh:mm:ss (i.e. 24-hour european format)."

    |h m s|

    h := self hours.
    (h < 10) ifTrue:[aStream nextPut:$0].
    h printOn:aStream.
    aStream nextPut:$:.
    m := self minutes.
    (m < 10) ifTrue:[aStream nextPut:$0].
    m printOn:aStream.
    aStream nextPut:$:.
    s := self seconds.
    (s < 10) ifTrue:[aStream nextPut:$0].
    s printOn:aStream

    "
     Time now print24HourFormatOn:Transcript. Transcript cr
    "
!

printOn:aStream
    "append a printed representation of the receiver to aStream.
     Format is hh:mm:ss either in 12-hour or 24-hour format.
     depending on the setting of LanguageTerritory.
     I dont know what ST-80 does here (12-hour format ?)"

    LanguageTerritory == #us ifTrue:[
        self print12HourFormatOn:aStream
    ] ifFalse:[
        self print24HourFormatOn:aStream
    ]

    "
     Time now printOn:Transcript. Transcript cr
    "

    "Modified: 22.2.1996 / 16:58:30 / cg"
!

shortPrintString
    "dummy - for now"

    ^ self printString

    "Created: 20.6.1997 / 17:17:01 / cg"
! !

!Time methodsFor:'private'!

fromOSTime:osTime
    "set my time, given an osTime"

    |h m s|

    OperatingSystem computeTimePartsOf:osTime for:[
        :hours :minutes :secs :millis |

        h := hours.
        m := minutes.
        s := secs.
    ].
    self setHour:h minutes:m seconds:s

    "Modified: 1.7.1996 / 15:21:06 / cg"
!

getSeconds
    ^ timeEncoding
!

setHour:h minutes:m seconds:s
    "set my time given individual values"

    timeEncoding := ((h\\24) * 60 * 60 ) + (m * 60) + s.
!

setSeconds:secs
    "set my time given seconds since midnight"

    timeEncoding := secs
!

timeEncoding
    "the internal encoding is stricktly private, 
     and should not be used outside."

    ^ timeEncoding
!

timeEncoding:encoding
    "the internal encoding is stricktly private, 
     and should not be used outside."

    timeEncoding := encoding
! !

!Time class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libbasic/Time.st,v 1.31 1997-06-20 15:29:38 cg Exp $'
! !