"{ Package: 'stx:libbasic2' }"

HashStream subclass:#CRC32Stream

	instanceVariableNames:'crc'

	classVariableNames:'CrcTable'

	poolDictionaries:''

	category:'System-Crypt-Streams'

!

!CRC32Stream class methodsFor:'documentation'!

documentation

"

    Standard CRC method as defined by ISO 3309 [ISO-3309] or ITU-T V.42 [ITU-T-V42]. 

    The CRC polynomial employed is

        x^32+x^26+x^23+x^22+x^16+x^12+x^11+x^10+x^8+x^7+x^5+x^4+x^2+x+1

    Use CRC to protect against communication errors. Do NOT use CRC for cryptography.

    Use SHA1Stream or MD5Stream instead.

    throughput:

    [author:]

        Stefan Vogel (stefan@zwerg)

    [instance variables:]

    [class variables:]

    [see also:]

        SHA1Stream

        MD5Stream

"

!

examples

"

  expect 60C1D0A0

                                                                [exBegin]

    self information:(CRC32Stream hashValueOf:'resume') hexPrintString

                                                                [exEnd]

  expect 16r60C1D0A0

                                                                [exBegin]

    self information:(CRC32Stream new

                            nextPut:$r;

                            nextPut:$e;

                            nextPut:$s;

                            nextPut:$u;

                            nextPut:$m;

                            nextPut:$e;

                            hashValue) hexPrintString

                                                                [exEnd]

  expect 16r98DC9ED7:

                                                                [exBegin]

    self information:(CRC32Stream new nextPut:4711; hashValue) printString

                                                                [exEnd]

  expect 16r70E46888:

                                                                [exBegin]

    self information:(CRC32Stream hashValueOf:#[1 2 3 4 5 6 7]) printString

                                                                [exEnd]

  expect 16r8CD04C73:

                                                                [exBegin]

    self information:((CRC32Stream hashValueOf:#[16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF]) digitBytes hexPrintString)

                                                                [exEnd]

  expect 16r86D7D79A:

  timing throughput:

                                                                [exBegin]

    |hashStream n t|

    hashStream := CRC32Stream new.

    n := 100000.

    t := Time millisecondsToRun:[

            n timesRepeat:[

                hashStream nextPutAll:'12345678901234567890123456789012345678901234567890'.

            ].

         ].

    t := (t / 1000) asFloat.

    Transcript show:'crc32:'; showCR: hashStream hashValue.

    Transcript show:t; show:' seconds for '; show:(50*n/1024) asFloat; showCR:' Kb'.

    Transcript show:(n*50/1024 / t); showCR:' Kb/s'

                                                                [exEnd]

"

! !

!CRC32Stream class methodsFor:'initialization'!

initialize

    CrcTable := IntegerArray new:256.

    0 to:255 do:[:count| |i|

        i := count.

        8 timesRepeat:[

            (i bitTest:1) ifTrue:[

                i := 16rEDB88320 bitXor:(i bitShift:-1)

            ] ifFalse:[

                i := i bitShift:-1

            ]

        ].

        CrcTable at:count+1 put:i.

    ].

    "

      self initialize

    "

! !

!CRC32Stream class methodsFor:'testing'!

testVector

    "define a testvector to test the implementation"

    ^ #(

          (#[16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF

             16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF 16rFF]

           2362461299)

          (#[0 0 0 0 0 0 0 0 0 0 

             0 0 0 0 0 0 0 0 0 0

             0 0 0 0 0 0 0 0 0 0

             0 0 0 0 0 0 0 0 0 0]

           3924573617)

          (#[0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19

             20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39]

           228994620 )

       )

    "

     self test

    "

! !

!CRC32Stream methodsFor:'initialization'!

initialize

    "initialize the CRC"

    crc := 16rFFFFFFFF.

! !

!CRC32Stream methodsFor:'queries'!

hashValue

    "return the computed CRC"

    ^ crc bitXor:16rFFFFFFFF

! !

!CRC32Stream methodsFor:'writing'!

nextPut:arg 

    "add the hash of anObject to the computed hash so far.

     anObject can be a Character, SmallInteger, or Character-, Byte-

     Integer-Array"

    | argSize "{ Class:SmallInteger }"

      byte    "{ Class:SmallInteger }" |

%{

#if 1

    unsigned char *cp;

    int n;

    unsigned char c;

    if (__isString(arg)) {

        cp = __stringVal(arg);

        n = __stringSize(arg);

        goto doBytes;

    }

    if (__isByteArray(arg)) {

        cp = __byteArrayVal(arg);

        n = __byteArraySize(arg);

    doBytes:

        {

            unsigned int _crc;

            unsigned int *_crcTable;

            if (__isSmallInteger(__INST(crc)) ) {

                _crc = (unsigned) (__intVal( __INST(crc) ));

            } else {

                _crc = __unsignedLongIntVal( __INST(crc) );

            }

            _crcTable = __integerArrayVal( @global(CrcTable) );

            while (n > 0) {

                unsigned _byte = *cp++;

                unsigned _idx;

                _idx = (_crc ^ _byte) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

                n--;

            }

            __INST(crc) = __MKUINT(_crc);

        }

        RETURN (self );

    }

    if (__isCharacter(arg)) {

        unsigned int value;

        value = __intVal(_characterVal(arg));

        if ((unsigned)value <= 0xFF) {

            c = value;

            cp = &c;

            n = 1;

            goto doBytes;

        }

    }

#endif

%}.

    arg isByteCollection ifTrue:[

        argSize := arg size.

        1 to:argSize do:[:n|

            byte := arg byteAt:n.

            crc := (CrcTable at:((crc bitXor:byte) bitAnd:16rFF)+1) 

                   bitXor:(crc bitShift:-8).

        ].

        ^ self.

    ].

    arg isCharacter ifTrue:[

        byte := arg codePoint.

        byte < 256 ifTrue:[

            crc := (CrcTable at:((crc bitXor:byte) bitAnd:16rFF)+1) 

                   bitXor:(crc bitShift:-8).

            ^ self.

        ].

        byte digitBytes do:[:eachByte|

            crc := (CrcTable at:((crc bitXor:eachByte) bitAnd:16rFF)+1) 

                   bitXor:(crc bitShift:-8).

        ].

        ^ self.

    ].

    arg isInteger ifTrue:[

        arg < 256 ifTrue:[

            crc := (CrcTable at:((crc bitXor:arg) bitAnd:16rFF)+1) 

                   bitXor:(crc bitShift:-8).

            ^ self.

        ].

        arg digitBytes do:[:eachByte|

            crc := (CrcTable at:((crc bitXor:eachByte) bitAnd:16rFF)+1) 

                   bitXor:(crc bitShift:-8).

        ].

        ^ self.

    ].

    arg isCollection ifTrue:[

        arg do:[:eachElement|

            self nextPut:eachElement

        ].

        ^ self.

    ].

    self error:'unsupported argument'.

! !

!CRC32Stream class methodsFor:'documentation'!

version

!

version_CVS

! !

CRC32Stream initialize!