First Version.
"
COPYRIGHT (c) 1992 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
'From Smalltalk/X, Version:2.10.9 on 6-may-1996 at 14:57:01' !
Dictionary subclass:#WeakValueDictionary
instanceVariableNames:''
classVariableNames:''
poolDictionaries:''
category:'Collections-Unordered'
!
!WeakValueDictionary class methodsFor:'documentation'!
copyright
"
COPYRIGHT (c) 1992 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
!
documentation
"
WeakValueDictionaries behave like Dictionaries,
as long as the values are still referenced by some
other (non-weak) object.
However, once the last non-weak reference ceases to exist,
the Dictionary will return nil for the value at position key.
(with some delay: it will be removed after the next garbage collect).
[author:]
Stefan Vogel
[See also:]
WeakArray WeakIdentityDictionary WeakIdentitySet
"
! !
!WeakValueDictionary methodsFor:'adding & removing'!
at:key put:anObject
"add the argument anObject under key, aKey to the receiver.
Return anObject (sigh).
Redefined to block interrupts, to avoid trouble when dependencies
are added within interrupting high prio processes."
|wasBlocked|
wasBlocked := OperatingSystem blockInterrupts.
super at:key put:anObject.
wasBlocked ifFalse:[OperatingSystem unblockInterrupts].
^ anObject
"Modified: 22.4.1996 / 17:39:09 / cg"
"Modified: 6.5.1996 / 12:22:26 / stefan"
"Created: 6.5.1996 / 14:47:37 / stefan"
!
removeKey:aKey ifAbsent:aBlock
"remove the association under aKey from the collection,
return the value previously stored there..
If it was not in the collection return the result
from evaluating aBlock.
Redefined to avoid synchronization problems, in case
of interrupts (otherwise, there could be some other operation
on the receiver done by another process, which garbles my contents)."
|wasBlocked ret|
wasBlocked := OperatingSystem blockInterrupts.
[
ret := super removeKey:aKey ifAbsent:aBlock
] valueNowOrOnUnwindDo:[
wasBlocked ifFalse:[OperatingSystem unblockInterrupts]
].
^ ret
"Modified: 6.5.1996 / 12:44:07 / stefan"
"Created: 6.5.1996 / 14:47:37 / stefan"
!
removeValue:aKey ifAbsent:aBlock
"remove the association under aValue from the collection,
return the value previously stored there..
If it was not in the collection return the result
from evaluating aBlock.
Redefined to avoid synchronization problems, in case
of interrupts (otherwise, there could be some other operation
on the receiver done by another process, which garbles my contents)."
|wasBlocked ret|
wasBlocked := OperatingSystem blockInterrupts.
[
ret := super removeValue:aKey ifAbsent:aBlock
] valueNowOrOnUnwindDo:[
wasBlocked ifFalse:[OperatingSystem unblockInterrupts]
].
^ ret.
"Created: 6.5.1996 / 14:47:37 / stefan"
! !
!WeakValueDictionary methodsFor:'private'!
valueContainerOfSize:n
"return a container for values of size n.
use WeakArrays here."
|w|
^ WeakArray new:n.
"Created: 6.5.1996 / 14:47:37 / stefan"
! !
!WeakValueDictionary class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/libbasic/WeakValueDictionary.st,v 1.1 1996-05-07 22:24:09 stefan Exp $'
! !